Fußzeile per VBA

Forumthread: Fußzeile per VBA

Fußzeile per VBA

02.10.2008 13:27:36

Ingo

Hallo zusammen,
ich habe folgendes Problem. Meine Datei hat ausgedrucht 24 Seiten. In der Druckvorschau jeweils 12 untereinander und nochmal 12 daneben. Ich möchte gerne in die erste Säule die Fußzeile Zeitfenser_I und in die 2. säule die Fußzeile Zeitfenster _II einfügen. Die Beiden begriffe stehen auch jeweils in den Zellen B5 und G5.
Hilfe wäre super.
mfG
Ingo Christiansen

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Fußzeile per VBA

02.10.2008 16:34:12

fcs
AW: Fußzeile per VBA

02.10.2008 17:02:10

Ingo
AW: Fußzeile per VBA

02.10.2008 18:09:29

fcs

AW: Fußzeile per VBA

02.10.2008 16:34:12

fcs

Hallo Ingo,
abhängig von der Einstellung der Druckreihenfolge für die Seiten. Kannst du eines der beiden folgenden Makros verwenden.
Die Preview-Option kannst du weglassen oder auf False setzen, wenn alles wie gewünscht funktioniert
Gruß
Franz


Sub Druck_Special_1()
'Seitenreihenfolge: nach unten, dann rechts
Dim wks As Worksheet
Set wks = ActiveSheet
With wks
.PageSetup.RightFooter = .Range("B5").Text
.PrintOut from:=1, to:=12, Preview:=True
.PageSetup.RightFooter = .Range("G5").Text
.PrintOut from:=13, to:=24, Preview:=True
.PageSetup.RightFooter = ""
End With
End Sub
Sub Druck_Special_2()
'Seitenreihenfolge: nach rechts, dann unten
Dim wks As Worksheet, intPage As Integer
Set wks = ActiveSheet
With wks
For intPage = 1 To 24
If intPage Mod 2 = 1 Then
.PageSetup.RightFooter = .Range("B5").Text
Else
.PageSetup.RightFooter = .Range("G5").Text
End If
.PrintOut from:=intPage, to:=intPage, Preview:=True
Next
.PageSetup.RightFooter = ""
End With
End Sub

AW: Fußzeile per VBA

02.10.2008 17:02:10

Ingo

Hallo Franz,
Funktioniert prima!
Dankeschön!
Kann ich eigentlich die Anzahl der Seiten, wenn es mal nicht gerafe 24 sind irgendwie ermitteln und an eine variable übergeben?
mfG
Ingo Christiansen

AW: Fußzeile per VBA

02.10.2008 18:09:29

fcs

Hallo Ingo,
über die Anzahl horizontaler Seitenwechsel, kann man die Seitenzahl variable ermitteln.
Makros schauen dann wie folgt aus. Getestet mit Excel 2003
Gruß
Franz


Sub Druck_Special_1()
'Seitenreihenfolge: nach unten, dann rechts
Dim wks As Worksheet
Set wks = ActiveSheet
With wks
.PageSetup.RightFooter = .Range("B5").Text
.PrintOut from:=1, To:=.HPageBreaks.Count + 1, Preview:=True
.PageSetup.RightFooter = .Range("G5").Text
.PrintOut from:=.HPageBreaks.Count + 2, To:=2 * .HPageBreaks.Count + 2, Preview:=True
.PageSetup.RightFooter = ""
End With
End Sub
Sub Druck_Special_2()
'Seitenreihenfolge: nach rechts, dann unten
Dim wks As Worksheet, intPage As Integer
Set wks = ActiveSheet
With wks
For intPage = 1 To 2 * .HPageBreaks.Count + 2
If intPage Mod 2 = 1 Then
.PageSetup.RightFooter = .Range("B5").Text
Else
.PageSetup.RightFooter = .Range("G5").Text
End If
.PrintOut from:=intPage, To:=intPage, Preview:=True
Next
.PageSetup.RightFooter = ""
End With
End Sub

Beliebteste Forumthreads (12 Monate)

Forumthread: Fußzeile per VBA

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread