Microsoft Excel

Herbers Excel/VBA-Archiv

Als *.csv bestimmte Bereiche speichern | Herbers Excel-Forum


Betrifft: Als *.csv bestimmte Bereiche speichern von: mehmet
Geschrieben am: 16.11.2009 00:59:37

Hallo Forum,

wie kann ich bestimmte Bereiche als *.csv Datei speichern?
Wenn ich Makroaufzeichnung mache, wird alles gespeichert (;;;;;;;;;;;).

Beginnend soll die Abfrage Zelle H10.

Wenn H10 = leer, dann Makro ende, sonst nur Zelle C10, F10, G10, H10, i10 und AB10 als csv (;) speichern.
Wenn H11 = leer, dann Makro ende, sonst nur Zelle C11, F11, G11, H11, i11 und AB11 als csv (;) speichern.

usw. bis H-Zelle leer ist.

Dateiname soll "daten.csv" heissen im Verzeichnis: "C:\Dokumente und Einstellungen\...\Desktop"

Dank und Gruss
mehmet

  

Betrifft: AW: Als *.csv bestimmte Bereiche speichern von: Heinz A. Wankmüller
Geschrieben am: 16.11.2009 07:19:32

Hallo mehmet,

hier ein ungetesteter Versuch (Zielordner Verz und Tabellennamen bitte anpassen):

Sub csv_speichern()
    
    Dim ws As Worksheet, lz%, z As Range, F%, strTemp$
    Dim strSpeicherPfad$, Verz$
    
    Verz = "C:\"                    'muss mit Backslash enden!
    strSpeicherPfad = Verz & "daten.csv"
    
    Set ws = ThisWorkbook.Worksheets("Tabelle 1")
    lz = ws.Cells(Rows.Count, 8).End(xlUp).Row
    
    F = FreeFile
    Close
    Open strSpeicherPfad For Output As #F

    For Each z In ws.Range("H10:H" & lz)
        If z.Value = "" Then Exit For
        strTemp = strTemp & z.Offset(0, -5).Text & ";"      'C
        strTemp = strTemp & z.Offset(0, -2).Text & ";"      'F
        strTemp = strTemp & z.Offset(0, -1).Text & ";"      'G
        strTemp = strTemp & z.Text & ";"                    'H
        strTemp = strTemp & z.Offset(0, 1).Text & ";"       'I
        strTemp = strTemp & z.Offset(0, 20).Text & ";"      'AB
        strTemp = Left(strTemp, Len(strTemp) - 1)
        Print #F, strTemp
        strTemp = ""
    Next z
    
    Close #F

End Sub

Gruß
Heinz


  

Betrifft: AW: Als *.csv bestimmte Bereiche speichern von: mehmet
Geschrieben am: 16.11.2009 11:28:11

Herzlichen Dank Heinz,
es funktioniert.
Viele Grüsse
mehmet


Beiträge aus den Excel-Beispielen zum Thema "Als *.csv bestimmte Bereiche speichern"