aus Excel PDF an E-Mail anhängen

Forumthread: aus Excel PDF an E-Mail anhängen

07.06.2013 18:40:20

Florian

Hallo liebe Mitglieder!
Ich habe eine Gesprächsnotiz in Excel 2010 erstellt. Diese möchte ich gerne in ein PDF umwandeln, und dann an eine E-Mail anhängen.
Das Ganze ist ja bereits in Excel als Standardfunktion vorhanden. "Datei, Speichern und Senden, als PDF-Datei senden"
Allerdings würde ich mir gern die Mausklicks sparen und einfach einen Button mit einem Makro direkt in die Gesprächsnotiz einfügen, so dass bei Druck auf den Button das Tabellenblatt als PDF an eine neue E-Mail in Outlook angefügt wird.
Es muss kein besonderer Betreff dort stehen und auch noch kein Empfänger eingegeben sein.
Ich wollte die Geschichte mit dem Makro-Recorder bewerkstelligen - das funktioniert aber nicht.
Habt ihr da ein kleines einfaches Makro für mich? Mit der Suche habe ich nichts gefunden und auch die Ergebnisse von Google sind nicht zufriedenstellend gewesen.
VBA-Kenntnisse habe ich so gut wie keine.
Ich bedanke mich schon mal im voraus.
Liebe Grüße
Florian

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread

Betreff

Datum

Anwender

AW: aus Excel PDF an E-Mail anhängen

08.06.2013 10:45:24

Tino

AW: aus Excel PDF an E-Mail anhängen

08.06.2013 10:45:24

Tino

Hallo,
kannst mal diesen Code testen, Kommentare stehen im Code.
Wenn Du nicht zurechtkommst, kannst Du dich ja noch einmal melden.

Sub Beispiel_PDF_Mail()
Dim sPathPDF$
Dim objOutlook As Object, objMail As Object

'PDF erstellen 
With ThisWorkbook
    
    'Pfad wo die PDF gespeichert werden soll, hier wo die Excel liegt 
    sPathPDF = IIf(Right$(.Path, 1) = "\", .Path, .Path & "\")
    
    'Pfad + PDF-File-Name, hier wird der Namer der Excel verwendet 
    sPathPDF = sPathPDF & Left(.Name, InStrRev(.Name, ".")) & "pdf"
    
    'oder so, mit anderen Dateinamen 
    'sPathPDF = sPathPDF & "Maine PDF Datei.pdf" 
    
    'Abfrage ob Datei ersetzt werden soll, bei nein Abbruch 
    If Dir(sPathPDF, vbNormal) <> "" Then
        If MsgBox("Vorhandene Datei ersetzen?", vbYesNo + vbQuestion) = vbNo Then
            Exit Sub
        End If
    End If
    
    'ges. Datei als PDF speichern ******************************************** 
    .ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
        sPathPDF, Quality:=xlQualityStandard, _
        IncludeDocProperties:=False, IgnorePrintAreas:=False, OpenAfterPublish:=False

'    'nur eine Tabelle als PDF *********************************************** 
'    Tabelle1.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
'        sPathPDF, Quality:=xlQualityStandard, IncludeDocProperties:= _
'        False, IgnorePrintAreas:=False, OpenAfterPublish:=False 

'    'nur eine bestimmte Seite auf der Tabelle als PDF, hier Seite 1 bis 1 *** 
'    Tabelle1.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
'        sPathPDF, Quality:=xlQualityStandard, IncludeDocProperties:= _
'        False, IgnorePrintAreas:=False, From:=1, To:=1, OpenAfterPublish:=False 

End With

'Mail erstellen ************************************ 
Set objOutlook = CreateObject("Outlook.Application")
Set objMail = objOutlook.CreateItem(0)
With objMail
    .To = "Mustermann@MusterProviter.de" 'An-Empfänger 
    .CC = "" 'Cc-Empfänger 
    .BCC = "" 'BCc-Empfänger 
    .Subject = "Betreff" 'Betreff 
    .Body = "Mail Nachricht" 'Nachricht 
    .Attachments.Add sPathPDF 'Anlage 
    .Display 'Mail anzeigen 
End With


Set objMail = Nothing
Set objOutlook = Nothing
End Sub

Gruß Tino

Infobox / Tutorial

PDF aus Excel erstellen und per E-Mail versenden

Schritt-für-Schritt-Anleitung
Häufige Fehler und Lösungen
Alternative Methoden
Praktische Beispiele
Tipps für Profis
FAQ: Häufige Fragen

Schritt-für-Schritt-Anleitung

Excel-Dokument vorbereiten: Stelle sicher, dass deine Gesprächsnotiz in Excel 2010 vollständig ausgefüllt ist.
VBA-Editor öffnen: Drücke ALT + F11, um den VBA-Editor zu öffnen.
Neues Modul hinzufügen:
- Klicke im Menü auf Einfügen und wähle Modul.

Makrocode einfügen: Kopiere den folgenden VBA-Code und füge ihn in das Modul ein:

Sub Beispiel_PDF_Mail()
   Dim sPathPDF$
   Dim objOutlook As Object, objMail As Object

   'PDF erstellen 
   With ThisWorkbook
       sPathPDF = IIf(Right$(.Path, 1) = "\", .Path, .Path & "\")
       sPathPDF = sPathPDF & Left(.Name, InStrRev(.Name, ".")) & "pdf"
       .ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
           sPathPDF, Quality:=xlQualityStandard, _
           IncludeDocProperties:=False, IgnorePrintAreas:=False, OpenAfterPublish:=False
   End With

   'Mail erstellen 
   Set objOutlook = CreateObject("Outlook.Application")
   Set objMail = objOutlook.CreateItem(0)
   With objMail
       .To = "Mustermann@MusterProviter.de" ' An-Empfänger
       .Subject = "Gesprächsnotiz"
       .Body = "Hier ist die angehängte PDF."
       .Attachments.Add sPathPDF ' Anlage
       .Display ' Mail anzeigen
   End With

   Set objMail = Nothing
   Set objOutlook = Nothing
End Sub

Makro ausführen: Schließe den VBA-Editor und kehre zu Excel zurück. Führe das Makro über Entwicklertools > Makros aus.
E-Mail überprüfen: Eine neue E-Mail wird in Outlook geöffnet, die PDF-Datei ist angehängt.

Häufige Fehler und Lösungen

PDF an E-Mail anhängen funktioniert nicht: Stelle sicher, dass der Pfad für die PDF-Datei korrekt ist und dass Outlook installiert ist.
E-Mail nicht gesendet: Überprüfe, ob Outlook korrekt konfiguriert ist und ob du verbunden bist.
Makro wird nicht ausgeführt: Stelle sicher, dass die Makros in Excel aktiviert sind (Datei > Optionen > Sicherheitscenter > Einstellungen für das Sicherheitscenter).

Alternative Methoden

Falls Du kein VBA verwenden möchtest, gibt es auch eine manuelle Methode:

PDF speichern: Gehe zu Datei > Speichern unter, wähle PDF als Dateiformat und speichere die Datei.
E-Mail öffnen: Öffne Outlook und erstelle eine neue E-Mail.
PDF anhängen: Klicke auf Anfügen, wähle die gespeicherte PDF-Datei aus und sende die E-Mail.

Praktische Beispiele

Gesprächsnotiz in PDF umwandeln: Nutze die oben beschriebenen Schritte, um eine Gesprächsnotiz als PDF zu erstellen und zu versenden.
Formelsammlung speichern: Erstelle eine Formelsammlung in Excel und verwende das Makro, um sie direkt als PDF an eine E-Mail anzuhängen.

Tipps für Profis

Automatisierung: Du kannst das Makro so anpassen, dass es eine Liste von Empfängern durchläuft und individuelle E-Mails mit unterschiedlichen PDFs versendet.
Fehlerbehandlung: Füge im Makro eine Fehlerbehandlung hinzu, um sicherzustellen, dass Dein Code nicht bei einem Fehler abbricht.
E-Mail-Formatierung: Experimentiere mit der Formatierung des E-Mail-Inhalts, um professioneller auszusehen.

FAQ: Häufige Fragen

1. Wie kann ich eine E-Mail in PDF umwandeln? Du kannst eine E-Mail in Outlook öffnen und die Funktion Drucken nutzen, um die E-Mail als PDF zu speichern.

2. Ist es möglich, mehrere PDFs gleichzeitig zu versenden? Ja, du kannst das Makro so anpassen, dass es mehrere PDFs erstellt und diese in einer E-Mail anhängt.

3. Funktioniert das auch mit anderen Excel-Versionen? Ja, die meisten Schritte sind auch auf neueren Excel-Versionen anwendbar, es kann jedoch geringfügige Unterschiede in der Benutzeroberfläche geben.

Beliebteste Forumthreads (12 Monate)

aus Excel PDF an E-Mail anhängen

Forumthread: aus Excel PDF an E-Mail anhängen

1 Beitrag zum Forumthread Beitrag zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial

PDF aus Excel erstellen und per E-Mail versenden

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread