Checkboxen unchecken

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
Bild

Betrifft: Checkboxen unchecken
von: Katrasenforense
Geschrieben am: 21.04.2015 18:45:54

Hi Forum,
bin VBA-Neuling und rätsel mich so durch.
Ich habe ein Arbeitsblatt, in dem ich mit ActiveX Checkbocken Zeilen ein- und ausblende. Ich möchte, dass grundsätzlich alle Checkboxen unchecked sind, also kein Haken drin ist, wenn die Arbeitsmappe geöffnet wird.
Lösungen, die ich gegoogelt habe, bewirken immer gar nichts... nicht mal eine Fehlermeldung, an der ich mich entlanghangeln könnte.
Hat jemand einen Tipp... Danke schon mal

Bild

Betrifft: AW: Checkboxen unchecken
von: Nepumuk
Geschrieben am: 21.04.2015 19:00:59
Hallo,
folgende Prozedur muss in das Modul "DieseArbeitsmappe":

Option Explicit

Private Sub Workbook_Open()
    Dim objOLEObject As OLEObject
    For Each objOLEObject In Tabelle1.OLEObjects 'TAbellenname anpassen !!!
        If TypeOf objOLEObject.Object Is MSForms.CheckBox Then _
            objOLEObject.Object.Value = False
    Next
End Sub


Gruß
Nepumuk

Bild

Betrifft: AW: Checkboxen unchecken
von: Daniel
Geschrieben am: 21.04.2015 19:01:07
Hi
wenn du die Checkboxen nicht umbenannt hast, probiere mal das im Modul "DieseArbeitsmappe"
bei "With Tabelle1" musst du für Tabelle1 ggf den passenden Codenamem einsetzen.
dass ist der Name des Tabellenblatts, der im Projektexplorer vor der Klammer steht


Private Sub Workbook_Open()
Dim x As Object
With Tabelle1
    For Each x In Tabelle1.OLEObjects
        If x.Name Like "CheckBox*" Then x.Object.Value = False
    Next
End With
End Sub

Gruß Daniel

Bild

Betrifft: AW: Checkboxen unchecken
von: Gerd L
Geschrieben am: 21.04.2015 20:05:14
Hi,
das With / End With kann man bei diesem Code getrost weglassen, weil es mehr als flüssig ist.
Gruß Gerd

Bild

Betrifft: AW: Checkboxen unchecken
von: Mullit
Geschrieben am: 21.04.2015 19:01:08
Hallo,
sollte so gehen:
Code in das Klassenmodul der Arbeitsmappe:

Option Explicit
Private Sub Workbook_Open()
  Dim objOLEObject As OLEObject
  For Each objOLEObject In Tabelle1.OLEObjects
      With objOLEObject
            If .progID = "Forms.CheckBox.1" Then _
               .Object.Value = False
      End With
  Next
End Sub

Gruß, Mullit

Bild

Betrifft: AW: Checkboxen unchecken
von: Mullit
Geschrieben am: 21.04.2015 19:08:50
Hallo @all,
Teufel, ich bin einfach zu langsam, aber der Fragesteller ist wenigstens mal gut versorgt...top...;-)
Gruß, Mullit

Bild

Betrifft: AW: Checkboxen unchecken
von: Katrasenforense
Geschrieben am: 21.04.2015 19:36:35
Besten Dank an Euch drei...
kam mir grad echt schon wieder blöd vor, weil alle drei Vorschläge nicht gingen.
Habe dann beim rumwurschteln gesehen, dass ich die Checkboxen via Zeichentools gruppiert hatte (zum ausrichten). Als ich die Gruppierung gelöst hatte, funktionierte es... hatte gerade die Lösung von Mullit am start und dann die Anderen dann nicht mehr ausprobiert.
Ich danke Euch für die Hilfe und komme in einem neuen Thread mit einer neuen Frage ;-)
Gruss... Katrasenforense

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Farbteppich über nicht ausgeblendeten Bereich"