Live-Forum - Die aktuellen Beiträge
Datum
Titel
19.10.2025 21:57:06
Diagrammpunkte in unterschiedlichen Farben je nach Wert
19.10.2025 18:21:56
Prüfen, ob Bild geladen wurde
19.10.2025 15:24:14
VBA -Drucken nur, wenn ich mit bestimmtem WLAN verbunden bin
19.10.2025 10:48:58
Zufällige Uhrzeit
Keine passende Antwort im Forumarchiv gefunden?
Stelle deine Frage im Live-Forum
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
736to740
736to740
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

RGB-Farbe auslesen ?

Forumthread: RGB-Farbe auslesen ?

RGB-Farbe auslesen ?
24.02.2006 12:23:59
Selma
Hallo Leute,
in aktivem Arbeitsblatt möchte ich die RGB-Farbe in Spalte E ab Zeile 2 auslesen.
Meine RGB-Werte stehen in Spalte B, C, D (ab Zeile 2).
Wie mache ich das?
Vielen Dank im Voraus...
Liebe Grüße
Selma
Anzeige

12
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: RGB-Farbe auslesen ?
24.02.2006 12:29:45
Nepumuk
Hallo Selma,
das ist jetzt nicht ganz klar. Wo kommt was her und wo soll was hin?
Gruß
Nepumuk
AW: RGB-Farbe auslesen ?
24.02.2006 12:56:37
Selma
Hallo Nepumuk,
anbei die Beispieldatei: https://www.herber.de/bbs/user/31383.xls
In Spalte E (ab Zeile 2) sollen die Farben stehen.
LG
Selma
Anzeige
AW: RGB-Farbe auslesen ?
24.02.2006 13:01:18
Ceci
Hallo Selma,
dann müsste mein kleines Makro funktionieren, so hab ich es getestet. Du musst halt den Tabellenblattnamen anpassen...
mfg Ceci
AW: RGB-Farbe auslesen ?
24.02.2006 13:06:41
Nepumuk
Hallo Selma,
da gibt es ein Problem. In einer Tabelle sind nur 56 Farben darstellbar. Excel passt also die RGB-Farben automatisch an die darstellbare Farbe an. Wenn du z.B. Labels in die Zellen einfügen würdest, dann könnten die Farben richtig dargestellt werden. Das ganze kannst du auch per VBA machen. Wäre das OK?
Gruß
Nepumuk
Anzeige
AW: RGB-Farbe auslesen ?
24.02.2006 13:18:41
Selma
Hallo Nepumuk,
das wäre auch OK !
LG
Selma
AW: RGB-Farbe auslesen ?
24.02.2006 13:46:50
Nepumuk
Hallo Selma,
in deiner Tabelle sind ein paar doppelte drin.
Hier der Code zum erzeugen der Labels:
Public Sub selmasRGB()
    Dim lngRow As Long
    Dim objColor As OLEObject
    Application.ScreenUpdating = False
    For lngRow = 2 To Cells(Rows.Count, 1).End(xlUp).Row
        Set objColor = ActiveSheet.OLEObjects.Add(ClassType:="Forms.Label.1", _
            Left:=Columns(5).Left, Top:=Rows(lngRow).Top, _
            Width:=Columns(5).Width, Height:=Rows(lngRow).Height)
        objColor.Object.Caption = ""
        objColor.Object.BackColor = RGB(Cells(lngRow, 2).Value, _
            Cells(lngRow, 3).Value, Cells(lngRow, 4).Value)
    Next
    Application.ScreenUpdating = True
End Sub


Und noch eine kleine Routine zum löschen der selben:



Public Sub DeleteLabel()
    Dim objColor As OLEObject
    For Each objColor In ActiveSheet.OLEObjects
        objColor.Delete
    Next
End Sub


Gruß

Nepumuk
Anzeige
warum auch immer...
24.02.2006 14:17:51
u_
Hallo,
..das ist vielleicht nicht so schön aber handgestoppt 9x schneller:

Sub test()
Dim intX As Single, intY As Single, intH As Single, intW As Single
Dim i As Long, sh As Shape
Dim R As Byte, G As Byte, B As Byte
Application.ScreenUpdating = False
For Each sh In ActiveSheet.Shapes
If sh.Name Like "rctCol*" Then sh.Delete
Next
For i = 2 To Range("a65536").End(xlUp).Row
With Cells(i, 5)
intX = .Left
intY = .Top
intH = .Height
intW = .Width
R = .Offset(0, -3)
G = .Offset(0, -2)
B = .Offset(0, -1)
End With
Set sh = ActiveSheet.Shapes.AddShape(msoShapeRectangle, intX, intY, intW, intH)
With sh
.Name = "rctCol_" & i
With .Fill
.Visible = msoTrue
.Solid
.ForeColor.RGB = RGB(R, G, B)
.Transparency = 0#
End With
.Line.Visible = msoFalse
End With
Next
Application.ScreenUpdating = True
End Sub

