Herbers Excel-Forum - das Archiv

Letzer Eintrag einer Spalte ermitteln (ohne VBA)

Bild

Betrifft: Letzer Eintrag einer Spalte ermitteln (ohne VBA)
von: Peter

Geschrieben am: 09.01.2007 18:15:33
Guten Abend
Vielleicht sollte man das ja mit Excel gut wissen ...
Wie kann ich mit einer Formel ermitteln, in welcher Zeile der letzte Eintrag in Spalte A einer bestimmten Tabelle steht?
Danke für Feedback.
Peter
Bild

Betrifft: AW: Letzer Eintrag einer Spalte ermitteln (ohne VBA)
von: HermannZ
Geschrieben am: 09.01.2007 18:22:52
Hallo Peter;
zwei Möglichkeiten;
letzte Zahl in Spalte A;
=VERWEIS(1E+307;A1:A1000)
oder Letzter Wert in Spalte A;
=VERWEIS(1;--(A1:A1000<>"");A1:A1000)
Gruss Hermann
Bild

Betrifft: AW: Letzer Eintrag einer Spalte ermitteln (ohne VBA)
von: Peter

Geschrieben am: 09.01.2007 18:41:57
Hallo Hermann
Vielen Dank.
Zwei Anschlussfragen:
- beim letzten Wert habe ich nur eine Null erhalten (vgl. https://www.herber.de/bbs/user/39523.xls)
- eigentlich wollte ich die Zeile wissen, in dem der Eintrag steht. Ist das auch möglich?
Danke und Gruss
Peter
Bild

Betrifft: AW: Letzer Eintrag einer Spalte ermitteln (ohne VBA)
von: HermannZ
Geschrieben am: 09.01.2007 18:58:10
Hallo Peter;
sihe hier;
https://www.herber.de/bbs/user/39524.xls
Gruss Hermann
Bild

Betrifft: AW: Letzer Eintrag einer Spalte ermitteln (ohne VBA)
von: HermannZ

Geschrieben am: 09.01.2007 21:53:23
Hallo peter;
das mit der Adresse habe ich total übersehen;
suche dir was aus..
hier einige Beispiele;
 
 ABCD
1206Bestimmen von erster und letzter Zeile und Wert in Spalte   
1207    
1208 1209<< erste Zeile in  Spalte A  >"" 
1209441216<< letzte Zeile in Spalte A  >"" 
12108A1209<< Adresse erster Eintrag Spalte A  >"" 
121116A1216<<Adresse  letzter Eintrag in  Spalte A  >"" 
1212-244<< Wert erster Eintrag Spalte A 
12134wert<< Wert letzter Eintrag Spalte A 
1214112<< Vorletzter Wert in Spalte A 
12152wert<< Letzter Eintrag in Spalte A  
1216wert2<< Letzte Zahl in Spalte A 
1217 2<< Letzte Zahl in Spalte A 
1218 2<< Letzte Zahl in Spalte A 
1219 2<< Letzte Zahl in Spalte A 
1220 wert<< Letzter Eintrag in Spalte A  
1221 44<< erster Eintrag in Spalte A 
1222 wert<< Letzter Eintrag in Spalte A  
Formeln der Tabelle
B1208 : {=MIN((WENN(A1208:A1217<>"";ZEILE(1208:1217))))}
B1209 : {=MAX((A1208:A1217<>"")*ZEILE(1208:1217))}
B1210 : {=ADRESSE(MIN((WENN(A1208:A1217<>"";ZEILE(1208:1217))));1;4)}
B1211 : {=ADRESSE(MAX((WENN(A1208:A1217<>"";ZEILE(1208:1217))));1;4)}
B1212 : {=INDIREKT("A"&MIN(WENN(A1208:A1217<>"";ZEILE(1208:1217))))}
B1213 : {=INDIREKT("A"&MAX((A1208:A1217<>"")*ZEILE(1208:1217)))}
B1214 : {=INDIREKT("A"&KGRÖSSTE(WENN(A1208:A1217<>"";ZEILE(1208:1217));2))}
B1215 : =VERWEIS(2;1/(A1208:A1217<>"");A1208:A1217)
B1216 : =INDEX(A1208:A1217;VERGLEICH(1E+307;A1208:A1217;1))
B1217 : =INDIREKT("A"&VERGLEICH(1E+307;A1208:A1217;1)+1207)
B1218 : =VERWEIS(1;--ISTZAHL(A1208:A1217);A1208:A1217)
B1219 : =VERWEIS(1E+307;A1208:A1217)
B1220 : =VERWEIS(1;--(A1208:A1217<>"");A1208:A1217)
B1221 : {=INDEX(A1208:A1217;VERGLEICH(1;--(A1208:A1217<>"");0))}
B1222 : {=INDEX(A1208:A1217;VERGLEICH(1;--(A1208:A1217<>""));1)}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  
Gruß HermannZ
 Bild
Excel-Beispiele zum Thema "Letzer Eintrag einer Spalte ermitteln (ohne VBA)"
Doppelte Einträge finden und löschen Submenüeinträge
Seitenanzahl eintragen Letztes Speicherdatum eintragen
Fußzeilen beim Öffnen eintragen Wert in erste leere Zelle eintragen
Häkchen eintragen KGRÖSSTE über VBA eintragen
Wochentage Mo - Fr in Tabelle eintragen Arbeitsmappe unter dem Text eines Zelleintrags speichern