Zeilenumbruch in Zelle entfernen

Daniel · 1970-01-01T00:00:00+00:00

Guten Morgen zusammen, ich habe folgendes Problem und steh gerade aufm Schlauch. Ich habe ein Tabelle ( Export aus einer Datenbank ) mit Text in Zellen die Zeilenumbrüche enthalten. Diese muss ich aufgrund eines Imports durch ein bestimmtes Zeichen ersetzen. Das funktioniert so lange bis in einer Zelle im Arbeitsblatt am Anfang des Zellinhaltes ein Zeilenumbruch vorkommt... Die bekomme ich nicht per Makro / bzw. Ersetzen 'ersetzt'. Hat mir jemand einen Tipp? Vielen Dank im Voraus und einen schönen Tag. Grüsse, Daniel

Hallo,
hier eine Version zum testen. (automatische Zeilenumbrüche werden nicht erkannt)

Sub BeispielCode()
Dim Regex As Object
Dim meAr()
Dim nCount&, MaxRow&
  
With Sheets("Tabelle1")

    MaxRow = .Cells(.Rows.Count, 1).End(xlUp).Row
    
    If MaxRow > 2 Then
        meAr = .Range("A2", .Cells(MaxRow, 1)).Value2
    Else
        meAr = .Range("A2", .Cells(MaxRow, 1)).Resize(, 2).Value2
        Redim Preserve meAr(1 To Ubound(meAr), 1 To 1)
    End If

    Set Regex = CreateObject("Vbscript.Regexp")
    
    With Regex
      .MultiLine = True
      .Pattern = "\n"
      .Global = True

      For nCount = 1 To Ubound(meAr)
        'ersetze Zeilenumbruch durch nichts oder ein anderes Zeichen 
         meAr(nCount, 1) = .Replace(meAr(nCount, 1), "")
      Next nCount
    
    End With
    
    .Range("A2").Resize(Ubound(meAr)) = meAr
End With
End Sub

Gruß Tino

Hallo,
vielleicht zu viele Daten im Bereich.
Versuchen wir es und Teilen den Bereich in Teilabschnitte auf.

Sub BeispielCode()
Dim Regex As Object
Dim meAr()
Dim nCount&, MaxRow&, lngTeil&, lngStep&
Dim rngBereich As Range
Set Regex = CreateObject("Vbscript.Regexp")

With Sheets("Tabelle1")

    MaxRow = .Cells(.Rows.Count, 1).End(xlUp).Row
    Set rngBereich = .Range("A2", .Cells(MaxRow, 1))
    
    lngStep = (MaxRow - 1) / 5
    
    With Regex
      .MultiLine = True
      .Pattern = "\n"
      .Global = True
    End With
      
      For lngTeil = 1 To MaxRow - 1 Step lngStep
        
        meAr = .Range(rngBereich(lngTeil, 1), rngBereich(lngTeil + lngStep - 1, 1)).Value2

        For nCount = 1 To Ubound(meAr)
          'ersetze Zeilenumbruch durch nichts oder ein anderes Zeichen 
           meAr(nCount, 1) = Regex.Replace(meAr(nCount, 1), "^")
        Next nCount
        
        rngBereich(lngTeil, 1).Resize(Ubound(meAr)) = meAr
        
        Erase meAr
      Next lngTeil

    
    
    
End With
End Sub

Gruß Tino

Forumthread: Zeilenumbruch in Zelle entfernen

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial

Zeilenumbruch in Excel-Zellen entfernen

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)