Gruß
Geist ist geil!
Anzeige
AW: warum auch immer...
24.02.2006 14:28:08
Nepumuk
Hi u_,
weil ich nie mit Shapes arbeite.
Gruß
Nepumuk
AW: RGB-Farbe auslesen ?
24.02.2006 14:25:28
Selma
Hallo Nepumuk,
super es hat prima geklappt...
Ich habe noch eine Frage dazu.
Und zwar besteht die Möglichkeit, wenn im Arbeitsblatt "Daten" z.B. in Zelle B9 = 25 steht
habe, das in Zelle C9 die richtige Farbe aus dem Arbeitsblatt "RGB" dargestellt wird?
Beispieldatei: https://www.herber.de/bbs/user/31385.xls
LG
Selma
Anzeige
AW: RGB-Farbe auslesen ?
25.02.2006 00:08:51
Nepumuk
Hallo Selma,
dazu müssen in der Tabelle RGB nur die Werte drin sein. Das Makro ist natürlich nur für diese Konstellation. Wenn du am Tabellenaufbau einer der beiden Tabellen was änderst, musst du es natürlich anpassen.
https://www.herber.de/bbs/user/31402.xls
Gruß
Nepumuk
Anzeige
Danke Nepumuk !!!
28.02.2006 17:41:47
Selma
Danke Nepumuk !!!
LG
SELMA
AW: RGB-Farbe auslesen ?
24.02.2006 12:54:12
Ceci
Hallo Selma,
versuch mal folgendes:

Sub test()
Dim Zaehler As Integer
Dim Wert1   As Integer
Dim Wert2   As Integer
Dim Wert3   As Integer
'Solange der Wert in Spalte 1 nicht leer ist, wird die Schleife durchgeführt
Do While Worksheets("Tabelle1").Cells(Zaehler + 2, 1).Value <> ""
Wert1 = Worksheets("TAbelle1").Cells(Zaehler + 2, 2).Value
Wert2 = Worksheets("TAbelle1").Cells(Zaehler + 2, 3).Value
Wert3 = Worksheets("TAbelle1").Cells(Zaehler + 2, 4).Value
Worksheets("Tabelle1").Cells(Zaehler + 2, 5).Interior.Color = _
RGB(Wert1, Wert2, Wert3)
Zaehler = Zaehler + 1
Loop
End Sub

mfg Ceci
Anzeige
;

Forumthreads zu verwandten Themen

Zahlen aus Zelle auslesen
Timo

Hallo liebes Forum,
gibt es eine Möglichkeit aus einer Zelle nur die Zahlen auszulesen, siehe Beispiel:
'123456 BLA --> 123456
Ist eine Excel-interne (keine VBA-Programmierung) hier möglich?
Vielen Dank für die Unterstützung!
Timo
14.08.2008 11:16:00
Thread-ID: 1001770
7 Beiträge
Anzeige
Zelleninhalte abwechselnd mit der Füllfarbe... ?
Selma

Hallo Leute,
in Spalte A habe ich ganz viele Einträge. Jetzt möchte ich von Zelle in der am Anfang dies <artikel name steht bis Zelle wo es am Anfang dies steht in Füllfarbe gelb und den nächsten Abschnitt mit der Füllfarbe grün darstellen. Dies soll immer abwechselnd bis letzte Zelle d...
07.10.2008 10:00:00
Thread-ID: 1014628
11 Beiträge
Hintergrundfarbe auf Grund Wert in anderer Zelle
Roger

Guten Morgen,
ich suche eine Lösung für folgendes Problem: In der Spalte F von Zeile 4 bis 300 habe ich folgende werte stehen: entweder nichts, Ja oder Nein. Nun will ich zwecks übersicht in Spalte A in den Zellen 4 bis 300 Farben als Hintergurnd haben. Wenn in Zelle F4 nichts steht, dann i...
18.12.2008 08:21:58
Thread-ID: 1033737
10 Beiträge
Farbe der Nachbarzelle
Volker

Hallo zusammen,
zuerst einmal wünsche ich Euch ein gutes 2009!
Nun zu meinem Problem:
Ich übergebe mittels untenstehendem Code die Daten an eine Tabelle. Funktioniert auch. Allerdings hätte ich jetzt gerne das bei nachträglich geleerter Zelle die Ursprungsfarbe wieder erscheint.
08.01.2009 12:50:17
Thread-ID: 1037876
8 Beiträge
Anzeige
MIN-Wert von bestimmten Zellen auslesen
bestimmten

Hallo zusammen,
ich habe folgendes Problem, welches sich erstmal gar nicht schwierig anhört, nur bei der Umsetzung hapert es noch ein bißchen.
Ich habe in meiner Excel Tabelle bspw... folgendes stehen
Zeile 12: I12=test, J12=4
Zeile 14: C14=test, D14=3, H14=test, I14=6
Zeile...
14.01.2009 11:17:03
Thread-ID: 1039535
10 Beiträge
Anzeige
Zahl aus best. Zelle auslesen
klaus

Hallo!
Folgende Tabelle soll dargestellt werden:
Tabelle1

 AB1Spalte 1nur 90 (für Anzahl Werte >2 und 210019,12,15,70,70,8,90,9013100160410009,10016,10019,10021,12,16,19,2,24,70,77,8,9,9015 0610009,77,99,88,10019,10021,12,16,19,2,24,70,77,8,9,900

Excel Tabel...
02.03.2009 15:51:14
Thread-ID: 1055623
6 Beiträge
Datum aus Zelle auslesen im Dateinamen übernehmen
Ralf

Hallo Zusammen,
hab' ein kleines Problem:
Wie kann man ein in einer Zelle hinterlegtes Datum im Dateinamen übernehmen.
Gruß Ralf
13.03.2009 16:49:57
Thread-ID: 1059943
4 Beiträge
Daten aus Zelle per CSV nur bedingt auslesen
Heiko

Hallöchen,
ich habe eine Datendatei in CSV mit Simikolon getrennt ohne Umbrüche.
Diese Lade ich auf eine Seite hoch, die mir die jeweiligen Zellen innerhalb einer Datenbank ausfüllt.
Meine Frage wäre jetzt, ob es eine Möglichkeit gibt, durch eingaben innerhalb der CSV-Datei den Text...
13.06.2009 20:14:31
Thread-ID: 1081318
4 Beiträge
farbe von Objekt auslesen
Objekt

Hallo zusammen,
ich würde gerne die Farbe von Objekten, mit denen Sie gefärbt sind auslesen.
Mit dem Makrorekorder kann ich mir ja leicht aufzeichnen, wie ich das Objekt färbe, aber rückwärts scheint das nicht zu funktionieren.
Im Prinzip bräuchte ich etwa sowas:
msgbox Workshee...
15.07.2009 17:30:03
Thread-ID: 1088874
3 Beiträge
Farbe bei betreten der Zelle
Stefanglander

Hallo Forum,
habe hier etwas sehr interessantes gefunden.
Option Explicit
Function ColorFromPallet(Optional lOldCol As Double = xlNone) As Double
Dim dSavCol As Double, dNewCol As Double
Dim iRGB_R As Integer, iRGB_G As Integer, iRGB_B As Integer
dSavCol = ActiveWorkbook...
13.08.2009 22:38:17
Thread-ID: 1095814
18 Beiträge
Wert aus Zelle herauslesen
Johannes

Hallo zusammen,
weiß jemand, wie man eine Zahl aus einer Zelle mittels einer Formel herauslesen kann und mit dieser auch weiter rechnen kann?
Beispiel:
In Zelle A1 steht (das ' signalsiert den Zellanfang und -ende):
' 600 Haushaltswaren'
Jetzt möchte in A2 nur den W...
28.09.2009 11:51:34
Thread-ID: 1105996
3 Beiträge
Anzeige
Zellen bei änderung einfärben
question2

Hallo,
ich habe folgendes Problem.
Mit folgendendem kleinen 3-Zeiler färbe ich geänderte Zellen ein. Die Schriftfarbe wird rot dargestellt:
Private Sub Worksheet_Change(ByVal Target As Range) Target.Font.ColorIndex = 3 End Sub
Soweit so gut. Ich bräuche nun aber eine Funktion,...
02.10.2009 19:09:58
Thread-ID: 1106902
4 Beiträge
Entdecke relevante Threads

Schau dir verwandte Threads basierend auf dem aktuellen Thema an

Alle relevanten Threads mit Inhaltsvorschau entdecken
Anzeige

Infobox / Tutorial

RGB-Farbe in Excel auslesen

Schritt-für-Schritt-Anleitung

Um die RGB-Farbe in Excel auszulesen, kannst du VBA verwenden. Hier ist eine einfache Anleitung, wie du dabei vorgehst:

  1. Öffne dein Excel-Dokument und drücke ALT + F11, um den VBA-Editor zu öffnen.

  2. Füge ein neues Modul hinzu: Klicke mit der rechten Maustaste auf "VBAProject (deinDateiname)", wähle "Einfügen" und dann "Modul".

  3. Kopiere den folgenden Code in das Modul:

    Sub RGB_Farbe_auslesen()
   Dim lngRow As Long
   Dim objColor As OLEObject
   Application.ScreenUpdating = False

   For lngRow = 2 To Cells(Rows.Count, 1).End(xlUp).Row
       Set objColor = ActiveSheet.OLEObjects.Add(ClassType:="Forms.Label.1", _
           Left:=Columns(5).Left, Top:=Rows(lngRow).Top, _
           Width:=Columns(5).Width, Height:=Rows(lngRow).Height)
       objColor.Object.BackColor = RGB(Cells(lngRow, 2).Value, _
                                       Cells(lngRow, 3).Value, _
                                       Cells(lngRow, 4).Value)
   Next lngRow

   Application.ScreenUpdating = True
End Sub

  4. Passe den Tabellenblattnamen an, falls nötig.

  5. Schließe den VBA-Editor und kehre zu Excel zurück.

  6. Führe das Makro aus: Drücke ALT + F8, wähle RGB_Farbe_auslesen und klicke auf "Ausführen".

Häufige Fehler und Lösungen

  • Problem: Die Farben werden nicht korrekt angezeigt.

    • Lösung: Überprüfe, ob die RGB-Werte in Spalte B, C und D korrekt sind und im richtigen Bereich liegen (0-255).

  • Problem: Makro läuft sehr langsam.

    • Lösung: Stelle sicher, dass Application.ScreenUpdating auf False gesetzt ist, um die Bildschirmaktualisierung auszuschalten.

Alternative Methoden

Du kannst auch die Funktion „Zellenfarbe auslesen“ verwenden, um die Farbe einer Zelle direkt zu ermitteln. Hier ist ein Beispiel:

Function ZellenfarbeAuslesen(rng As Range) As Long
    ZellenfarbeAuslesen = rng.Interior.Color
End Function

Mit dieser Funktion kannst du die Hintergrundfarbe einer Zelle abfragen und den Farbcode erhalten.

Praktische Beispiele

  1. Zellenfarbe auslesen: Um die Farbe einer bestimmten Zelle auszulesen, verwende die Funktion wie folgt:

    Sub BeispielFarbeAuslesen()
   Dim farbe As Long
   farbe = ZellenfarbeAuslesen(Sheets("Tabelle1").Cells(2, 1))
   MsgBox "Die Hintergrundfarbe der Zelle ist: " & farbe
End Sub

  2. Farbcode auslesen: Um den Farbcode einer Zelle zu ermitteln, kannst du die Funktion in einer Formel verwenden, z.B. =ZellenfarbeAuslesen(A1) in einer anderen Zelle.

Tipps für Profis

  • Nutze die VBA-Funktion „ColorIndex“, um einfache Farben effizient zu verarbeiten.
  • Speichere dein Excel-Dokument als Makro-fähige Datei (.xlsm), um deine Makros zu nutzen.
  • Verwende Formeln wie =FORMEL.FARBE(A1) (abhängig von deiner Excel-Version), um Farben direkt in Zellen anzuzeigen.

FAQ: Häufige Fragen

1. Wie kann ich die Schriftfarbe einer Zelle auslesen?
Du kannst die Schriftfarbe mit der Font.Color-Eigenschaft auslesen:

Dim schriftfarbe As Long
schriftfarbe = Cells(1, 1).Font.Color

2. Gibt es eine Möglichkeit, die Hintergrundfarbe einer Zelle in eine andere Zelle zu kopieren?
Ja, du kannst einfach den Wert von Interior.Color in die Zielzelle zuweisen:

Cells(2, 2).Interior.Color = Cells(1, 1).Interior.Color

Mit diesen Anleitungen und Tipps kannst du die Farbe in Excel auslesen und deine VBA-Kenntnisse vertiefen.

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Entdecke mehr
Finde genau, was du suchst

Die erweiterte Suchfunktion hilft dir, gezielt die besten Antworten zu finden

Suche nach den besten Antworten
Unsere beliebtesten Threads

Entdecke unsere meistgeklickten Beiträge in der Google Suche

Top 100 Threads jetzt ansehen
Anzeige