ich bring's nicht fertig:
ich möchte von A nach B Dateien kopieren-
allerdings nur die, deren Änderungsdatum auf A jünger ist, als das Datum auf B
wenn Datei auf B noch nicht vorhanden, von A nach B kopieren
um Hilfe bittet
mit Gruß
Robert
Option Explicit
Sub Kopiere_Dateien()
Dim Fso, Ordner, varDatei
Dim SucheDatei As String, strDatei As String
Dim strPfad1 As String, strPfad2 As String
Dim F1, F2
strPfad1 = "J:\Quelle\" 'Quelle
strPfad2 = "J:\Ziel\" 'Ziel
SucheDatei = ".xls" 'welche Dateien?
Set Fso = CreateObject("Scripting.FileSystemObject")
Set Ordner = Fso.getfolder(strPfad1) 'Ordner Quelle
'Schleife über alle Dateien im Ordner
For Each varDatei In Ordner.Files
'Dateifilter, Platzhalter verwenden
If varDatei Like "*" & SucheDatei Then
strDatei = Right$(varDatei, Len(varDatei) - InStrRev(varDatei, "\"))
Set F1 = Fso.getfile(varDatei)
If Dir$(strPfad2 & strDatei) <> "" Then 'Datei in Ziel vorhanden?
Set F2 = Fso.getfile(strPfad2 & strDatei)
If F1.DateLastModified > F2.DateLastModified Then 'Datum letzte Änderung prüfen
F1.Copy (strPfad2 & strDatei) 'kopiere
End If
Else
F1.Copy (strPfad2 & strDatei) 'kopiere
End If
End If
Next varDatei
End Sub
Gruß Tino