Microsoft Excel

Herbers Excel/VBA-Archiv

Formelsuche

Betrifft: Formelsuche von: anke2245
Geschrieben am: 10.08.2008 12:40:34

Ich suche den Experten mit dem Code WF,
wir haben einige Formeln bearbeitet und dabei fast alles berücksichtigt.
Nur einen Punkt habe ich vergessen Dir zu sagen:
ich erhalte bei einem Unentschieden 2 Punkte z.B. Tipp 2:2 Ergebnis 1:1
bei exaktem Ergebnis z.B. Tipp 2:1 Ergebnis 2:1 gibt es 4 Punkte , aber auch bei dem exakten Tipp eines Unentschieden z.B. Tipp 1:1 Ergebnis 1:1
Vielleicht kannst Du mirja noch einmal helfen.
anke

  

Betrifft: Bin zwar nicht WF... von: {Boris}
Geschrieben am: 10.08.2008 12:44:31

Hi Anke,

...der ist viel zu sehr damit beschäftigt, sich Olympia reinzuziehen.
Um welche Formeln genau ging es denn? Bzw. wie soll es sein?
Exakt 4, Tendenz 2, sonst nix?

Grüße Boris


  

Betrifft: AW: Formelsuche von: anke2245
Geschrieben am: 10.08.2008 12:59:41

Hallo Boris,
WF und ich haben folgende Kriterien erfüllt:
Es ist ein internes Tippspiel zwischen unserer Fußballabteilung, Tischtennisabteilung und den Volleyballern
Hier die Beispiele
Tipp: 3:1 Ergebnis: 3:1 = 4 Punkte ( exakter Tipp)
Tipp 3:2 Ergebnis: 2:1 = 3 Punkte ( Tendenz und Tordifferenz exakt)
Tipp 3:1 Ergebnis: 2:1 = 1 Punkt ( Tendenz richtig)
Tipp 0:0 Ergebnis: 1:1 = 2 Punkte ( Tendenz beim Unentschieden)
für falsche Tipps gibt es natürlich keine Punkte.
Ein Problem ist aufgetaucht, wenn ich exakt ein Unentschieden tippe, erhalte ich statt 4 nur 2 Punkte.
Gruß anke


  

Betrifft: AW: Formelsuche von: {Boris}
Geschrieben am: 10.08.2008 13:23:49

Hi Anke,

Formel aus E2 runterkopieren:

Tabelle1

 ABCDE
1Ergebnis Tipp Punkte
222112
311114
431203
541201
621120

Formeln der Tabelle
ZelleFormel
E2=WENN(ANZAHL(A2:D2)<>4;"";WENN(UND($A2=C2;$B2=D2); 4;WENN($A2-$B2=C2-D2;2+(C2<>D2); WENN(VORZEICHEN($A2-$B2)=VORZEICHEN(C2-D2); 1;0))))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4



Grüße Boris


  

Betrifft: Ankes Problem kann ich wieder nicht ... von: WF
Geschrieben am: 10.08.2008 13:33:10

... nachvollziehen.

Moin Boris,
Meine Formel von gestern funktioniert doch in allen Lebenslagen:
=WENN(ISTLEER(C1);0;(A1=C1)*(B1=D1)+(A1-B1-C1+D1=0)*2+(VORZEICHEN(A1-B1)=(VORZEICHEN(C1-D1)))-(A1=B1) *(C1=D1)*(A1<>C1))

WF


  

Betrifft: Stimmt... von: {Boris}
Geschrieben am: 10.08.2008 13:37:32

Moin Walter,

...funktioniert tadellos (ich kannte Deine Lösung nur nicht).

Grüße Boris


  

Betrifft: AW: Ankes Problem kann ich wieder nicht ... von: anke2245
Geschrieben am: 10.08.2008 13:44:42

entschuldigt, aber ich habe vor der Eingabe der Formel, teilweise Ergebnisse eingetragen gehabt, die sich logischerweise dann nicht änderten.
Nochmals vielen dank für die Bemühungen
undschönen Sonntag
Danke Anke


  

Betrifft: nein; nicht "in allen Lebenslagen" ... von: neopa
Geschrieben am: 10.08.2008 14:42:34

Hallo Walter,

... wie meine nachfolgende Gegenüberstellung und mein WENN-freier Ergänzungsvorschlag (auch nur 2 Zeichen länger) zeigen dürfte. Fazit: die 0 soll gefälligst auch eindeutig erkennbar "getippt" werden ;-)

 ABCDEF
1ErgebnisTippPunkte
2221122
3111144
4312033
5412011
6211200
7414144
802 200
9000 40

Formeln der Tabelle
ZelleFormel
E2=WENN(ISTLEER(C2); 0;(A2=C2)*(B2=D2)+(A2-B2-C2+D2=0)*2+(VORZEICHEN(A2-B2)=(VORZEICHEN(C2-D2)))-(A2=B2) *(C2=D2)*(A2<>C2))
F2=((A2=C2)*(B2=D2)+(A2-B2-C2+D2=0)*2+(VORZEICHEN(A2-B2)=(VORZEICHEN(C2-D2)))-(A2=B2) *(C2=D2)*(A2<>C2))*((C2<>"")*(D2<>""))
E9=WENN(ISTLEER(C9); 0;(A9=C9)*(B9=D9)+(A9-B9-C9+D9=0)*2+(VORZEICHEN(A9-B9)=(VORZEICHEN(C9-D9)))-(A9=B9) *(C9=D9)*(A9<>C9))
F9=((A9=C9)*(B9=D9)+(A9-B9-C9+D9=0)*2+(VORZEICHEN(A9-B9)=(VORZEICHEN(C9-D9)))-(A9=B9) *(C9=D9)*(A9<>C9))*((C9<>"")*(D9<>""))


Schönen Sonntag noch.

Gruß Werner
.. , - ...


  

Betrifft: das Klammerpar ... von: neopa
Geschrieben am: 11.08.2008 08:23:50

... um meinen WENN() Ersatz kann noch entfallen.

Gruß Werner
.. , - ...



  

Betrifft: na ja, was ist... von: FP
Geschrieben am: 12.08.2008 19:18:31

Hallo Werner,



... wenn das Spielergebnis noch gar nicht vollständig eingegeben wurde? ;D



Tipperei
 ABCDEFGH
1SpielergebnisT i p p    
2HeimAuswärtsHeimAuswärts FPneopaWF
30000 444
41100 222
50011 222
62121 444
72110 333
82030 111
93010 111
101214 111
112112 000
1202 2 000
13000  004
144 31 011
151 32 033
Formeln der Tabelle
F3 : =((VORZEICHEN(A3-B3)=VORZEICHEN(C3-D3))+(A3-C3=B3-D3)*(2+((A3=C3)*(B3=D3)))-(A3=B3)*(B3<>C3))*(ANZAHL(A3:D3)=4)
G3 : =((A3=C3)*(B3=D3)+(A3-B3-C3+D3=0)*2+(VORZEICHEN(A3-B3)=(VORZEICHEN(C3-D3)))-(A3=B3) *(C3=D3)*(A3<>C3))*((C3<>"")*(D3<>""))
H3 : =WENN(ISTLEER(C3); 0;(A3=C3)*(B3=D3)+(A3-B3-C3+D3=0)*2+(VORZEICHEN(A3-B3)=(VORZEICHEN(C3-D3)))-(A3=B3) *(C3=D3)*(A3<>C3))
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  




Servus aus dem Salzkammergut

Franz


  

Betrifft: AW: na ja, was ist... von: WF
Geschrieben am: 12.08.2008 19:22:23

=(ANZAHL(A1:D1)=4)*((A1=C1)*(B1=D1)+(A1-B1-C1+D1=0)*2+(VORZEICHEN(A1-B1)=(VORZEICHEN(C1-D1)))-(A1=B1) *(C1=D1)*(A1<>C1))


  

Betrifft: ja so funktioniert es dann... von: FP
Geschrieben am: 12.08.2008 23:39:15

Hallo Walter,

...aber ich habe meine noch ein bischen verkürzt :-)

Tipperei
 ABCDEFGH
1SpielergebnisT i p p    
2HeimAuswärtsHeimAuswärts FPneopaWF
30000 444
41100 222
50011 222
62121 444
72110 333
82030 111
93010 111
101214 111
112112 000
1202 2 000
13000  000
144 31 010
151 32 030
Formeln der Tabelle
F3 : =((1-(A3>B3)*2=1-(C3>D3)*2)+(A3-C3=B3-D3)*(2+(A3=C3)*(B3=D3))-(A3=B3)*(B3<>C3))*(ANZAHL(A3:D3)=4)
G3 : =((A3=C3)*(B3=D3)+(A3-B3-C3+D3=0)*2+(VORZEICHEN(A3-B3)=(VORZEICHEN(C3-D3)))-(A3=B3) *(C3=D3)*(A3<>C3))*(C3<>"")*(D3<>"")
H3 : =(ANZAHL(A3:D3)=4)*((A3=C3)*(B3=D3)+(A3-B3-C3+D3=0)*2+(VORZEICHEN(A3-B3)=(VORZEICHEN(C3-D3)))-(A3=B3) *(C3=D3)*(A3<>C3))
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  


Servus aus dem Salzkammergut
Franz


  

Betrifft: genau genommen... von: FP
Geschrieben am: 12.08.2008 23:45:46

Hallo Walter,

...genügt sogar diese Formel in F3:

=((-(A3>B3)=-(C3>D3))+(A3-C3=B3-D3)*(2+(A3=C3)*(B3=D3))-(A3=B3)*(B3<>C3))*(ANZAHL(A3:D3) =4)


Servus aus dem Salzkammergut

Franz


  

Betrifft: und noch 2 Zeichen gespart von: FP
Geschrieben am: 12.08.2008 23:54:29

Hallo Walter,

... weil es ja nur darum geht, die richtige Tendenz zu ermitteln. Habe mich zu sehr an die VORZEICHEN Funktion geklammert.

in F3:

=(((A3>B3)=(C3>D3))+(A3-C3=B3-D3)*(2+(A3=C3)*(B3=D3))-(A3=B3)*(B3<>C3))*(ANZAHL(A3:D3)=4)

Servus aus dem Salzkammergut
Franz


  

Betrifft: ich freue mich, ... von: neopa
Geschrieben am: 13.08.2008 08:53:42

Hallo Franz,

... dass Du wieder "auferstanden" bist und es Dir wieder besser geht. Den Nachweis hast Du hiermit erbracht. Eine schöne und vor allem gute Restwoche

wünscht Werner
.. , - ...


  

Betrifft: ich mich auch, aber... von: FP
Geschrieben am: 13.08.2008 10:52:06

Hallo Werner,

... ganz gut geht's mir offenbar doch noch nicht, weil ich einen Fall übersehen habe: wenn das Ergebnis ein Sieg der Auswärtsmannschaft ist und auf unentschieden getippt wurde.

Hier eine korrigierte Version, ohne VORZEICHEN()

=(((A3+(A3=B3)>B3)=(C3+(C3=D3)>D3))+(A3-C3=B3-D3)*(2+(A3=C3)*(B3=D3))-(A3=B3)*(B3<>C3)) *(ANZAHL(A3:D3)=4)


Servus aus dem Salzkammergut
Franz


  

Betrifft: jetzt Fehler: Heimsieg und Unentschieden von: WF
Geschrieben am: 13.08.2008 11:59:34

.


  

Betrifft: es bleibt also doch bei VORZEICHEN von: FP
Geschrieben am: 13.08.2008 20:32:38

Hallo Walter,

... obwohl ich eine Lösung ohne diese Funktion gefunden habe, aber die ist dann länger

Tipperei
 ABCDEFGHI
1SpielergebnisT i p p     
2HeimAuswärtsHeimAuswärts FPFP2WFFP
30000 4444
41100 2222
50011 2222
62121 4444
72110 3333
82030 1111
93010 1111
101214 1111
112112 0000
1202 2 0000
13000  0000
144 31 0000
151 32 0000
162111 0000
171211 0001
Formeln der Tabelle
F3 : =((VORZEICHEN(A3-B3)=VORZEICHEN(C3-D3))+(A3-C3=B3-D3)*(2+(A3=C3)*(B3=D3))-(A3=B3)*(B3<>C3))*(ANZAHL(A3:D3)=4)
G3 : =(((A3-B3<0)=(C3-D3<0))*((C3<>D3)+(A3=B3))+(A3-C3=B3-D3)*(2+(A3=C3)*(B3=D3))-(A3=B3)*(B3<>C3))*(ANZAHL(A3:D3)=4)
H3 : =(ANZAHL(A3:D3)=4)*((A3=C3)*(B3=D3)+(A3-B3-C3+D3=0)*2+(VORZEICHEN(A3-B3)=(VORZEICHEN(C3-D3)))-(A3=B3) *(C3=D3)*(A3<>C3))
I3 : =(((A3>B3)=(C3>D3))+(A3-C3=B3-D3)*(2+(A3=C3)*(B3=D3))-(A3=B3)*(B3<>C3))*(ANZAHL(A3:D3)=4)
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  


Servus aus dem Salzkammergut
Franz


  

Betrifft: AW: ich mich auch, aber... von: Josef B
Geschrieben am: 13.08.2008 20:34:58

Hallo Franz und alle
Auch ich habe in meinem "Archiv" eine Tippspiel -Lösung ohne die Funktion Vorzeichen gefunden,
und habe diese den Vorgaben angepasst.

=(((A3-B3)*(C3-D3)>-(A3=B3)*(C3=D3)*(B3=D3))+(A3-C3=B3-D3)*2+(A3=C3)*(B3=D3))*(ANZAHL(A3:D3)=4)

Gruss Sepp


  

Betrifft: Die gefällt mir :-) :-) :-) von: FP
Geschrieben am: 13.08.2008 20:44:03

Hallo Sepp,

einsame Klasse !!!

Servus aus dem Salzkammergut
Franz