Microsoft Excel

Herbers Excel/VBA-Archiv

Fehler in Formel SVERWEIS WENN | Herbers Excel-Forum


Betrifft: Fehler in Formel SVERWEIS WENN von: David
Geschrieben am: 16.10.2008 12:59:09

Hallo zusammen,

ich finde den Fehler in folgender Formel nicht:
Er markiert mir den letzten SVERWEIS bei der Fehlersuche.
Gibt es nen Limit für Anzahl SVERWEISE in einer Formel?
Sind doch auch nur 6 WENN-Funktionen.......benutze Excel 2002.

=WENN(D6="Clamp A Euro 9/16";SVERWEIS(A6;Matrix$A$25:$Z$93;16;FALSCH);WENN(D6="Clamp B Euro 9/16"; SVERWEIS(A6;Matrix$A$25:$Z$93;11;FALSCH);WENN(D6="Formteil";SVERWEIS(A6;Matrix$A$25:$Z$93; 6; FALSCH) ; WENN(FEHLER.TYP(WENN(D6="Formteil";SVERWEIS(A6;Matrix$A$25:$Z$93;6;FALSCH); WENN(D6="Clamp B Euro 9/16";SVERWEIS(A6;Matrix$A$25:$Z$93;11;FALSCH); WENN(D6="Clamp A Euro 9/16";<b>SVERWEIS</b>(A6;Matrix$A$25:$Z$93;16;FALSCH);""))) > 6);"Wert fehlt"; ""))))

Wäre für jede Anregung dankbar.

Viele Grüße

David

  

Betrifft: AW: Fehler in Formel SVERWEIS WENN von: Luschi
Geschrieben am: 16.10.2008 13:46:11

Hallo David,

wenn 'Matrix' ein Tabellenblatt ist, dann muß im SVerweis das so geschrieben werden:
Matrix!A$25:$Z$93. Zwischen Tabellenname und Zelladresse muß ein '!' stehen.

Gruß von Luschi
aus klein-Paris


  

Betrifft: AW: Fehler in Formel SVERWEIS WENN von: David
Geschrieben am: 16.10.2008 14:07:28

Hallo Luschi,

ja da hab ich nur den mega-langen verweis gelöscht. der stimmt normal schon.
auch das <b> vorm letzten sverweis ist ein html tag....

Amitiés à Paris


David


  

Betrifft: AW: Fehler in Formel SVERWEIS WENN von: heikoS
Geschrieben am: 16.10.2008 14:48:50

Hallo David,

ich habe Deine Formel ´mal etwas gekürzt:

=wenn(d6="";"Wert fehlt";wenn(D6="Clamp A Euro 9/16";SVERWEIS(A6;Matrix!$A$25:$Z$93;16;); WENN(D6="Clamp B Euro 9/16"; SVERWEIS(A6;Matrix!$A$25:$Z$93;11;);WENN(D6="Formteil";SVERWEIS(A6; Matrix!$A$25:$Z$93;6;))))

Was passiert jetzt?


Gruß Heiko


  

Betrifft: AW: Fehler in Formel SVERWEIS WENN von: David
Geschrieben am: 16.10.2008 14:57:38

Hallo Heiko,

das triffts leider nicht ganz:

was ich möchte ist:

a) wenn D6="Clamp A Euro 9/16" -> suche wert per sverweis
b) wenn D6="Clamp B Euro 9/16" -> "
c) wenn D6="Formteil" -> "
wenn a,b,c nicht zutreffen (ergibt das #NV) dann gib für fehler.typ >6 (->#NV)
"Wert fehlt" aus.

Hoffe das ist verständlich.

Danke im Voraus.


David


  

Betrifft: AW: Fehler in Formel SVERWEIS WENN von: Rudi Maintaire
Geschrieben am: 16.10.2008 15:03:09

Hallo,
evtl. so?
=WENN(ODER(D6={"Formteile"."Clamp B Euro 9/16"."Clamp A Euro 9/16"});SVERWEIS(A6;A25:Z94; VERGLEICH(D6;{"Formteile"."Clamp B Euro 9/16"."Clamp A Euro 9/16"};0)*5+1;);"nicht vorhanden")

Gruß
Rudi


  

Betrifft: AW: Fehler in Formel SVERWEIS WENN von: David
Geschrieben am: 16.10.2008 15:21:06

Rudi,

super, das triffts fast genau. habe sie jetzt so hingefriemelt, dass sie
mir das richtige ergebnis jeweils liefert (auch wenn ich die formel für den
spaltenindex nicht verstehe).
aber "nicht vorhanden" wirft er nicht aus, da steht dann wieder #NV, was
ich ja eleminieren wollte.


  

Betrifft: AW: Fehler in Formel SVERWEIS WENN von: Rudi Maintaire
Geschrieben am: 16.10.2008 17:39:31

Hallo,
dann so:
=WENN(UND(ZÄHLENWENN(A25:A94;A6)>0;ODER(D6={"Formteile"."Clamp B Euro 9/16"."Clamp A Euro 9/16"})); SVERWEIS(A6;A25:Z94; VERGLEICH(D6;{"Formteile"."Clamp B Euro 9/16"."Clamp A Euro 9/16"};0)*5+1;); "nicht vorhanden")

auch wenn ich die formel für den spaltenindex nicht verstehe)


Ist doch ganz einfach.
Es wird innerhalb der Matrix {"Formteile"."Clamp B Euro 9/16"."Clamp A Euro 9/16"} nach dem Wert in D6 gesucht. Ergibt bei 'Clamp A Euro 9/16' 3. 3*5+1=16

Gruß
Rudi


  

Betrifft: AW: Fehler in Formel SVERWEIS WENN von: David
Geschrieben am: 17.10.2008 14:32:36

Merci bcp.

habe es zwar nicht geblickt, aber es klappt :)
vergleich und {} sind mir fremd.

Gruß


David


  

Betrifft: @David: Matrixkonstante von: heikos
Geschrieben am: 17.10.2008 23:32:04

Hallo David,

was unser Rudi Dir mit den { } empfahl, waren sog. "Matrixkonstante".

Mit diesem Suchbegriff solltest Du im Archiv dieser HP sehr viele Einträge finden, die Dir weiterhelfen.

Sonst nimm einen einfachen sverweis wie z.B. =sverweis(a1;b1:c3;2;), dann markierst Du ´mal die Matrix "b1:c3" und drückst F9 ... und was macht Excel? Da sind sie, die { } .

Ok?


Gruß Heiko


Beiträge aus den Excel-Beispielen zum Thema "Fehler in Formel SVERWEIS WENN"