Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1136to1140
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Gültigkeitsprüfung stimmt nach Speichern nicht meh

Gültigkeitsprüfung stimmt nach Speichern nicht meh
Sonja
Hallo,
nachdem 1 Problem gelöst wurde habe ich nun das nächste:
Ich habe DropDown-Zellen die ich mit Hilfe von Gültigkeitsprüfung auf eine externe Datei verweise.
Beim Speichern unter einem anderen Namen/und Speicherplatz stimmt der Pfad bei der Gültigkeitsprüfung nicht mehr.
Vorher: 'C:=Ordner\[Mappe2.xls]\Namensliste'!$B$2:$B$400
Nach Abspeichern: =#BEZUG!$B$2:$B$400
Was muss ich eingeben, dass der Pfad auch fix bleibt, nicht nur der Zellbezug?
Grüße
Sonja
AW: Gültigkeitsprüfung stimmt nach Speichern nicht meh
19.02.2010 22:13:27
Josef
Hallo Sonja,

wenn dein Problen aus deinem v orherigen Thread gelöst ist, solltest du es auch dort Kundtun, sonst schafst du dir im Forum keine Freunde.
Zu deiner neuern Frage: Die Gültigkeit akzeptiert keinen Bezug zu anderen Mappen.

Gruß Sepp

AW: Gültigkeitsprüfung stimmt nach Speichern nicht meh
19.02.2010 22:26:55
Sonja
Hallo Sepp,
sorry, und Danke für Deine Lösung meines Problemes!!
Wie könnte ich das Problem mit der Namensliste denn sonst lösen? Die Namensliste wird von verschiedenen Dateien benötigt, ich kann die Namensliste also nicht mit in die Mappe2 integrieren, sondern muss sie gesondert ablegen.
In Mappe eins wurde ich aber gerne in Spalte A ein DopDown habe um die Nachnamen auszuwählen. Die Restlichen Spalten, wie Name und Anschrift lese ich dann mit SVerweis ein...
Wenn ich "Liste" bei der Gültigkeitsprüfung auswähle und dann auf eine externe Datei verweise werden die Daten gefunden! (Bei z.B. Benutzerdefiniert macht mich Excel darauf aufmerksam, dass nicht auf externe Dateien zugegriffen werden kann)
Es funktioniert auch alles klasse, nur eben nicht mehr, wenn ich die Mappe unter einem anderen Pfad abspeichere...
Grüßle
Sonja
Anzeige
AW: Gültigkeitsprüfung stimmt nach Speichern nicht meh
19.02.2010 22:41:31
Josef
Hallo Sonja,

also weder bei xl2003 noch bei xl2007 wird bei mir ein Bezug zu einer anderen Datei als Quelle der Liste akzeptiert!
Mit VBA könnte man beim Öffnen der Datei die Gültigkeitsliste füllen.

Gruß Sepp

AW: Gültigkeitsprüfung stimmt nach Speichern nicht meh
20.02.2010 08:21:21
Sonja
Guten Morgen an Alle,
Danke Sepp für Deine Antwort.
Wie schaut denn dann solch ein Makro für eine Dropp-Down-Liste aus?
Ich bräuchte die Felder von 'C:Ordner\[Mappe2.xls]\Namensliste'!
und davon die Zellen $A$39:$A$147
Grüße
Sonja
Anzeige
AW: Gültigkeitsprüfung stimmt nach Speichern nicht meh
20.02.2010 09:00:51
Josef
Hallo Sonja,

achte darauf, welcher Codeteil wohin gehört und mache im Code die notwendigen Anpassungen (siehe Kommentare).

' **********************************************************************
' Modul: DieseArbeitsmappe Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Workbook_Open()
  addValidation
End Sub

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Const cstrFile As String = "C:\Ordner\Mappe2.xls" 'Dateiname - Anpassen!
Const cstrTab As String = "Namenliste" 'Tabellenname - Anpassen!
Const cstrRange As String = "A39:A147" 'Zellbereich - Anpassen!

Sub addValidation()
  Dim objWb As Workbook, vntList As Variant
  
  On Error GoTo ErrExit
  With Application
    .ScreenUpdating = False
    .EnableEvents = False
  End With
  
  If Dir(cstrFile) <> "" Then
    Set objWb = Workbooks.Open(cstrFile)
    vntList = UniqueList(objWb.Sheets(cstrTab).Range(cstrRange), True)
    objWb.Close False
    'Tabellenname und Bereich der Gültigkeit - Anpassen!
    With ThisWorkbook.Sheets("Tabelle1").Range("A1:A25")
      .Validation.Delete
      .Validation.Add Type:=xlValidateList, _
        AlertStyle:=xlValidAlertStop, _
        Operator:=xlBetween, _
        Formula1:=Join(vntList, ",")
    End With
  End If
  
  ErrExit:
  With Application
    .ScreenUpdating = True
    .EnableEvents = True
  End With
  
  Set objWb = Nothing
End Sub

Private Function UniqueList(Matrix As Range, Optional Sorted As Boolean = True) As Variant
  Dim objDic As Object, rng As Range, varTmp() As Variant
  
  Set objDic = CreateObject("Scripting.Dictionary")
  
  For Each rng In Matrix
    If rng.Value <> "" Then objDic(rng.Value) = 0
  Next
  
  varTmp = objDic.keys
  
  If Sorted Then QuickSort varTmp
  
  UniqueList = varTmp
  
  Set objDic = Nothing
End Function

Private Sub QuickSort(data() As Variant, Optional UG, Optional OG)
  Dim P1&, P2&, T1 As Variant, T2 As Variant
  
  UG = IIf(IsMissing(UG), LBound(data), UG)
  OG = IIf(IsMissing(OG), UBound(data), OG)
  
  P1 = UG
  P2 = OG
  T1 = data((P1 + P2) / 2)
  
  Do
    
    Do While (data(P1) < T1)
      P1 = P1 + 1
    Loop
    
    Do While (data(P2) > T1)
      P2 = P2 - 1
    Loop
    
    If P1 <= P2 Then
      T2 = data(P1)
      data(P1) = data(P2)
      data(P2) = T2
      P1 = P1 + 1
      P2 = P2 - 1
    End If
    
  Loop Until (P1 > P2)
  
  If UG < P2 Then QuickSort data, UG, P2
  If P1 < OG Then QuickSort data, P1, OG
  
End Sub

Gruß Sepp

Anzeige
AW: Gültigkeitsprüfung stimmt nach Speichern nicht meh
20.02.2010 09:48:35
Sonja
Hi Sepp,
hier eine Tasse Kaffee und ein Muffin für Deine Mühe!
Ich bekomm das leider nicht hin. So werde ich das Projekt "DropDown" sterben lassen. Dann muss man eben händisch die Mitarbeiter-Nummer eingeben und der Rest füllt sich ja eh mit Sverweis aus...
Wäre halt einfacher gewesen...
Grüße
Sonja
AW: Gültigkeitsprüfung stimmt nach Speichern nicht meh
20.02.2010 09:49:59
Josef
Hallo Sonja,

danke fürs Frühstück;-))
aber warum so schnell aufgeben? Was bekommst du denn nicht hin?

Gruß Sepp

Anzeige
AW: Gültigkeitsprüfung stimmt nach Speichern nicht meh
20.02.2010 10:06:00
Sonja
Hi Sepp,
bei mir zeigen sich leider keine DropDown-Auswahlfelder. Nach ca. 10 Stunden rumprobieren wegen diesen Feldern strecke ich die Segel...
Grüße
Sonja
AW: Gültigkeitsprüfung stimmt nach Speichern nicht meh
20.02.2010 10:07:49
Josef
Hallo Sonja,

hast du im Code die Anpassungen vorgenommen?
Hast du die Datei gespeichert, geschlossen und wieder geöffnet?

Gruß Sepp

AW: Gültigkeitsprüfung stimmt nach Speichern nicht meh
20.02.2010 10:24:04
Sonja
Hi Sepp,
yop, habe ich gemacht. Aber vielleicht doch irgendetwas falsch?! Soooooo gut kenne ich mich nun mit VBA auch nicht aus...
Grüße
Sonja
Anzeige
AW: Gültigkeitsprüfung stimmt nach Speichern nicht meh
20.02.2010 11:16:38
Sonja
Hi Sepp,
Deine Beispieldatei klappt, wenn ich Sie auf meine Pfade abändere.
Ich werde es noch mal mit meiner Datei versuchen, muss jetzt allerdings weg.
Werder Dir morgen von meinem Erfolg berichten!!
Grüßle
Sonja
Anzeige
AW: Gültigkeitsprüfung stimmt nach Speichern nicht meh
20.02.2010 10:21:44
Sonja
Hi Sepp,
bei mir zeigen sich leider keine DropDown-Auswahlfelder. Nach ca. 10 Stunden rumprobieren wegen diesen Feldern strecke ich die Segel...
Grüße
Sonja
AW: Gültigkeitsprüfung stimmt nach Speichern nicht meh
21.02.2010 09:14:45
Sonja
Hi Sepp,
ich habe das Problem gefunden. Funktionierte nicht, da ja noch eine 2. Mappe im Hintergrund geladen ist. Jetzt überdenke ich erst einmal den kompletten Aufbau meiner Mappen neu!!
Grüße und einen schönen Sonntag
Sonja

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige