Zeile eines Formelergebnis ermitteln

Forumthread: Zeile eines Formelergebnis ermitteln

20.01.2016 10:41:03

Steffen

Liebe Excel Freunde,
ich habe folgendes Problem (siehe die angehängte xls).
https://www.herber.de/bbs/user/102899.xlsx
Es gibt Lager in mehreren Städten (Köln, Wiesbaden, Berlin - Spalte A) von denen ich zwei Orte anliefern kann (in DE und NL - Spalte B). In Splate C steht die PLZ des jeweiligen Orts. Spalte D zeigt die Spedition mit welcher ich die LIeferung vornehmen kann und die folgende Matrix zeigt Frachtraten für verschiedene Liefergrößen.
Im ersten Schritt ermittel ich welche der beiden Speditionen die günstigste Rate hat, abhängig von den Kriterien in Matrix A16:B19. Die Formel hierfür ist in Zelle A21 hinterlegt.
Jetzt meine Frage: mit welcher Formel kann ich ermitteln um welche Spedition es sich bei dem ermittelten Wert handelt?
Vielen Dank für eure Hilfe

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread

Betreff

Datum

Anwender

AW: Zeile eines Formelergebnis ermitteln

20.01.2016 11:04:40

Sepp

AW: Zeile eines Formelergebnis ermitteln

20.01.2016 11:04:40

Sepp

Hallo Steffen,
Tabelle1

	A	B	C	D	E	F	G	H	I	J	K
1	Ladeort	Bestimmungsland	Postleitzahl	Spedition	1 Kiste	2 Kisten	3 Kisten	4 Kisten	5 Kisten	6 Kisten	7 Kisten
2	Köln	Deutschland	33000	Sped. Karl	193,00	284,00	358,00	369,00	380,00	391,00	482,00
3	Köln	Deutschland	33000	Sped. Schmidt	198,00	289,00	363,00	374,00	385,00	396,00	487,00
4	Wiesbaden	Deutschland	33000	Sped. Karl	193,00	284,00	358,00	369,00	380,00	391,00	482,00
5	Wiesbaden	Deutschland	33000	Sped. Schmidt	177,00	262,00	316,00	337,00	348,00	358,00	407,00
6	Berlin	Deutschland	33000	Sped. Karl	177,00	262,00	316,00	337,00	348,00	358,00	407,00
7	Berlin	Deutschland	33000	Sped. Schmidt	182,00	267,00	321,00	342,00	353,00	363,00	412,00
8	Köln	Niederlande	8000	Sped. Karl	177,00	262,00	316,00	337,00	348,00	358,00	407,00
9	Köln	Niederlande	8000	Sped. Schmidt	187,00	272,00	326,00	347,00	358,00	368,00	417,00
10	Wiesbaden	Niederlande	8000	Sped. Karl	177,00	262,00	316,00	337,00	348,00	358,00	449,00
11	Wiesbaden	Niederlande	8000	Sped. Schmidt	207,00	292,00	346,00	367,00	378,00	388,00	479,00
12	Berlin	Niederlande	8000	Sped. Karl	177,00	262,00	316,00	337,00	348,00	358,00	449,00
13	Berlin	Niederlande	8000	Sped. Schmidt	173,00	258,00	312,00	333,00	344,00	354,00	445,00
14
15
16	Anzahl Kisten	4 Kisten
17	Ladeort	Berlin
18	Bestimmungsland	Niederlande
19	Postleitzahl	8000
20
21	Niedrigste Rate	333,00
22	Speditionen	Sped. Schmidt
23
24
25

Formeln der Tabelle

Zelle	Formel
B21	=WENNFEHLER(AGGREGAT(15;6;E2:K13/(E1:K1=B16)/(A2:A13=B17)/(B2:B13=B18)/(C2:C13=B19); 1); "")
B22	=WENNFEHLER(INDEX($D$2:$D$13;AGGREGAT(15;6;ZEILE($A$1:$A$12)/(INDEX($E$2:$K$13;;VERGLEICH($B$16;$E$1:$K$1;0))=$B$21)/($A$2:$A$13=B17)/($B$2:$B$13=B18)/($C$2:$C$13=B19); ZEILE(A1))); "")
B23	=WENNFEHLER(INDEX($D$2:$D$13;AGGREGAT(15;6;ZEILE($A$1:$A$12)/(INDEX($E$2:$K$13;;VERGLEICH($B$16;$E$1:$K$1;0))=$B$21)/($A$2:$A$13=B18)/($B$2:$B$13=B19)/($C$2:$C$13=B20); ZEILE(A2))); "")
B24	=WENNFEHLER(INDEX($D$2:$D$13;AGGREGAT(15;6;ZEILE($A$1:$A$12)/(INDEX($E$2:$K$13;;VERGLEICH($B$16;$E$1:$K$1;0))=$B$21)/($A$2:$A$13=B19)/($B$2:$B$13=B20)/($C$2:$C$13=B21); ZEILE(A3))); "")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Gruß Sepp

Beliebteste Forumthreads (12 Monate)

Zeile eines Formelergebnis ermitteln

Forumthread: Zeile eines Formelergebnis ermitteln

1 Beitrag zum Forumthread Beitrag zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread