aus Access als Excel-XLSX und -CSV wegspeichern

Bild

Betrifft: aus Access als Excel-XLSX und -CSV wegspeichern
von: vso
Geschrieben am: 14.07.2015 07:36:49

Hallo,
ich möchte eine Auswertung, die in Access läuft, über Excel als Excel-xlsx und auch noch als Excel-csv wegspeichern.
Wie teile ich das Excel mit?
Der Code sieht zur Zeit so aus und läuft auch, erzeugt aber nur das xlsx (Dim-Block habe ich weggelassen):
Set rstDaten = Datenbank.OpenRecordset("SELECT Feld1, Feld2, Feld3 " & _
"FROM QS_001_Daten " & _
"WHERE Feld2 LIKE '*0*'")

'*** Ein Excel-Sheet starten
Set Zielapplikation = New Excel.Application
Zielapplikation.Visible = True
Set wkbZieldatei = Zielapplikation.Workbooks.Add()
Set wksZielTabelle = wkbZieldatei.Worksheets(1)

'*** Tabelle umbenennen
wksZielTabelle.Name = "Output"

'*** Spaltenüberschriften
Set rngZielBereich = Range("A1")
For Each Feld In rstDaten.Fields
rngZielBereich.Value = Feld.Name
Set rngZielBereich = rngZielBereich.Offset(, 1)
Next

'*** Daten in Excel einfügen
Set rngZielBereich = wksZielTabelle.Range("A2")
rngZielBereich.CopyFromRecordset rstDaten

'*** Wegspeichern als xlsx:
With Zielapplikation
.ActiveWorkbook.SaveAs "H:\5570\IT-Sec-Admin\06_Work\Test.xlsx"
.Quit
End With
Set Zielapplikation = Nothing
Set rngZielBereich = Nothing


Danke vorab für jeden Tipp!
Volker

Bild

Betrifft: AW: aus Access als Excel-XLSX und -CSV wegspeichern
von: fcs
Geschrieben am: 15.07.2015 05:10:16
Hallo Volker,
mit folgenden -nicht getesten- Anpassungen sollte es funktionieren.
Gruß
Franz

    With Zielapplikation
    '*** Wegspeichern als xlsx:
        .ActiveWorkbook.SaveAs Filename:="H:\5570\IT-Sec-Admin\06_Work\Test.xlsx", _
                FileFormat:=51 '51 = Open XML-Arbeitsmappe
    '*** Wegspeichern als csv:
        .DisplayAlerts = False
        .ActiveWorkbook.SaveAs Filename:="H:\5570\IT-Sec-Admin\06_Work\Test.CSV", _
                FileFormat:=23, Local:=True ' 23 = xlCSVWindows, 6 = xlCSV, _
                bei Local = True werden Dezimalzeichen, Datum/Zeiten und Trennzeichen für _
                Spalten mit den Landes-Einstellungen im Betriebssystem gespeichert.
        .ActiveWorkbook.Close savechanges:=False
        .DisplayAlerts = True
        .Quit
    End With
    


 Bild

Beiträge aus den Excel-Beispielen zum Thema "aus Access als Excel-XLSX und -CSV wegspeichern"