Formel mit Abrage

Forumthread: Formel mit Abrage

Formel mit Abrage

20.05.2009 19:35:10

Lemmi

Hallo zusammen,
ich benötige eine Formel/ Verwies die nach einem Eintrag 1 in der Tabelle 1 in den Zellen H6-K1000 mit den Buschstaben A; B; C oder D herausgibt
Die Ausgabe findet in der Ausgabe- Tabelle statt!
Schaut vielleicht einmal!
https://www.herber.de/bbs/user/61955.xls
Gruß
Lemmi

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Formel mit Abrage

20.05.2009 20:32:25

Josef
AW: längere Formel

20.05.2009 20:44:43

Erich
AW: längere Formel

20.05.2009 23:11:30

Lemmi
ohne Zeile 4: mit WAHL

20.05.2009 23:28:49

WF
AW: oder mit ZEICHEN

21.05.2009 00:06:01

Erich
AW: oder mit TEIL

21.05.2009 00:21:24

Erich
AW: ohne Zeile 4: mit WAHL

21.05.2009 08:03:59

Lemmi
VERGLEICH mal drei

20.05.2009 20:49:21

WF
AW: mit Summenprodukt

21.05.2009 14:44:50

Daniel

AW: Formel mit Abrage

20.05.2009 20:32:25

Josef

Hallo Lemmi,
so?
Tabelle1

	G	H	I	J	K	L
5
6			1			B
7		1				A
8					1	D
9				1		C
10

Formeln der Tabelle

Zelle	Formel
L6	=ZEICHEN(64+VERGLEICH(1;H6:K6;0))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

Gruß Sepp

AW: längere Formel

20.05.2009 20:44:43

Erich

Hi Nick,
oder so? (viel länger als Sepps Formel, aber flexibler einsetzbar)
Abfrage- Tabelle

	F
6	C
7	B

Formeln der Tabelle

Zelle	Formel
F6	=WENN(ISTNV(VERGLEICH(1;BEREICH.VERSCHIEBEN(Tabelle1!H$5:K$5; VERGLEICH(A6;Tabelle1!A$6:A$30;0); 0); 0)); ""; INDEX(Tabelle1!H$4:K$4; VERGLEICH(1;BEREICH.VERSCHIEBEN(Tabelle1!H$5:K$5; VERGLEICH(A6;Tabelle1!A$6:A$30;0); 0); 0)))

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: längere Formel

20.05.2009 23:11:30

Lemmi

Hallo Erich,
ich möchte Deinen Vorschlag aufgreifen!
leider habe ich abweichend in meiner Arbeitsdatei nicht die Möglichkeit über den Index H4:K4 die Buchstaben mit den Inhalten A; B; C; D; in Zeile 4 zu plazieren!
Kann man das auch ohne die Referenzzelle hinbekommen?
Gruß
Lemmi

ohne Zeile 4: mit WAHL

20.05.2009 23:28:49

Hi,
die Formel von mir:
=WENN(ISTNV(VERGLEICH(1;INDIREKT("Tabelle1!h"&VERGLEICH(A6;Tabelle1!A:A;)&":K"&VERGLEICH(A6; Tabelle1!A:A;));));"";WAHL(VERGLEICH(1;INDIREKT("Tabelle1!h"&VERGLEICH(A6;Tabelle1!A:A;) &":K"&VERGLEICH(A6;Tabelle1!A:A;0)););"A";"B";"C";"D"))
oder die von Erich:
=WENN(ISTNV(VERGLEICH(1;BEREICH.VERSCHIEBEN(Tabelle1!H$5:K$5; VERGLEICH(A6;Tabelle1!A$6:A$30;0); 0); 0));"";WAHL(VERGLEICH(1;BEREICH.VERSCHIEBEN(Tabelle1!H$5:K$5; VERGLEICH(A6;Tabelle1!A$6:A$30;0); 0); 0);"A";"B";"C";"D"))
Salut WF

AW: oder mit ZEICHEN

21.05.2009 00:06:01

Erich

Hi Lemmi,
so ginge es auch (und damit ist Sepps Ansatz wieder da!):
Abfrage- Tabelle

	F
6	C
7	B

Formeln der Tabelle

Zelle	Formel
F6	=WENN(ISTNV(VERGLEICH(1;BEREICH.VERSCHIEBEN(Tabelle1!H$5:K$5; VERGLEICH(A6;Tabelle1!A$6:A$30;0); 0); 0)); ""; ZEICHEN(64+VERGLEICH(1;BEREICH.VERSCHIEBEN(Tabelle1!H$5:K$5; VERGLEICH(A6;Tabelle1!A$6:A$30;0); 0); 0)))

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: oder mit TEIL

21.05.2009 00:21:24

Erich

Hi,
TEIL kann das auch:
Abfrage- Tabelle

	C
6	C
7	B

Formeln der Tabelle

Zelle	Formel
C6	=WENN(ISTNV(VERGLEICH(1;BEREICH.VERSCHIEBEN(Tabelle1!H$5:K$5; VERGLEICH(A6;Tabelle1!A$6:A$30;0); 0); 0)); "";TEIL("ABCD";VERGLEICH(1;BEREICH.VERSCHIEBEN(Tabelle1!H$5:K$5; VERGLEICH(A6;Tabelle1!A$6:A$30;0); 0); 0); 1))

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: ohne Zeile 4: mit WAHL

21.05.2009 08:03:59

Lemmi

Hallo zusammen,
alles bestens!
Danke!
Gruß
Lemmi

VERGLEICH mal drei

20.05.2009 20:49:21

Hi,
in F6:
=INDEX(Tabelle1!$4:$4;VERGLEICH(1;INDIREKT("Tabelle1!H"&VERGLEICH(A6;Tabelle1!A:A;0) &":K"&VERGLEICH(A6;Tabelle1!A:A;0));0)+7)
Die Fehlermeldung bekommst Du selber weg.
Salut WF

AW: mit Summenprodukt

21.05.2009 14:44:50

Daniel

Hi
diese Formel, wenn die Tabelle genau so aufgebaut ist
- Kennzeichen für die auswahl ist die Zahl 1
- es ist immer nur eine Antwort zulässig
- Positionen stehen lückenlos ab Zeile 6 untereinander
=INDEX(Tabelle1!$4:$4;SUMMENPRODUKT(INDEX(Tabelle1!H:K;A6+5;);SPALTE(INDEX(Tabelle1!H:K;A6+5;))))

Positionen ohne Eintrage werden mit 0 gekennzeichnet
Gruß, Daniel

Beliebteste Forumthreads (12 Monate)

Forumthread: Formel mit Abrage

9 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread