Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1228to1232
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Vormonatsdatei per Schaltfläche

Vormonatsdatei per Schaltfläche
Ribbongegner
Hallo zusammen,
bin gerade dabei, eine Automatisierung für das Aufrufen von Vormonatsdateien zu erstellen.
Was soll das Ergebnis sein:
-eine Datei ist geöffnet, welche auf zB 0610 endet (für Oktober 2010)
-bei Betätigung einer Schaltfläche "VOR" wird automatisch die entsprechende Vormonatsdatei 0510 geöffnet. Eine Schaltfläche "NÄCHSTER" zeigt den Monat 0710 an
-wenn es keine Vormonatsdatei, bzw. keine Folgemonat-Datei gibt wird dies über eine MsgBox angezeigt
Sofern sich dieser Vorgang nur z.B. auf einen oder zwei Ordner bezieht, habe ich noch kein Problem bei der Programmierung.
Schwieriger wird es durch die folgende Zusatzprämisse: die Schaltfläche ist immer einsetzbar. Immer ist so zu verstehen: egal aus welchem Ordner ist eine Datei geöffnet habe: ich kann über die Schaltfläche immer die Vormonatsdatei aufrufen (bzw. es wird zumindest geprüft ob es eine gibt).
Bsp: Datei 1) C:\AUTO\0610
Datei 2) F:\HAUS\AUTO\XXXX\0510
Suchkriterium ist also MMJJ (MonatJahr).
Um es noch ein wenig komplizierter machen: wenn MMJJ nicht gefunden werden kann, soll nach JJMM gesucht werden - wird JJMM dann gefunden soll auch hier die Vormonatsdatei geöffnet werden.
Soweit bin ich (was mir fehlt sind Ideen für die Generalisierung...)
Vielen Dank für jede Hilfe!

Sub VM ()
' Definieren
Dim A, File, Path, Filename, Jahr, _
Jahr2, Jahrneu, Monat, Monatneu, Frequenz, _
Zelle, i, Ausgabe, CurJahr, Sparte, Quartal, Vorquartal, _
Result, Vormonat, Existiert, tv, Feld1
Filename = ActiveWorkbook.FullName
Path = Left(Filename, InStrRev(Filename, "\"))
File = Right(Filename, Len(Filename) - Len(Path))
Set tv = CreateObject("Scripting.FileSystemObject")
‘wie generalisieren?
If Filename Like "Z:\KALLE\HAUS?####.xls" Then
Monat = Format(Int(Mid(File, 7, 2)), "00")
If Monat  "01" Then
Vormonat = Format(Monat - 1, "00")
Jahr = Format(Int(Mid(File, 5, 2)), "00")
Sparte = Mid(File, 3, 2)
Result = "S:\KALLE\HAUS" & Jahr & ".xls"
Existiert = tv.FileExists(Result)
If Existiert Then Workbooks.Open (Result)
End If
End If
End Sub

AW: Vormonatsdatei per Schaltfläche
02.09.2011 21:21:46
Tino
Hallo,
möglich ist dies schon, nur bei mir hat Laufwerk C: schon über 40000 Ordner und Unterordner,
da müsstest Du schon den Suchbereich einschränken, sonst dauert dies einfach zu lang.
Kannst Du dies nicht anders Organisieren?
Persönlich würde ich mich auf einen Ordner mit n Unterordnern beschränken.
Die Schaltfläche würde ich wahrscheinlich mit einem Addin ins Menü rechte Maustaste einbauen,
wenn die Datei auf MMJJ.xls oder MMJJ.xlsm endet, dann hast Du diese immer zur Verfügung in den entsprechenden Dateien.
Gruß Tino
AW: Vormonatsdatei per Schaltfläche
05.09.2011 08:57:22
Ribbongegner
Hallo nochmal, vielen Dank für die erste Hilfestellung.
kann den Bereich auf zwei Netzlaufpfade eingrenzen (sind ca. 500 Unterordner). Hat noch jemand eine Idee für die Generalisierung - mit welcher Programmierung kann ich MMJJ/JJMM so verallgemeinern, das es egal ist wie die Datei sonst heißt, oder in welchem der begrenzten Pfade sie liegt - das Makro sieht nur MMJJ/JJMM und sucht die entsprechende Vormonatsdatei...
Viele Grüße
Ribbon
Anzeige
AW: Vormonatsdatei per Schaltfläche
05.09.2011 11:55:12
Tino
Hallo,
dann hast Du noch ein Problem.
Wie soll unterschieden werden was nun Monat und was Jahr ist.
Beispiel:
…1110.xls = November 2010 oder Oktober 2011?
oder
…1112.xls = November 2012 oder Dezember 2011?
Gruß Tino
AW: Vormonatsdatei per Schaltfläche
05.09.2011 12:57:16
Ribbongegner
Hallo Tino,
guter Hinweis, danke. Die Struktur MMJJ wird die allgemeingültige (muss also auf den angesprochenen 2 Netzwerkpfaden immer gefunden werden). Die JJMM Struktur findet sich nur in einem Unterordner, diese müsste also eine Ausnahme bilden. Wichtigster Punkt nach dem ich nun suche ist eine Möglichkeit zur Verallgemeinerung der Suche und Nutzung des Kriteriums MMJJ...
Viele Grüße
Ribbon
Anzeige
AW: Vormonatsdatei per Schaltfläche
05.09.2011 16:15:33
Tino
Hallo,
hier mal eine Version. (Code in DieseArbeitsmappe, Modul1, Modul2 u. Klasse1)
Excel- File entsprechend aufbauen und als Addin- speichern und mit dem Assistenten einbinden.
Im Modul1 in der Zeile
ArrLW = Array("C:\Auto\", "F:\Auto\")
die Pfadangaben für die beiden Ordner anpassen.
Wenn eine andere Datei geöffnet wird, wird die aktuelle nicht geschlossen, kann man aber noch einbauen.
Getestet unter xl2007 mit dem Format MMJJ.
kommt als Code in DieseArbeitsmappe

Option Explicit 
 
Dim oKlasseExcel As Klasse1 
 
Private Sub Workbook_BeforeClose(Cancel As Boolean) 
   LoeschButton "Zurück", "Vor" 
   Set oKlasseExcel = Nothing 
End Sub 
 
Private Sub Workbook_Open() 
    Set oKlasseExcel = New Klasse1 
    Set oKlasseExcel.ExcelWatch = Application 
End Sub 
kommt als Code in Modul1

Option Explicit 
 
Sub Suche_File(intSuchRichtung As Integer) 
Dim ArrLW(), n&, strNextFile$, nStart&, sFileName$ 
Dim DateMMJJ As Date, oWB As Workbook, booIsOben As Boolean 
 
'hier die beiden Pfade 
ArrLW = Array("C:\Auto\", "F:\Auto\") 
 
strNextFile = ActiveWorkbook.Name 
nStart = InStrRev(strNextFile, ".") - 4 
strNextFile = Mid$(strNextFile, nStart, 4) 
 
DateMMJJ = DateSerial(Mid(strNextFile, 3, 2) * 1, Mid(strNextFile, 1, 2) * 1, 1) 
DateMMJJ = DateMMJJ + intSuchRichtung 
For n = Lbound(ArrLW) To Ubound(ArrLW) 
    If Right$(ArrLW(n), 1) <> "\" Then ArrLW(n) = ArrLW(n) & "\" 
    strNextFile = FindFile(ArrLW(n), "*" & Format(DateMMJJ, "mmyy") & ".xls", , "*" & Format(DateMMJJ, "mmyy") & ".xlsm") 
    If strNextFile <> "" Then Exit For 
Next n 
If strNextFile <> "" Then 
    sFileName = Mid$(strNextFile, InStrRev(strNextFile, "\") + 1, 10 ^ 9) 
    For Each oWB In Workbooks 
        booIsOben = oWB.Name = sFileName 
        If booIsOben Then Exit For 
    Next oWB 
    If Not booIsOben Then 
        Workbooks.Open strNextFile 
    Else 
        MsgBox "Datei mit diesen Namen bereits offen!" & vbCr & "Diese wird jetzt aktiviert!" 
        Workbooks(sFileName).Activate 
    End If 
Else 
    MsgBox "Excel- Datei '" & Format(DateMMJJ, "mmyy") & ".xls(m)' wurde nicht gefunden!", vbExclamation 
End If 
End Sub 
 
Sub ButtenMenueRechteMaus(booErstellen As Boolean) 
Dim NeuerButton(1) As CommandBarControl 
 
On Error Resume Next 
    Set NeuerButton(0) = Application.CommandBars("cell").Controls("Zurück") 
    Set NeuerButton(1) = Application.CommandBars("cell").Controls("Vor") 
    If NeuerButton(0) Is Nothing Then _
    Set NeuerButton(0) = Application.CommandBars("cell").Controls.Add(Type:=msoControlButton, Before:=1, Temporary:=True) 
    If NeuerButton(1) Is Nothing Then _
    Set NeuerButton(1) = Application.CommandBars("cell").Controls.Add(Type:=msoControlButton, Before:=2, Temporary:=True) 
On Error GoTo 0 
 
If booErstellen Then 
    With NeuerButton(0) 
           .Enabled = True 
           .FaceId = 41 
           .Caption = "Zurück" 'Name im Menü 
           .OnAction = "'Suche_File ""-1""'" 'Name des Macros 
           .Visible = True 
    End With 
    With NeuerButton(1) 
           .Enabled = True 
           .FaceId = 39 
           .Caption = "Vor" 'Name im Menü 
           .OnAction = "'Suche_File ""31""'" 'Name des Macros 
           .Visible = True 
    End With 
Else 
    NeuerButton(0).Delete 
    NeuerButton(1).Delete 
End If 
 
Erase NeuerButton 
End Sub 
Sub LoeschButton(ParamArray varButtonCaption() As Variant) 
Dim varName 
For Each varName In varButtonCaption 
    On Error Resume Next 
    Do While Err.Number = 0 
     Application.CommandBars("cell").Controls(varName).Delete 
    Loop 
    Err.Clear: On Error GoTo 0 
Next varName 
End Sub 
kommt als Code in Modul2

Option Explicit 
 
Function FindFile(ByVal sPath$, ParamArray ArrFilter() As Variant) 
Dim fs As Object, strDir$, varFilter 
Dim Ordner As Object, Unterordner As Object 
 
Set fs = CreateObject("Scripting.FileSystemObject") 
Set Ordner = fs.getfolder(sPath) 
On Error GoTo ErrorZugriff: 
 
FindFile = Find_File(fs, sPath, ArrFilter) 
For Each Unterordner In Ordner.subfolders 
    FindFile = Find_File(fs, Unterordner.Path, ArrFilter) 
    If FindFile <> "" Then Exit Function 
Next 
 
For Each Unterordner In Ordner.subfolders 
    If FindFile <> "" Then Exit Function 
    FindFile Unterordner.Path 
Next 
 
ErrorZugriff: 
Set fs = Nothing 
End Function 
 
Function Find_File(fs As Object, strPath$, ByVal ArrFilter) 
Dim varFilter, strDir$ 
If Right$(strPath, 1) <> "\" Then strPath = strPath & "\" 
ChDrive Left$(strPath, 2) 
ChDir strPath 
For Each varFilter In ArrFilter 
    strDir = Dir$(strPath & varFilter) 
    If strDir <> "" Then 
        Find_File = strPath & strDir 
    End If 
    If Find_File <> "" Then Exit Function 
Next varFilter 
End Function 
kommt als Code in Klasse1

Option Explicit 
 
Public WithEvents ExcelWatch As Application 
Private Sub ExcelWatch_WorkbookDeactivate(ByVal Wb As Workbook) 
ButtenMenueRechteMaus False 
End Sub 
 
Private Sub ExcelWatch_WorkbookActivate(ByVal Wb As Workbook) 
Dim sName$, nPos% 
With Wb 
    nPos = InStrRev(.Name, ".") 
    If nPos > 4 Then _
    sName = Mid$(.Name, nPos - 4, 4) 
    If sName Like "[0-1][0-9][0-9][0-9]" Then 
        ButtenMenueRechteMaus True 
    Else 
        ButtenMenueRechteMaus False 
    End If 
End With 
End Sub 
 
 
 
 
Gruß Tino
Anzeige
AW: Vormonatsdatei per Schaltfläche
05.09.2011 17:45:06
Tino
Hallo,
habe das mit dem Schließen der Datei mit einer Abfrage eingebaut u.
noch ein paar andere Zeilen anders aufgebaut wo ich meine das es so besser ist.
kommt als Code in DieseArbeitsmappe

Option Explicit 
 
Dim oKlasseExcel As Klasse1 
 
Private Sub Workbook_BeforeClose(Cancel As Boolean) 
   LoeschButton CaptionButtonZurueck, CaptionButtonVor 
   Set oKlasseExcel = Nothing 
End Sub 
 
Private Sub Workbook_Open() 
    Set oKlasseExcel = New Klasse1 
    Set oKlasseExcel.ExcelWatch = Application 
End Sub 
kommt als Code in Modul1

Option Explicit 
Public Const CaptionButtonVor$ = "Vor", CaptionButtonZurueck$ = "Zurück" 
Sub Suche_File(intSuchRichtung As Integer) 
Dim ArrLW(), n&, strNextFile$, nStart&, sFileName$ 
Dim DateMMJJ As Date, oWB As Workbook, booIsOben As Boolean 
Dim intAntwort As VbMsgBoxResult 
 
'hier die beiden Pfade 
ArrLW = Array("C:\Auto\", "F:\Auto\") 
 
strNextFile = ActiveWorkbook.Name 
nStart = InStrRev(strNextFile, ".") - 4 
strNextFile = Mid$(strNextFile, nStart, 4) 
 
DateMMJJ = DateSerial(Mid(strNextFile, 3, 2) * 1, Mid(strNextFile, 1, 2) * 1, 1) 
DateMMJJ = DateMMJJ + intSuchRichtung 
For n = Lbound(ArrLW) To Ubound(ArrLW) 
    If Right$(ArrLW(n), 1) <> "\" Then ArrLW(n) = ArrLW(n) & "\" 
    strNextFile = FindFile(ArrLW(n), "*" & Format(DateMMJJ, "mmyy") & ".xls", , "*" & Format(DateMMJJ, "mmyy") & ".xlsm") 
    If strNextFile <> "" Then Exit For 
Next n 
If strNextFile <> "" Then 
    sFileName = Mid$(strNextFile, InStrRev(strNextFile, "\") + 1, 10 ^ 9) 
    For Each oWB In Workbooks 
        booIsOben = oWB.Name = sFileName 
        If booIsOben Then Exit For 
    Next oWB 
     
    If Not booIsOben Then 'Datei nicht offen 
        intAntwort = MsgBox("Datei gefunden!" & vbCr & "Soll die aktuelle Datei '" & ActiveWorkbook.Name & _
                     "' jetzt gespeichert u. geschlossen werden?", vbQuestion + vbYesNo) 
        Set oWB = ActiveWorkbook 
        Workbooks.Open strNextFile 
    Else 'Datei offen 
        Set oWB = ActiveWorkbook 
        MsgBox "Datei mit diesen Namen ' " & sFileName & "' bereits offen!" & vbCr & "Diese wird jetzt aktiviert!", vbInformation 
        Workbooks(sFileName).Activate 
    End If 
     
    If intAntwort = vbYes Then 
        Application.EnableEvents = False 
        oWB.Close True 
        Application.EnableEvents = True 
    End If 
Else 
    MsgBox "Excel- Datei '" & Format(DateMMJJ, "mmyy") & ".xls(m)' wurde nicht gefunden!", vbExclamation 
End If 
End Sub 
 
Sub ButtenMenueRechteMaus(booErstellen As Boolean) 
Dim NeuerButton(1) As CommandBarControl 
 
On Error Resume Next 
    Set NeuerButton(0) = Application.CommandBars("cell").Controls(CaptionButtonZurueck) 
    Set NeuerButton(1) = Application.CommandBars("cell").Controls(CaptionButtonVor) 
On Error GoTo 0 
 
If booErstellen Then 
    If NeuerButton(0) Is Nothing Then 
        Set NeuerButton(0) = Application.CommandBars("cell").Controls.Add(Type:=msoControlButton, Before:=1, Temporary:=True) 
        With NeuerButton(0) 
               .Enabled = True 
               .FaceId = 41 
               .Caption = CaptionButtonZurueck 'Name im Menü 
               .OnAction = "'Suche_File ""-1""'" 'Name des Macros 
        End With 
    End If 
    NeuerButton(0).Visible = True 
     
    If NeuerButton(1) Is Nothing Then 
        Set NeuerButton(1) = Application.CommandBars("cell").Controls.Add(Type:=msoControlButton, Before:=1, Temporary:=True) 
        With NeuerButton(1) 
               .Enabled = True 
               .FaceId = 39 
               .Caption = CaptionButtonVor 'Name im Menü 
               .OnAction = "'Suche_File ""31""'" 'Name des Macros 
        End With 
    End If 
    NeuerButton(1).Visible = True 
Else 
   If Not NeuerButton(0) Is Nothing Then NeuerButton(0).Visible = False 
   If Not NeuerButton(1) Is Nothing Then NeuerButton(1).Visible = False 
End If 
 
Erase NeuerButton 
End Sub 
Sub LoeschButton(ParamArray varButtonCaption() As Variant) 
Dim varName 
For Each varName In varButtonCaption 
    On Error Resume Next 
    Do While Err.Number = 0 
     Application.CommandBars("cell").Controls(varName).Delete 
    Loop 
    Err.Clear: On Error GoTo 0 
Next varName 
End Sub 
kommt als Code in Modul2

Option Explicit 
 
Function FindFile(ByVal sPath$, ParamArray ArrFilter() As Variant) 
Dim fs As Object, strDir$, varFilter 
Dim Ordner As Object, Unterordner As Object 
 
Set fs = CreateObject("Scripting.FileSystemObject") 
Set Ordner = fs.getfolder(sPath) 
On Error GoTo ErrorZugriff: 
 
FindFile = Find_File(fs, sPath, ArrFilter) 
For Each Unterordner In Ordner.subfolders 
    FindFile = Find_File(fs, Unterordner.Path, ArrFilter) 
    If FindFile <> "" Then Exit Function 
Next 
 
For Each Unterordner In Ordner.subfolders 
    If FindFile <> "" Then Exit Function 
    FindFile Unterordner.Path 
Next 
 
ErrorZugriff: 
Set fs = Nothing 
End Function 
 
Function Find_File(fs As Object, strPath$, ByVal ArrFilter) 
Dim varFilter, strDir$ 
If Right$(strPath, 1) <> "\" Then strPath = strPath & "\" 
ChDrive Left$(strPath, 2) 
ChDir strPath 
For Each varFilter In ArrFilter 
    strDir = Dir$(strPath & varFilter) 
    If strDir <> "" Then 
        Find_File = strPath & strDir 
    End If 
    If Find_File <> "" Then Exit Function 
Next varFilter 
End Function 
kommt als Code in Klasse1

Option Explicit 
 
Public WithEvents ExcelWatch As Application 
Private Sub ExcelWatch_WorkbookDeactivate(ByVal Wb As Workbook) 
ButtenMenueRechteMaus False 
End Sub 
 
Private Sub ExcelWatch_WorkbookActivate(ByVal Wb As Workbook) 
Dim sName$, nPos% 
With Wb 
    nPos = InStrRev(.Name, ".") 
    If nPos > 4 Then _
    sName = Mid$(.Name, nPos - 4, 4) 
    If sName Like "[0-1][0-9][0-9][0-9]" Then 
        ButtenMenueRechteMaus True 
    Else 
        ButtenMenueRechteMaus False 
    End If 
End With 
End Sub 
 
 
 
 
Gruß Tino
Anzeige
AW: Vormonatsdatei per Schaltfläche
05.09.2011 18:11:34
Ribbongegner
Wow! Vielen Dank schonmal, werde das jetzt testen/anpassen und melde mich dann:-)
Gruß
Ribbon
AW: Vormonatsdatei per Schaltfläche
05.09.2011 18:41:16
fcs
Hallo Ribbon,
ich hatte auch schon etwas Gehirnschmalz investiert.
Dann will ich die Lösung auch nicht für mich behalten.
Evtl. ist da ja auch noch was brauchbares drin jenseits von Toni's Lösung.
https://www.herber.de/bbs/user/76469.txt
Gruß
Franz
AW: Vormonatsdatei per Schaltfläche
05.09.2011 18:59:40
Ribbongegner
Wow! Vielen Dank schonmal, werde das jetzt testen/anpassen und melde mich dann:-)
Gruß
Ribbon
AW: Vormonatsdatei per Schaltfläche
05.09.2011 19:01:59
Ribbongegner
Hmmm. Nutze Excel 2010. Beim Öffner einer Datei bekomme ich nach Integration den Hinweis "Fehler beim Kompilieren - benutzerdef. Typ nicht definiert" - die Buttons werden nicht angelegt...
Anzeige
AW: Vormonatsdatei per Schaltfläche
05.09.2011 19:39:51
Tino
Hallo,
hier mein Testordner als Zip- File, Pfad habe ich zum testen ob es bei Dir geht auf die aktive Datei gesetzt.
https://www.herber.de/bbs/user/76470.zip
Gruß Tino
AW: Vormonatsdatei per Schaltfläche
05.09.2011 21:16:00
fcs
Hallo Tino,
Super-Lösung als xla-AddIn inklusive Rechte-Maus-Menü. Integration in Excel 2007 ging ohne Probleme.
Ein kleiner Fehler hatte sich noch eingeschlichen.

Sub Suche_File(intSuchRichtung As Integer)
Dim ArrLW(), n&, strNextFile$, nStart&, sFileName$
Dim DateMMJJ As Date, oWB As Workbook, booIsOben As Boolean
Dim intAntwort As VbMsgBoxResult
'hier die beiden Pfade
ArrLW = Array("C:\Users\Public\Test", "C:\Users\Admin\Documents")
'ArrLW = Array(ActiveWorkbook.Path, ActiveWorkbook.Path)
strNextFile = ActiveWorkbook.Name
nStart = InStrRev(strNextFile, ".") - 4
strNextFile = Mid$(strNextFile, nStart, 4)
DateMMJJ = DateSerial(Mid(strNextFile, 3, 2) * 1, Mid(strNextFile, 1, 2) * 1, 1)
DateMMJJ = DateMMJJ + intSuchRichtung
For n = LBound(ArrLW) To UBound(ArrLW)
If Right$(ArrLW(n), 1)  "\" Then ArrLW(n) = ArrLW(n) & "\"
strNextFile = FindFile(ArrLW(n), "*" & Format(DateMMJJ, "mmyy") & ".xls", _
"*" & Format(DateMMJJ, "mmyy") & ".xls*")
If strNextFile  "" Then Exit For
Next n

In der Parameter-Übergabe für FindFile war durch 2 Komma hintereinander ein Filter ohne Wert. Folge: Fehler und Abbruch in der Suchroutine bevor die Unterverzeichnisse durchsucht werden. Außerdem wurden xlsx-Dateien noch nicht gefunden.
Gruß
Franz
Anzeige
AW: Vormonatsdatei per Schaltfläche
06.09.2011 06:24:47
Tino
Hallo,
sachen gibt es, beim hochladen immer die falsche Datei erwischt?!
Das mit der xlsx kann man leicht erweitern.
danke
Gruß Tino
AW: Vormonatsdatei per Schaltfläche
06.09.2011 08:56:44
Ribbongegner
Hallo zusammen! Das sieht wirklich super aus. Leider bekomme ich unter Excel 2010 immer noch diesen Hinweis - das Add-In lässt sich integrieren. Allerdings sehe ich auch keine Schaltfläche...
Userbild
AW: Vormonatsdatei per Schaltfläche
06.09.2011 09:28:47
Ribbongegner
Update: Trotz Fehlermeldung funktioniert das Add-In soweit. Eine Erschwernis kommt nun aber noch dazu: alles funktioniert super, wenn nur eine Datei je Monat im Ordner liegt - Bsp Ordner Mappe0612. Allerdings habe gibt es bei mir in einem Ordner teilweise mehrere Dateien mit dem selben Monat, aber einem anderen Namen Bsp Mappe0612 und Mapper0612. Kann man da noch eine Routine hinzufügen, damit der gesamt Dateiname z.B. als Kriterium integriert wird?
Anzeige
AW: Vormonatsdatei per Schaltfläche
06.09.2011 12:38:20
Tino
Hallo,
versuch es mal mit dieser Version.
https://www.herber.de/bbs/user/76482.zip
Habe dies jetzt auch unter xl2003 u. 2010 eingebaut, es kommt keine Fehlermeldung bei mir.
Gruß Tino
AW: Vormonatsdatei per Schaltfläche
06.09.2011 18:44:47
Ribbongegner
Stimmt, die Fehlermeldung ist verschwunden:-) nur wenn ich jetzt in einem Ordner mit verschiedenen Dateien nach dem Muster MMJJ VOR auslöse wird die Vormonatsdatei einer anderen aufgerufen.
BSP: ich rufe Muster0611 auf und erwarte durch VOR Muster0511, dann kommt Master0511 usw.
AW: Vormonatsdatei per Schaltfläche
06.09.2011 20:01:24
Tino
Hallo,
vielleicht geht es jetzt.
https://www.herber.de/bbs/user/76494.zip
Gruß Tino
Anzeige
AW: Vormonatsdatei per Schaltfläche
07.09.2011 09:17:09
Ribbongegner
Guten Morgen,
leider spuckt xls eine Fehlermeldung aus...nicht gefunden...
Userbild
AW: Vormonatsdatei per Schaltfläche
07.09.2011 15:59:09
Tino
Hallo,
diese Meldung kommt wenn diese Datei nicht gefunden wurde.
Beispiel Du hast die Datei
Master0511.xls geöffnet beim drücken auf Vor wird nach der Datei
Master0611.xls gesucht und beim drücken auf Zurück Master0411.xls.
Kann dies jetzt nicht nachvollziehen, habe es mit einigen Unterordnern getestet.
Gruß Tino
AW: Vormonatsdatei per Schaltfläche
08.09.2011 09:59:22
Ribbongegner
Super! Funktioniert! Vielen Dank! Hast Du vielleicht noch eine Idee, wie ich am Besten Ausnahmen einbauen könnte? Also ganz bestimmte Pfade (nur wenige) in denen Dateien zB mit JJMM aufgebaut sind? Das Tool müsste also checken, ob die Datei einer "normalen" Datei in der Konfiguration MMJJ entspricht oder eben einer der Ausnahmen und entsprechend handeln...
Anzeige
AW: Vormonatsdatei per Schaltfläche
08.09.2011 16:20:16
Tino
Hallo,
man könnte eine Userform einbauen und mittels Optionsbutton diese den Filter von MMJJ auf JJMM umstellen.
https://www.herber.de/bbs/user/76522.zip
Gruß Tino
AW: Vormonatsdatei per Schaltfläche
08.09.2011 18:34:55
Ribbongegner
Gute Idee. Werde mich da mal versuchen. Vielen Dank!!!!

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige