sverweis zwei Suchbegriffe: Index & Vergleich??

Forumthread: sverweis zwei Suchbegriffe: Index & Vergleich?

sverweis zwei Suchbegriffe: Index & Vergleich?

17.06.2017 11:55:24

Gregor

Hallo xlsx Gemeinde,
ich habe jetzt schon einige Stunden damit verbracht, diese Formel hinzubekommen, aber irgendwo habe ich einen Denkfehler.
Ich habe zwei Tabellen mit 2 Suchkriterien:
1x Datum (=Monat) & 1x Kundennummer
Das Datum steht einmal in Spalten (CuCO_all_formula) und auf einem anderen Blatt (=Erlöse_ReDatum) in einer Zeile;
zudem habe ich eine Kundennummer die beides Mal in Spalten steht.
Ich benötige den Wert, der sich aus der Schnittmenge ergibt.
Am besten, ihr seht euch das Beispiel im Anhang an.. ;)
Über verschachtelte Wenn-Formeln bekomme ich es hin, ist aber a.) nicht sehr sexy und b.) mehr als unübersichtlich; jetzt wollte ich es über eine index-Formel mit zwei Vergleichen lösen, aber ich bekomme immer ein #NV.
Vielen Dank im Voraus für euren Support.
lg Gregor
https://www.herber.de/bbs/user/114324.xlsx

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: ja, mit INDEX() und VERGLEICH(), allerdings...

17.06.2017 12:56:19

...

Hallo Gregor,
... Du musst dabei beachten, dass in den Kopfzeilen einer formatierten Tabelle nur Textwerte stehen können. Die Datumswerte sind also keine entsprechend formatierte Zahlen sondern Texte!
Deshalb folgende Formel in E4:
=INDEX(Tabelle17;VERGLEICH(B4;Tabelle17[clientID];0);VERGLEICH(TEXT(A4;"TT.MM.JJJJ");Tabelle17[#Kopfzeilen];0))
... und gugge ;-) Deine WENN()-Formelergebnisse entpuppen sich zusätzlich auch noch als inkorrekt.
Gruß Werner
.. , - ...

AW: ja, mit INDEX() und VERGLEICH(), allerdings...

17.06.2017 13:19:29

Gregor

Hallo Werner,
spitze, vielen vielen Dank für die schnelle Hilfe - funktioniert spitze!
Ich hatte mir schon gedacht, dass es an so etwas liegen könnte, wäre alleine aber nie draufgekommen...
Und wegen den Ergebnissen: Zum Glück habe ich die Datei noch nicht an unsere GF weitergeleitet... :D
Noch einmal vielen Dank und lg aus Wien
Gregor

index, vergleich, erste Ziffern = Monat

17.06.2017 14:46:11

Gregor

Hallo,
auf diesem Thema aufbauend, gleich die nächste Herausforderung - ich hoffe das ist so lösbar...
Kurze Beschreibung (am Beispiel im Anhang wird es hoffentlich deutlicher).
1. Vergleiche ClientID
2. Nimm die ersten beiden Ziffern in Zeile 3 und nimm das als Monat und vergleiche diesen Wert mit "CuCo_all_formula" Spalte A
3. und dann den Wert aus der betreffenden Spalte, der bei dem jeweiligen Monat steht (via Index Spalte?)
Und hier das (fortgesetzte) Beispiel:
https://www.herber.de/bbs/user/114328.xlsx
Vielen dank im Voraus für euren Input

AW: hier dann besser mit SVERWEIS() und ...

17.06.2017 20:17:13

...

Hallo Gregor,
... Du solltest die Bezeichnungen natürlich immer identisch haben.
Nachfolgende Formel kannst Du dann auch nach rechts kopieren (nachträglich nur das Format entsprechend anpassen) vorausgesetzt Du änderst die Überschriften (G3:I3) wie angegeben auch ab (zusätzliches Leerzeichen!):

	F	G	H	I
3	03 DBI	03 DB I %	03 DB II	03 DB II %
4	- 500	0%	- 1.500	0%
5	- 422	-237%	- 1.522	-856%
6	1.725	71%	525	22%
7	- 800	0%	- 2.100	0%
8	- 900	0%	- 2.300	0%
9	- 750	0%	- 2.000	0%
10	- 600	0%	- 1.700	0%
11	19.790	97%	18.640	91%

Formeln der Tabelle

Zelle	Formel
F4	=VERWEIS(9;1/(MONAT(Tabelle13411[Monat])=LINKS(F$3;2)*1)/(Tabelle13411[ClientID]=[@ClientID]); INDEX(Tabelle13411[[Monat]:[DB I %3]];;VERGLEICH(TEIL(F$3;4;99); Tabelle13411[#Kopfzeilen];)))

Gruß Werner
.. , - ...

AW: hier dann besser mit SVERWEIS() und ...

18.06.2017 11:01:08

Gregor

Hallo Werner,
und wieder, vielen vielen Dank - funktioniert spitze!
Never ever wäre ich auf diese bzw. überhaupt eine Lösung gekommen... :)
Wie gesagt, vielen lieben Dank und noch einen schönen Sonntag.
Gregor

AW: bitte und ...

18.06.2017 11:28:33

...

Hallo Gregor,
... beachte auch meinen eben eingestellten Ergänzungsbeitrag.
Auch Dir noch einen schönen Sonntag.
Gruß Werner
.. , - ...

AW: bitte und ...

18.06.2017 12:15:19

Gregor

Hi Werner,
habe das "Tool" eben nach deiner Ergänzung angepasst, so ist es um einiges besser nachzuvollziehen.
Nur habe ich anstatt den Bereich "CuCo_all_formula!I$4:I$45" zu fixieren, die Spalte der Tabelle verwendet "Tabelle13411[DBI ]", da sich die Zeilenanzahl von (in diesem Bsp) "DBI " jedenfalls erhöhen wird. Die Tabellenspalte bleibt auch beim Kopieren und (Formel) einfügen 'fixiert'.
Die Formel sieht jetzt so aus:
=VERWEIS(9;1/(MONAT(Tabelle13411[Monat])=LINKS(F$3;2)*1)/(Tabelle13411[ClientID]=[@ClientID]); Tabelle13411[DBI ])
Funktioniert super!
Vielen lieben Dank
Lg Gregor

AW: dazu ...

18.06.2017 13:21:22

...

Hallo Gregor,
... zu dieser jetzt von Dir genutzten Formel, hatte ich in meinem Beitrag um 11:24 geschrieben:
"... nach rechts kopiert, einer Änderung von Tabelle13411[DBI ] in der kopierten Zelle bedarf."
Und Du brauchst ja auch die Formel noch in G:I.
Deshalb mein Vorschlag mit den Bereich "CuCo_all_formula!I$4:I$45" zu arbeiten. Da dies der Bereich einer formatierten Tabelle (Tabelle13411) ist, passt sich die Formel auch bzgl. des Zeilenendes auch da an, wenn Du Zeilen anfügst.
Gruß Werner
.. , - ...

AW: Ah so, jetzt verstehe ich ....

18.06.2017 13:41:04

Gregor

Hallo Werner,
jetzt checke ich es...
Es sollte "CuCo_all_formula!$I4:$I45" anstatt "CuCo_all_formula!I$4:I$45" sein; ich Honk...
Eine (wahrscheinlich blöde) Frage noch; du würdest bis "I45" angeben, die Tabelle geht aber nur bis "I43", muss ich das so angeben damit ich Zeilen hinzufügen kann oder nehme ich als Bereich "CuCo_all_formula!$I4:$I43"?
Lg Gregor

AW: Deine Frage ist schnell erklärt ...

18.06.2017 19:32:07

...

Hallo Gregor,
... ich hatte vor dem Einstellen meines Formelvorschlages zum Testen mal zwei Zeilen eingefügt, um auch den Nachweis zu führen, dass der Adressbereich in der Formel sich anpasst und habe die so erweiterte Formel hier eingestellt. Also im Original Deiner Beispieldatei ist "CuCo_all_formula!$I4:$I43" ist ausreichend, aber Du könntest auch mit "CuCo_all_formula!$I4:$I45" arbeiten.
Deine Aussage: Es sollte "CuCo_all_formula!$I4:$I45" anstatt "CuCo_all_formula!I$4:I$45" sein allerdings verstehe ich momentan nicht. Beides ist doch das Gleiche bzw. sogar identisch.
Gruß Werner
.. , - ...

AW: in meinem Betreff sollte VERWEIS() stehen ...

18.06.2017 11:24:07

...

Hallo Gregor,
... da SVERWEIS() ja in meinem Formelvorschlag auch gar nicht vorkommt.
Die Kombination mit INDEX() hatte ich gestern auch nur vorgenommen, weil die Kurzform der VERWEIS()-Formel in F4:
=VERWEIS(9;1/(MONAT(Tabelle13411[Monat])=LINKS(F$3;2)*1)/(Tabelle13411[ClientID]=[@ClientID]); Tabelle13411[DBI ])
nach rechts kopiert, einer Änderung von Tabelle13411[DBI ] in der kopierten Zelle bedarf.
Aber wenn man den Ergebnisvektor der VERWEIS()-Formel mit der "klassischen" Zellbereichsdefinition vornimmt, ist das nicht notwendig, weil sich dann die Formel automatisch anpasst.

=VERWEIS(9;1/(MONAT(Tabelle13411[Monat])=LINKS(F$3;2)*1)/(Tabelle13411[ClientID]=[@ClientID]); CuCo_all_formula!I$4:I$45)
Allerdings beachte: Bei Formeln mit Bezug auf formatierte Tabellen, muss "normal" kopiert werden. Ein "ziehendes" kopieren verändert den jeweiligen Bezug.
Gruß Werner
.. , - ...

Beliebteste Forumthreads (12 Monate)

sverweis zwei Suchbegriffe: Index & Vergleich??

Forumthread: sverweis zwei Suchbegriffe: Index & Vergleich?

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

sverweis zwei Suchbegriffe: Index & Vergleich??

Forumthread: sverweis zwei Suchbegriffe: Index & Vergleich?

11 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread