Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1328to1332
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Zeilen ausblenden, wenn bestimmter Bereich leer

Zeilen ausblenden, wenn bestimmter Bereich leer
23.09.2013 11:04:23
Tim
Hallo an alle,
ich habe eine größere Tabelle und möchte folgenden Bereich untersuchen:
- jeweils die Spalten AS bis BB (also Spalte 45 bis Spalte 54) für jede Zeile
Wenn in einer Zeile in dem Bereich AS bis BB kein Eintrag steht, soll diese ausgeblendet werden. Befindet sich in diesem Bereich ein Eintrag, soll alles so stehen bleiben.
Kann mir dabei jemand bitte helfen?
Vielen Dank und viele Grüße
Tim

4
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Zeilen ausblenden, wenn bestimmter Bereich leer
23.09.2013 13:10:03
fcs
Hallo Tim,
ergänze in einer Spalte z.B. BC eine der folgenden Formeln in allen Zeilen.
Formel in BC2:
=ANZAHL2(AS2:BB2)=0
oder
=ZÄHLENWENN(AS2:BB2;"")=0

Danach kannst du per Filter die leeren Zeilen ausblenden, indem du im FilterDropdpwn den Wert WAHR abwählst.
Gruß
Franz

AW: Zeilen ausblenden, wenn bestimmter Bereich leer
23.09.2013 13:37:00
Tim
Hallo Franz,
dies ist leider nur meine zweite Alternative, da ich sonst alle vorherigen Makros ändern muss!
Funktioniert dies auch mit einem Makro?
Du hast mir schonmal bei einem ähnlichen Problem geholfen:
https://www.herber.de/forum/archiv/1328to1332/t1329522.htm
So in der Art sollte es auch aussehen, eben nur auf den beschriebenen anderen Bereich.
Viele Grüße
Tim

Anzeige
AW: Zeilen ausblenden, wenn bestimmter Bereich leer
23.09.2013 14:52:18
fcs
Hallo Tim,
ich hab das andere Makro jetzt auf die neuen Prüfbedingungen umgeschrieben.
Gruß
Franz
'Makro in einem allgemeinen Modul erstellt unter Excel 2010
Sub Zeilen_Ausblenden()
Dim wks As Worksheet, rngBereich As Range, rngKriterien As Range
Dim lngZeile_1 As Long, lngSpalte_1 As Long
Dim lngZeile_L As Long, lngSpalte_L As Long
Dim lngZeile As Long, StatusCalc As Long
StatusCalc = Application.Calculation
If MsgBox("Zeilen gemäß Kriterien ausblenden?", vbQuestion + vbOKCancel, _
"Z E I L E N   A U S B L E N D E N") = vbCancel Then GoTo Beenden
On Error GoTo Fehler
lngZeile_1 = 2
lngSpalte_1 = 45
lngSpalte_L = 54
Set wks = ActiveSheet
'Makrobremsen lösen
With Application
.ScreenUpdating = False
.Calculation = xlCalculationManual
.EnableEvents = False
End With
With wks
'Alle Zeilem einblenden
.Rows.Hidden = False
'letzte Zeile
Set rngBereich = .Cells.Find(What:="*", After:=.Cells(1, 1), LookIn:=xlFormulas, _
lookat:=xlWhole, searchOrder:=xlByRows, searchdirection:=xlPrevious)
If rngBereich Is Nothing Then
MsgBox "Keine Daten im Tabellenblatt", vbInformation + vbOKOnly, _
"Makro: Zeilen_Ausblenden"
GoTo Beenden
End If
lngZeile_L = rngBereich.Row
For lngZeile = lngZeile_L To lngZeile_1 Step -1
'relevanter Bereich
Set rngBereich = .Range(.Cells(lngZeile, lngSpalte_1), _
.Cells(lngZeile, lngSpalte_L))
'Prüfen der Anzahl Werte im relevanten Bereich
If Application.WorksheetFunction.CountA(rngBereich) = 0 Then
If rngKriterien Is Nothing Then
Set rngKriterien = .Cells(lngZeile, 1)
Else
Set rngKriterien = Application.Union(rngKriterien, .Cells(lngZeile, 1))
End If
End If
Next
If Not rngKriterien Is Nothing Then
rngKriterien.EntireRow.Hidden = True            'Zeilen ausblenden
End If
End With
Fehler:
With Err
Select Case .Number
Case 0 'alles OK
Case Else
MsgBox "Fehler-Nr.: " & .Number & vbLf & .Description, _
vbInformation + vbCritical + vbOKOnly, _
"Fehler - Makro Zeilen_Ausblenden"
End Select
End With
Beenden:
'Makrobremsen zurücksetzen
With Application
.ScreenUpdating = True
.Calculation = StatusCalc
.EnableEvents = True
End With
Set wks = Nothing: Set rngBereich = Nothing: Set rngKriterien = Nothing
End Sub

Anzeige
AW: Zeilen ausblenden, wenn bestimmter Bereich leer
23.09.2013 13:56:22
Rudi
Hallo,
bis letzte gefüllte in A:
Sub aaa()
Dim i As Long
Application.ScreenUpdating = False
For i = 1 To Cells(Rows.Count, 1).End(xlUp).Row
Rows(i).Hidden = WorksheetFunction.CountA(Cells(i, 45).Resize(, 10)) = 0
Next
End Sub

Gruß
Rudi

331 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige