Live-Forum - Die aktuellen Beiträge
Datum
Titel
25.04.2024 18:41:19
vba Zeilen duplizieren ab aktiver Zeile bis letzte Zeile
25.04.2024 18:22:55
Zeilen mit bestimmtem Datum in andere Mappe übertragen
25.04.2024 18:14:45
VBA - Excell - Kopie und "Diebstahl" Schützen
25.04.2024 17:49:39
Bedingte Formatierung
Du findest keine passende Antwort auf Deine Frage?
Stelle Deine Frage in unserem Live-Forum
Anzeige
Archiv - Navigation
1340to1344
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1340to1344
1340to1344
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Größe und Position Diagramm

Größe und Position Diagramm
27.11.2013 10:08:29
Benni
Hallo zusammen,
würde gerne bei meinem Macro die Position und Größe des jeweiligen Diagramms vorgeben. Leider bekomme ich dies mit meinen VBA wissen nicht hin. Kann mir jemand von Euch helfen? 
Sub Diagramm()
Dim anzahl As Integer
anzahl = ActiveWorkbook.Sheets.Count
For x = 1 To anzahl
Windows("Auswertung.xlsm").Activate
Sheets.Item(x).Select
Range("D4:E5").Select
ActiveSheet.Shapes.AddChart.Select
ActiveChart.ChartType = xlXYScatterLinesNoMarkers
ActiveChart.SeriesCollection(1).Name = Sheets.Item(x).Range("H1")
ActiveChart.SeriesCollection(1).XValues = Sheets.Item(x).Range("A4:A500")
ActiveChart.SeriesCollection(1).Values = Sheets.Item(x).Range("B4:B500")
ActiveChart.HasTitle = True
ActiveChart.ChartTitle.Characters.Text = "Einpresskraft"
ActiveChart.Axes(xlCategory, xlPrimary).HasTitle = True
ActiveChart.Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "Weg [mm]"
ActiveChart.Axes(xlValue, xlPrimary).HasTitle = True
ActiveChart.Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "Kraft [kN]"
ActiveChart.Axes(xlCategory).HasMajorGridlines = True
ActiveChart.HasLegend = True
ActiveChart.Axes(xlCategory).Select
ActiveChart.Axes(xlCategory).MinimumScale = 54
ActiveChart.Axes(xlCategory).MaximumScale = 58
ActiveChart.Axes(xlCategory).MajorUnit = 1
ActiveChart.ChartArea.Select
Next x
End Sub

Vielen Dank
Grüße
Benni

4
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Größe und Position Diagramm
27.11.2013 11:40:26
Beverly
Hi Benni,
Sub Diagramm()
Dim anzahl As Integer, x As Integer
anzahl = ActiveWorkbook.Sheets.Count
For x = 1 To anzahl
With Sheets.Item(x)
With .Shapes.AddChart(0, 0, 0, 0).Chart
.ChartType = xlXYScatterLinesNoMarkers
.HasTitle = True
.ChartTitle.Characters.Text = "Einpresskraft"
.HasLegend = True
.Axes(xlValue, xlPrimary).HasTitle = True
.Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "Kraft [kN]"
With .Axes(xlCategory)
.HasTitle = True
.AxisTitle.Characters.Text = "Weg [mm]"
.HasMajorGridlines = True
.MinimumScale = 54
.MaximumScale = 58
.MajorUnit = 1
End With
With .SeriesCollection.NewSeries
.Name = Sheets.Item(x).Range("H1")
.XValues = Sheets.Item(x).Range("A4:A500")
.Values = Sheets.Item(x).Range("B4:B500")
End With
With .Parent
.Top = Sheets(x).Rows(2).Top        ' Position oben
.Left = Sheets(x).Columns(3).Left   ' Position links
.Width = 450                        ' Breite
.Height = 250                       ' Höhe
End With
End With
End With
Next x
End Sub

Anzeige
AW: Größe und Position Diagramm
29.11.2013 12:51:48
Benni
Hallo Beverly,
vielen Dank für deine Hilfe!
Bei dem Macro funktioniert die Darstellung im Diagramm nicht. Hier werden mehere Datenreihen in dem Diagramm angezeigt. Die Reihenname sowie Y-Werte verweisen auf die fasche Adresse (A1:A2 // A3:A500).
Könntest Du mir vielleicht weiterhelfen? Konnte das Problem leider nicht selber lösen.
Vielen Dank
Benni

AW: Größe und Position Diagramm
29.11.2013 13:09:46
Beverly
Hi Benni,
das hängt damit zusammen, dass dein Cursor in einem Zellbereich steht, den Excel als Wertebereich interpretieren kann. Setze den Cursor in einen Zellbereich ohne Inhalte, oder ändere den Code wie folgt:
Sub Diagramm()
Dim anzahl As Integer, x As Integer
Dim lngReihen As Long
anzahl = ActiveWorkbook.Sheets.Count
For x = 1 To anzahl
With Sheets.Item(x)
With .Shapes.AddChart(0, 0, 0, 0).Chart
.ChartType = xlXYScatterLinesNoMarkers
.HasTitle = True
.ChartTitle.Characters.Text = "Einpresskraft"
.HasLegend = True
.Axes(xlValue, xlPrimary).HasTitle = True
.Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "Kraft [kN]"
With .Axes(xlCategory)
.HasTitle = True
.AxisTitle.Characters.Text = "Weg [mm]"
.HasMajorGridlines = True
.MinimumScale = 54
.MaximumScale = 58
.MajorUnit = 1
End With
            If .SeriesCollection.Count > 1 Then
For lngReihen = .SeriesCollection.Count To 1 Step -1
.SeriesCollection(lngReihen).Delete
Next lngReihen
End If
With .SeriesCollection.NewSeries
.Name = Sheets.Item(x).Range("H1")
.XValues = Sheets.Item(x).Range("A4:A500")
.Values = Sheets.Item(x).Range("B4:B500")
End With
With .Parent
.Top = Sheets(x).Rows(2).Top        ' Position oben
.Left = Sheets(x).Columns(3).Left   ' Position links
.Width = 450                        ' Breite
.Height = 250                       ' Höhe
End With
End With
End With
Next x
End Sub

Anzeige
AW: Größe und Position Diagramm
29.11.2013 13:34:41
Benni
Vielen Dank!

Beliebteste Forumthreads (12 Monate)

Anzeige
Jetzt das Excel-Portal bewerten: Deine Stimme zählt!

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige