Alle PDF Dateien an Mail hängen

Forumthread: Alle PDF Dateien an Mail hängen

15.06.2018 14:51:18

Philip

Hallo zusammen
Ich möchte eine Mail vorbereiten um zu senden, dazu möchte ich alle PDF Dateien in einem bestimmten Ordner als Anhang in die Mail. Die Namen der PDF Dateien ändern sich ständig. Ich habe schon gesucht habe jedoch nichts passendes gefunden.
Danke und Gruss

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Alle PDF Dateien an Mail hängen

15.06.2018 17:09:56

Nepumuk
AW: Alle PDF Dateien an Mail hängen

15.06.2018 17:10:40

Torsten
AW: Alle PDF Dateien an Mail hängen

15.06.2018 17:11:25

Torsten
AW: Alle PDF Dateien an Mail hängen

15.06.2018 22:34:25

Philip

AW: Alle PDF Dateien an Mail hängen

15.06.2018 17:09:56

Nepumuk

Hallo Philip,
ein Beispiel:

Option Explicit

Public Sub Beispiel()
    Const FOLDER_PATH As String = "H:\Dateien\PDF\" 'anpassen
    Dim strFilename As String
    Dim objOutlook As Object, objMail As Object

    Set objOutlook = CreateObject(Class:="Outlook.Application")
    Set objMail = objOutlook.CreateItem(0)

    With objMail

        .To = "mailadresse@provider.de" 'anpassen
        .Subject = "Betreff" 'anpassen
        .Body = "Hallo" 'anpassen

        strFilename = Dir$(FOLDER_PATH & "*.pdf")
        Do Until strFilename = vbNullString
            Call .Attachments.Add(FOLDER_PATH & strFilename)
            strFilename = Dir$
        Loop

        Call .Display 'nur anzeigen
        ' Call .Send 'direkt senden
    End With

    Set objMail = Nothing
    Set objOutlook = Nothing
End Sub

Gruß
Nepumuk

AW: Alle PDF Dateien an Mail hängen

15.06.2018 17:10:40

Torsten

Hi Philip,
habe einen Code gefunden und ihn nach deinen Beduerfnissen angepasst. Probiers mal aus. Bei mir hats funktioniert. Ist fuer Outlook.
Lass mich wissen, wie es laeuft.

Sub PDF_versenden()
Const strEmpfänger As String = "empfänger@woauch.immer"
Const strVerzeichnis As String = "C:\Users\torsten.wetzel\Desktop\Testfolder Excel 2\"
Dim Email As Object, OutApp As Object
Dim strFilename As String
Set OutApp = CreateObject("Outlook.Application")
strFilename = Dir(strVerzeichnis & "*.pdf")
Set Email = OutApp.CreateItem(0)
With Email
.To = strEmpfänger
.Subject = "Bla Bla"
.Body = "Bla Bla"
Do While strFilename  ""
.Attachments.Add strVerzeichnis & strFilename
.Display
strFilename = Dir
Loop
End With
Set Email = Nothing
End Sub

Gruss Torsten

AW: Alle PDF Dateien an Mail hängen

15.06.2018 17:11:25

Torsten

Nepomuk war schneller ;-)

AW: Alle PDF Dateien an Mail hängen

15.06.2018 22:34:25

Philip

Hallo zusammen
Ich habe den code von nepomuk verwendet. Funktioniert super.
Danke für die Hilfe.
Gruss

Beliebteste Forumthreads (12 Monate)

Forumthread: Alle PDF Dateien an Mail hängen

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread