Arbeitszeiten mit mehreren Bedingungen

Forumthread: Arbeitszeiten mit mehreren Bedingungen

06.08.2006 16:19:19

Kurt

Hallo,
ich habe folgende Tabelle
von bis Pause Arbeitszeit
8:00 20:00 1:00
Die komplette Arbeitszeit ist von 8:00 bis 20:00
Das Problem
von 8:00 bis 14:01 gibt es keine Zuschläge
von 14:01 bis 16:00 gibt es 20 %
und von 16:01 bis 20:00 gibt es 25 %
Ich habe schon mehrere wenn(und - Verknüpfungen probiert, doch immer wenn ich glaubte es geschafft zu haben erschien #WERT.
Vielleicht kann mir ja jemand helfen.
Vielen Dank im Voraus

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Arbeitszeiten mit mehreren Bedingungen

06.08.2006 16:59:04

Josef

Hallo Kurt!
Ein Ansatz.

Tabelle1

	A	B	C	D	E	F	G	H	I
1	Beginn	Ende	Pause	Arbeitszeit	davon + 20%	davon + 25%	Brutto	Stundensatz:=	22,00
2	07:00	16:15	01:00	08:15	02:00	00:15	191,68
3	06:45	21:15	01:30	13:00	02:00	05:15	323,68
4	08:00	15:30	00:45	06:45	01:30	00:00	155,10

Formeln der Tabelle

D2 : =B2-A2-C2
E2 : =SUMMENPRODUKT((ZEILE($1:$1439)<B2*1440)*(ZEILE($1:$1439)>=ZEITWERT("14:00")*1440)*(ZEILE($1:$1439)<=ZEITWERT("15:59")*1440))/1440
F2 : =SUMMENPRODUKT((ZEILE($1:$1439)<B2*1440)*(ZEILE($1:$1439)>=ZEITWERT("16:00")*1440))/1440
G2 : =((D2*24)*$I$1)+((E2*24)*($I$1*0,2))+((F2*24)*($I$1*0,25))
D3 : =B3-A3-C3
E3 : =SUMMENPRODUKT((ZEILE($1:$1439)<B3*1440)*(ZEILE($1:$1439)>=ZEITWERT("14:00")*1440)*(ZEILE($1:$1439)<=ZEITWERT("15:59")*1440))/1440
F3 : =SUMMENPRODUKT((ZEILE($1:$1439)<B3*1440)*(ZEILE($1:$1439)>=ZEITWERT("16:00")*1440))/1440
G3 : =((D3*24)*$I$1)+((E3*24)*($I$1*0,2))+((F3*24)*($I$1*0,25))
D4 : =B4-A4-C4
E4 : =SUMMENPRODUKT((ZEILE($1:$1439)<B4*1440)*(ZEILE($1:$1439)>=ZEITWERT("14:00")*1440)*(ZEILE($1:$1439)<=ZEITWERT("15:59")*1440))/1440
F4 : =SUMMENPRODUKT((ZEILE($1:$1439)<B4*1440)*(ZEILE($1:$1439)>=ZEITWERT("16:00")*1440))/1440
G4 : =((D4*24)*$I$1)+((E4*24)*($I$1*0,2))+((F4*24)*($I$1*0,25))

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download

Gruß Sepp

AW: Arbeitszeiten mit mehreren Bedingungen

06.08.2006 17:06:33

Luschi

Hallo Josef,
wenn der Arbeiter in dem 2. Beispiel die Pause aber von 16:01 bis 17:31 macht, wie muß dann die Formel lauten
fragt sich Luschi
aus klein-Paris?

AW: Arbeitszeiten mit mehreren Bedingungen

06.08.2006 17:55:50

Kurt

Hallo Sepp,
vielen Dank für deine schnelle Hilfe. Leider funktionieren die Formeln nur , wenn die Anfangszeit vor 14:00 ist. In meinem Fall kann die Anfangszeit aber auch nach 14:00 bzw. sogar nach 16:00 sein.
Kurt

AW: Arbeitszeiten mit mehreren Bedingungen

06.08.2006 18:53:11

Josef

Hallo Kurt!
Dann kann man das ganze mit dieser Formel realisieren.
http://www.excelformeln.de/formeln.html?welcher=9

Gruß Sepp

AW: Arbeitszeiten mit mehreren Bedingungen

06.08.2006 21:23:51

Josef

Hallo Sepp u.Kurt
Im Beispiel von Sepp in E2:
=MAX(0;MIN(B2;2/3)-MAX(A2;7/12))
In F2
=MAX(0;B2-MAX(A2;2/3))
und die Formeln nach unten Kopieren.
Gruss Josef

Meinst Du wirklich ;-)

06.08.2006 23:06:09

Hallo Sepp,
Ganz so einfach ist es denn doch nicht ;-)
Ich habe hier 2 Lösungen gebastelt:
1) mit Berücksichtigung der Pause bei den Zuschlägen
1 Stunde soferne die Arbeitszeit mehr als 4,5 Stunden beträgt und die nach einer Zeit von 3,5 Stunden angetreten wird
2) ohne Berücksichtigung der Pause bei den Zuschlägen

Tabelle2

	A	B	C	D	E	F	G	H	I	J	K
1	14:00	16:00	18:00	03:30	01:00	<- Pause nach 3,5 Stunden				ohne Pause
2	Beg	End1	Beg2	End	Pau	AZ	20%	25%		20%	25%
3	04:00	07:30	08:30	14:00	01:00	09:00	00:00	00:00		00:00	00:00
4	10:00	14:00	14:00	14:00	00:00	04:00	00:00	00:00		00:00	00:00
5	08:00	11:30	12:30	15:45	01:00	06:45	01:45	00:00		01:45	00:00
6	14:30	18:00	19:00	23:00	01:00	07:30	01:30	02:00		01:30	02:00
7	14:30	15:59	15:59	15:59	00:00	01:29	01:29	00:00		01:29	00:00
8	12:00	15:30	16:30	22:00	01:00	09:00	01:30	01:30		02:00	02:00
9	12:00	15:30	16:30	17:30	01:00	04:30	01:30	01:00		02:00	01:30
10	16:30	20:00	21:00	02:00	01:00	08:30	00:00	01:30		00:00	01:30
11	15:00	18:30	19:30	01:00	01:00	09:00	01:00	02:00		01:00	02:00
12	18:00	21:30	22:30	03:00	01:00	08:00	00:00	00:00		00:00	00:00
13	22:00	01:30	02:30	08:00	01:00	09:00	00:00	00:00		00:00	00:00
14	07:00	10:30	11:30	19:00	01:00	11:00	02:00	02:00		02:00	02:00

Formeln der Tabelle

B3 : =REST(C3-(C3<D3+(A3>D3))*E$1;1)
C3 : =REST(MIN(A3+D$1+E$1;D3+(A3>D3));1)
E3 : =C3-B3
F3 : =D3+(A3>D3)-A3-E3
G3 : =MAX(;MIN(B$1;B3+(A3>B3))-MAX(A$1;A3))+MAX(;MIN(B$1;B3+0)-A$1)*(A3>B3)+MAX(;MIN(B$1;D3+(C3>D3))-MAX(A$1;C3))+MAX(;MIN(B$1;D3+0)-A$1)*(C3>D3)
H3 : =MAX(;MIN(C$1;B3+(A3>B3))-MAX(B$1;A3))+MAX(;MIN(C$1;B3+0)-B$1)*(A3>B3)+MAX(;MIN(C$1;D3+(C3>D3))-MAX(B$1;C3))+MAX(;MIN(C$1;D3+0)-B$1)*(C3>D3)
J3 : =MAX(;MIN(B$1;D3+(A3>D3))-MAX(A$1;A3))+MAX(;MIN(B$1;D3+0)-A$1)*(A3>B3)
K3 : =MAX(;MIN(C$1;D3+(A3>D3))-MAX(B$1;A3))+MAX(;MIN(C$1;D3+0)-B$1)*(A3>D3)

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Servus aus dem Salzkammergut
Franz

AW: Arbeitszeiten mit mehreren Bedingungen

06.08.2006 22:04:48

ingUR

Hallo, Kurt,
aufbauend auf Sepps Vorarbeit habe ich folgenden Vorschlag mit Zellenformel, wobei jedoch die Arbeitszeitpausen moch nicht in dem Formeln berücksichtigt wurden, da aus den Angaben nicht zu erkennen ist, zu welcher Zuschlagsgruppe sie zu zählen sind!

	A	B	C	D	E	F	G	H
1					14:00	16:00	20:00	Stundensatz
2	Beginn	Ende	Pause	Arbeitszeit	100%	120%	125%	22
3	07:00	16:15	01:00	08:15	07:00	02:00	00:15	213,68
4	17:30	21:15	01:30	02:15	00:00	00:00	02:30	68,75
5	15:15	15:30	00:15	00:00	00:00	00:15	00:00	6,60
6					ohne Pausen!

Formeln der Tabelle

D3 : =B3-A3-C3
E3 : =WENN(B3<=$E$1;B3-A3;WENN($E$1-A3<=0;0;$E$1-A3))
F3 : =WENN(B3<=$F$1;WENN(B3-A3-E3<=0;0;B3-A3-E3);WENN($F$1-A3<=0;0;$F$1-A3-E3))
G3 : =WENN(B3<=$G$1;WENN(B3-A3-(E3+F3)<=0;0;B3-A3-(E3+F3));WENN($G$1-A3<=0;0;$G$1-A3-(E3+F3)))
H3 : =$H$2*SUMMENPRODUKT($E$2:$G$2;E3:G3)*24
D4 : =B4-A4-C4
E4 : =WENN(B4<=$E$1;B4-A4;WENN($E$1-A4<=0;0;$E$1-A4))
F4 : =WENN(B4<=$F$1;WENN(B4-A4-E4<=0;0;B4-A4-E4);WENN($F$1-A4<=0;0;$F$1-A4-E4))
G4 : =WENN(B4<=$G$1;WENN(B4-A4-(E4+F4)<=0;0;B4-A4-(E4+F4));WENN($G$1-A4<=0;0;$G$1-A4-(E4+F4)))
H4 : =$H$2*SUMMENPRODUKT($E$2:$G$2;E4:G4)*24
D5 : =B5-A5-C5
E5 : =WENN(B5<=$E$1;B5-A5;WENN($E$1-A5<=0;0;$E$1-A5))
F5 : =WENN(B5<=$F$1;WENN(B5-A5-E5<=0;0;B5-A5-E5);WENN($F$1-A5<=0;0;$F$1-A5-E5))
G5 : =WENN(B5<=$G$1;WENN(B5-A5-(E5+F5)<=0;0;B5-A5-(E5+F5));WENN($G$1-A5<=0;0;$G$1-A5-(E5+F5)))
H5 : =$H$2*SUMMENPRODUKT($E$2:$G$2;E5:G5)*24

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Gruß,
Uwe

Beliebteste Forumthreads (12 Monate)

Arbeitszeiten mit mehreren Bedingungen

Forumthread: Arbeitszeiten mit mehreren Bedingungen

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Arbeitszeiten mit mehreren Bedingungen

Forumthread: Arbeitszeiten mit mehreren Bedingungen

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread