Live-Forum - Die aktuellen Beiträge
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Formel auf mehrere Arbeitsblätter anwenden

Formel auf mehrere Arbeitsblätter anwenden
Philipp
Hallo!
Die unten stehende Formel bildet in einem anderen Arbeitsblatt (Name:Oghren) eine Summe, wenn verschiedenste Bedingungen gegeben sind und gibt diese im Feld M3 im Arbeitsblatt "Menelaos" wieder.
Die Formel funktioniert einwandfrei.
=WENN(Oghren!$V$6"";SUMMENPRODUKT((Oghren!$P$41:$P$90=$A3)*(Oghren!$Q$41:$Q$90="x") *(Oghren!$R$41:$R$90="yes");Oghren!$S$41:$S$90);0)
Mir stellt sich aber folgendes Problem:
Die gleiche Formel soll auch noch auf 7 weitere Arbeitsblätter angewendet werden und im gleichen Ergebnisfeld (Menelaos!M3) wiedergegeben werden.
Natürlich könnte ich einfach die Formel 8 mal hintereinander schreiben und jeweils die Namen der anderen Tabellenblätter einsetzen. Dies ist aber natürlich nicht besonders elegant, und ich befürchte,dass mir Excel auch irgendwann sagen wird, dass die Formel zu lang ist.
Hat jemand einen Vorschlag?
PS: Auch die anderen Namen der Arbeitsblätter sind nicht numerisch und auch nicht alphabetisch sortiert.
Es dankt für Eure Hilfe,
Philipp
Wir wissen nicht, wie d.and Blätter 1gbd wdn! orT
14.02.2011 21:12:25
Luc:-?
Gruß Luc :-?
AW: Wir wissen nicht, wie d.and Blätter 1gbd wdn! orT
14.02.2011 23:31:29
Philipp
Hi Luc!
Bin nicht ganz sicher, was Du nicht weißt, aber ich tippe mal auf die Namen der anderen Blätter.
Wenn dem so ist, hier sind sie:
Oghren
Nathaniel
Anders
Justice
Velanna
Alistair
Zevran
Morrigan
Ich hoffe, ich hab richtig geraten, damit Ihr nicht mehr raten müsst:)
Gruß
Pille
AW: Formel auf mehrere Arbeitsblätter anwenden
14.02.2011 23:43:16
Philipp
Hi Sepp!
Danke, dass ist wohl das, was ich suche!
Da werde ich dann mal ein bißchen probieren, aber folgende Frage bleibt noch:
{=SUMME((T(INDIREKT("'"&{"JensF"."WF"."Boris"}&"'!A"&ZEILE(1:100)))="x") *(T(INDIREKT("'"&{"JensF"."WF"."Boris"}&"'!B"&ZEILE(1:100)))="y") *(N(INDIREKT("'"&{"JensF"."WF"."Boris"}&"'!C"&ZEILE(1:100))))) }
Diese Formel findet sich in der Erklärung.
Ich meine zu wissen, dass Array-Klammern zu Beginn und Ende einer Formel nicht geschrieben, sondern mit STRG+SHIFT+EINGABE erstellt werden. Wie steht es aber mit den Array-Klammern, die in diesem Beispiel z.T. auch innerhalb der Formel zu finden sind?
Kannste noch mal?
Gruß
Pille
Anzeige
AW: Formel auf mehrere Arbeitsblätter anwenden
14.02.2011 23:46:06
Philipp
Für den Fall, dass die Frage nicht ganz klar gewesen sein sollte:
Wie schreibt man Array-Klammern, die innerhalb einer Formel und nicht am Anfang oder Ende auftauchen?
AW: Formel auf mehrere Arbeitsblätter anwenden
14.02.2011 23:54:39
Josef

Hallo Philipp,
die Klammern innerhalb der Formel musst du eingeben, die am Anfang und Ende werden Strg+Shift+Enter erzeugt.
Deine Formel könnte so aussehen.
Tabelle1

 B
5112

Formeln der Tabelle
ZelleFormel
B5{=SUMME((T(INDIREKT("'"&{"Oghren"."Nathaniel"."Anders"."Justice"."Velanna"."Alistair"."Zevran"."Morrigan"}&"'!P"&ZEILE($41:$90)))=$A3)*(T(INDIREKT("'"&{"Oghren"."Nathaniel"."Anders"."Justice"."Velanna"."Alistair"."Zevran"."Morrigan"}&"'!Q"&ZEILE($41:$90)))="x")*(T(INDIREKT("'"&{"Oghren"."Nathaniel"."Anders"."Justice"."Velanna"."Alistair"."Zevran"."Morrigan"}&"'!R"&ZEILE($41:$90)))="yes")*(N(INDIREKT("'"&{"Oghren"."Nathaniel"."Anders"."Justice"."Velanna"."Alistair"."Zevran"."Morrigan"}&"'!S"&ZEILE($41:$90)))))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Sepp

Anzeige
Und wenn man ...
15.02.2011 00:08:11
Josef

... zwei Namen für die Tabellennamen und die Zeilen vergibt, dann wird's übersichtlicher.
Tabelle1

 B
5112

Formeln der Tabelle
ZelleFormel
B5{=SUMME((T(INDIREKT("'"&_sheets&"'!P"&_rows))=$A3)*(T(INDIREKT("'"&_sheets&"'!Q"&_rows))="x")*(T(INDIREKT("'"&_sheets&"'!R"&_rows))="yes")*(N(INDIREKT("'"&_sheets&"'!S"&_rows))))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen
Namen in Formeln
ZelleNameBezieht sich auf
B5_rows=ZEILE(Tabelle1!$41:$90)
B5_sheets={"Oghren"."Nathaniel"."Anders"."Justice"."Velanna"."Alistair"."Zevran"."Morrigan"}
Namen verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

Gruß Sepp

Anzeige
AW: Und wenn man ...
15.02.2011 16:04:52
Philipp
Hallo Sepp!
Mal wieder 1000 Dank für Deine Hilfe!
Werde es heute nicht schaffen zu testen, aber ich gehe davon aus, dass das schon klappen wird!
Grüße,
Pille
AW: Und wenn man ...
18.02.2011 19:35:51
Philipp
Hallo Sepp!
Konnte heute Deinen Formelvorschlag einmal ausprobieren und es hat (erneut:)) hervorragend funktioniert.
Danke, dass Du mir geholfen hast.
Pille

328 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige