Zeilen Zählen wenn Begriff vorkommt

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Danke,
lässt sich das nicht vielleicht auch ohne Hilfsspalte lösen? Die Auswertung erfolgt in einer separaten Tabelle, ich müsste außerdem mehrere Begriffe zählen, im Laufe der Zeit werden auch weitere hinzu kommen. Wenn es geht, würde ich nur ungerne die Tabelle mit einer Vielzahl Hilfsspalten aufblasen.
Bei künftigen Erweiterungen würde ich im Idealfall auch gerne pro Zählung nur den neuen Vergleichsbegriff austauschen müssen.

Betrifft: AW: Zeilen Zählen wenn Begriff vorkommt

Hi
ohne Hilfsspalte so
=SUMMENPRODUKT(1*(0<ZÄHLENWENN(BEREICH.VERSCHIEBEN(D1:N1;ZEILE(1:99)-1;0);"apfel")))
die Anzahl der zu durchsuchenden Zeilen solltest du bei "Zeile(...)" so genau wie möglich angeben.
Die Berechnungszeit wächst mit Anzahl der Zeilen und da die Formel volatil ist, Sollte man diese so kurz wie möglich halten.
Gruß Daniel

Betrifft: AW: Zeilen Zählen wenn Begriff vorkommt

Funktioniert sehr gut, danke!
Anknüpfend an deine Empfehlung mit der Zeilenzahl...:
Die Zeilenzahl wird sich im Laufe der Zeit erweitern. Ich passe also entweder regelmäßig an (was ich ungern möchte) oder bin großzügig mit der Angabe (was dem widerspricht, was du geraten hast).
Startzeile ist immer 4. Ich habe aufgrund einer anderen Auswertung bereits eine Zelle in einem anderen Arbeitsblatt, welche die befüllten und demnach die zu durchsuchenden Zeilen ermittelt.
Wenn das z.B. 48 Zeilen sind, und diese in Tabelle5!F15 gezählt wurden, wäre meine Endzeile Tabelle5!F15+4.
Kann man "Zeile(...)" so verwenden, dass excel sich den Wert füt die Endzeile holt?

Betrifft: AW: Zeilen Zählen wenn Begriff vorkommt
Kann man machen.
Wenn du eine Spalte hast, die durchgängig befüllt ist:
Zeile(A1:Index(A:A;Anzahl2(A:A)))
Bei nicht durchgängig gefüllten Spalten geht's auch, wird aber nochmal komplizierter.
Ich würde das dann auch in eine eigene Zelle auslagern.
Gruß Daniel

Betrifft: AW: wenn Du eine formatierte Tabelle hättest, ...

Hallo Sepp,
... welche auch meist einfach und schnell erstellt ist, besteht das "Problem" nicht. Dann könnte die Auswertungsformel für diese definiert werden. Diese Art Tabelle passt sich bei Datenerweiterung an (wird deswegen oft auch als "intelligente" bezeichnet) und damit auch die dafür so definierte Auswertungsformel.
Da Du momentan noch keine derartige Tabelle uns angeben konntest hier eine alternative Formel für eine noch nicht formatierte Tabelle, die ohne volatile Funktion auskommt:
=SUMMENPRODUKT(N(MMULT(--(D4:N999="Äpfel");ZEILE(D1:D11)^0)>0))
(Darin steht ZEILE(D1:D11) für die Anzahl der Spalten D:N)
Gruß Werner
.. , - ...

Betrifft: Eine zwar antike Formel, aber schnell
=SUMMENPRODUKT(1*ISTZAHL(SUCHEN("Apfel";
D1:D99&E1:E99&F1:F99&G1:G99&H1:H99&I1:I99&J1:J99&K1:K99&L1:L99&M1:M99&N1:N99)))

Betrifft: Frage und Antwort in Deinem Betreff...owT

Betrifft: wie meinst du das?
beiträge ohne Beitragtext sind immer irgendwie so schwammig.
bist du dir sicher, dass du die Frage vollständig gelesen und verstanden hast?
Gruß Daniel

Betrifft: Zeilen (nicht Zellen) mit Suchbegriff zählen

siehe unsere:
https://www.herber.de/excelformeln/pages/in_wie_vielen_Zeilen_nicht_Zellen_kommt_ein_Suchbegriff_vor.html
hier diese Arrayformel:
{=SUMME(WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN(D1:N1;ZEILE(1:99)-1;);"Apfel");1))}
WF

Betrifft: Die ist architektonisch so wie die von Daniel ...

Betrifft: AW: hier ist BEREICH.VERSCHIEBEN() nicht notw. ...

Hallo WF,
... mit meinem hier eingestellten Vorschlag mit MMULT() wird dadurch auch zumindest ZÄHLENWENN() eingespart. Die von mir eingesetzte Funktion N() lässt sich dazu auch durch z.B. durch *1 noch ersetzen.
Dagegen ist BEREICH.VERSCHIEBEN() in der Formel von Chris Kaiser (untere Teil in https://www.herber.de/excelformeln/pages/in_wie_vielen_Zeilen_nicht_Zellen_kommt_ein_Suchbegriff_vor.html ) in Excelversionen zumindest vor Office365 nicht ersetzbar.
Allerdings könnte dort für die Option: "Suchbegriffe dürfen nur einmal vorhanden sein" der Vergleich mit =1 noch eingespart werden. Denn es reicht hierfür völlig:
=SUMME(N(MMULT(ZÄHLENWENN(BEREICH.VERSCHIEBEN(A1:H1;ZEILE(1:9)-1;;);{"a"."b"."c"});{1;1;1})=3))
Gruß Werner
.. , - ...

Betrifft: AW: Zeilen Zählen wenn Begriff vorkommt
Vielen Dank nochmals für die ganzen Antworten, habe nun die Formel von Daniel am Laufen in Kombination mit dem Vorschlag einer formatierten Tabelle von neopa C. Bisher läuft alles wie gewünscht!
Danke! :)

Hi
ohne Hilfsspalte so
=SUMMENPRODUKT(1*(0<ZÄHLENWENN(BEREICH.VERSCHIEBEN(D1:N1;ZEILE(1:99)-1;0);"apfel")))
die Anzahl der zu durchsuchenden Zeilen solltest du bei "Zeile(...)" so genau wie möglich angeben.
Die Berechnungszeit wächst mit Anzahl der Zeilen und da die Formel volatil ist, Sollte man diese so kurz wie möglich halten.
Gruß Daniel

Betrifft: Eine zwar antike Formel, aber schnell
=SUMMENPRODUKT(1*ISTZAHL(SUCHEN("Apfel";
D1:D99&E1:E99&F1:F99&G1:G99&H1:H99&I1:I99&J1:J99&K1:K99&L1:L99&M1:M99&N1:N99)))

Betrifft: Frage und Antwort in Deinem Betreff...owT

Betrifft: wie meinst du das?
beiträge ohne Beitragtext sind immer irgendwie so schwammig.
bist du dir sicher, dass du die Frage vollständig gelesen und verstanden hast?
Gruß Daniel

Betrifft: Die ist architektonisch so wie die von Daniel ...

Beliebteste Forumthreads (12 Monate)

Zeilen Zählen wenn Begriff vorkommt

13
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

307 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Zeilen Zählen wenn Begriff vorkommt

13 Beiträge zum Forumthread Beiträge zu diesem Forumthread

307 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

13
Beiträge zum Forumthread

Beiträge zu diesem Forumthread