Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1572to1576
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Ausgewählte Excel-Blätter einzeln als PDF

Ausgewählte Excel-Blätter einzeln als PDF
21.08.2017 16:03:21
Leif
Hallo zusammen,
ich habe das Internet durchsucht und leider keine Lösung gefunden. Ich möchte gerne aus einer Datei mit ca. 20 Tabellenblättern einige Blätter als PDF einzeln mit dem jeweiligen Blattnamen speichern.
So heißt beispielsweise ein Blatt KST-Linie oder KST-Dry. Wobei diese immer gleich und vergeben werden. Sprich dies könnte fest vorgegeben werden.
Der Pfand, in dem diese gespeichert werden, soll dabei zuvor ausgewählt werden.
Bei diesem Code bekomme ich immer einen Timeout! Vielleicht mag mir einer helfen, ich bin dafür nicht erfahren genug.
Sub PDF()
Dim lsheet As Integer
For lsheet = 1 To ActiveWorkbook.Worksheets.Count
With Worksheets(lsheet)
If Not IsEmpty(.UsedRange) Then
.ExportAsFixedFormat _
Type:=xlTypePDF, _
Filename:="M:\Controlling\CTRL-FM\Ab_2017\Vodafone_Stammdaten_und_Reports\ _
Report an KST\" & .Name & ".pdf", _
Quality:=xlQualityStandard
End If
End With
Next lsheet
End Sub

9
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Ausgewählte Excel-Blätter einzeln als PDF
21.08.2017 16:30:16
Nepumuk
Hallo Leif,
ich hab gerade keine Lust deinen Pfad nachzubauen. Teste maL
Option Explicit

Public Sub PDF()
    Dim lsheet As Integer
    For lsheet = 1 To ThisWorkbook.Worksheets.Count
        With Worksheets(lsheet)
            If Not IsEmpty(.UsedRange) Then
                .ExportAsFixedFormat Type:=xlTypePDF, Filename:="M:\Controlling\ " & _
                    "CTRL-FM\Ab_2017\Vodafone_Stammdaten_und_Reports\Report an KST\" & _
                    .Name & ".pdf", Quality:=xlQualityStandard
                DoEvents
            End If
        End With
    Next lsheet
End Sub

Gruß
Nepumuk
Anzeige
AW: Ausgewählte Excel-Blätter einzeln als PDF
22.08.2017 09:54:15
Leif
Hallo Nepumuk,
leider bekomme ich bei dem Code folgenden Fehler gemeldet.
Es wäre auch toll, wenn man einzelne Tabellenblätter auswählen könnte (fest definiert).
Gruß und Danke
Userbild
AW: Ausgewählte Excel-Blätter einzeln als PDF
22.08.2017 10:26:43
Nepumuk
Hallo Leif,
da hat sich im Pfad ein Leerzeichen eingschlichen. Sorry.
Teste mal:
Public Sub PDF()
    Dim ialngIndex As Long
    Dim avntSheetArray As Variant
    avntSheetArray = Array("Tabelle1", "Tabelle2", "Tabelle3") 'diese Tabellen drucken - anpassen !!!
    For ialngIndex = 0 To UBound(avntSheetArray)
        With Worksheets(avntSheetArray(ialngIndex))
            If Not IsEmpty(.UsedRange) Then
                .ExportAsFixedFormat Type:=xlTypePDF, Filename:="M:\Controlling\" & _
                    "CTRL-FM\Ab_2017\Vodafone_Stammdaten_und_Reports\Report an KST\" & _
                    .Name & ".pdf", Quality:=xlQualityStandard
                DoEvents
            End If
        End With
    Next
End Sub

Gruß
Nepumuk
Anzeige
AW: Ausgewählte Excel-Blätter einzeln als PDF
22.08.2017 10:43:57
Leif
Hallo Nepumuk,
das klappt jetzt. Danke.
Leider bekomme ich nach dem erstellen des 9. PDF folgende Fehlermeldung:
Userbild
AW: Ausgewählte Excel-Blätter einzeln als PDF
22.08.2017 11:07:34
Nepumuk
Hallo Leif,
kannst du die Tabelle manuell als PDF speichern oder bekommst du da auch eine Fehlermeldung?
Eventuell liegt es am Namen der Tabelle, wie lautet der?
Gruß
Nepumuk
AW: Ausgewählte Excel-Blätter einzeln als PDF
22.08.2017 11:21:12
Leif
Hey Nepumuk,
stimmt das Problem war die Bezeichnung, der Name war mit | getrennt. Das mag VBA gar nicht.
Vielen Dank für deine Hilfe, nun läuft es prima.
Allerdings stürzt nun nach dem Durchlauf des Makro das Excel ab!
Beste Grüße
Leif
Anzeige
AW: Ausgewählte Excel-Blätter einzeln als PDF
23.08.2017 08:44:43
Leif
Hey Nepumuk,
scheint nicht am Makro zu liegen.
Deine Programmierung weckt Begehrlichkeiten ;-)
Könnten man im Code auch einrichten, dass man den Ordner in den die PDF's gespeichert werden auswählen könnte?
Danke und Gruß
Leif
AW: Ausgewählte Excel-Blätter einzeln als PDF
23.08.2017 12:45:18
Nepumuk
Hallo Leif,
teste mal:
Option Explicit

Public Sub PDF()
    Dim ialngIndex As Long
    Dim avntSheetArray As Variant
    Dim strPath As String
    With Application.FileDialog(msoFileDialogFolderPicker)
        .AllowMultiSelect = False
        .InitialFileName = "M:\"
        .InitialView = msoFileDialogViewSmallIcons
        .Title = "Bitte Ordner auswählen"
        If .Show = -1 Then
            strPath = .SelectedItems(1)
            avntSheetArray = Array("Tabelle1", "Tabelle2", "Tabelle3")
            For ialngIndex = 0 To UBound(avntSheetArray)
                With Worksheets(avntSheetArray(ialngIndex))
                    If Not IsEmpty(.UsedRange) Then
                        .ExportAsFixedFormat Type:=xlTypePDF, Filename:=strPath & _
                            "\" & .Name & ".pdf", Quality:=xlQualityStandard
                        DoEvents
                    End If
                End With
            Next
        End If
    End With
End Sub

Gruß
Nepumuk
Anzeige
AW: Ausgewählte Excel-Blätter einzeln als PDF
24.08.2017 08:44:54
Leif
Hallo Nepumuk,
das funktioniert prima. Vielen Dank.
Dir ein schönes Wochenende.
Gruß
Leif

303 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige