2 Spalten in ComboBox

Forumthread: 2 Spalten in ComboBox

05.03.2015 08:40:47

Wolfgang

Hallo alle gemeinsam,
folgendes Problem:
im Arbeitsblatt "Stammdaten" befindet sich eine Liste mit Daten(Spalten U:W).Die Anzahl der verwendeten Zeilen ist Variabel. Nun möchte ich 2 Spalten in der ComboBox anzeigen lassen. Die Anzahl der Spalten ist in den Eigenschaften auf 2 eingestellt.
Ich habe folgenden Skript geschrieben:

Private Sub Worksheet_Activate()
Dim s As Integer
s = 4
With Sheets("Stammdaten")
Do Until .Cells(s, 22).Value = ""
UserForm4.ComboBox1.AddItem .Cells(s, 22)
s = s + 1
Loop
End With
UserForm4.Show
End Sub

So bekomme ich aber nur die Daten der Spalte 22 angezeigt.
Wie bekomme ich nun die Spalte 23 dazu?
Danke für Eure Mühe im Voraus.
Wolfgang
aus dem Erzgebirge

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: 2 Spalten in ComboBox

05.03.2015 09:23:32

Nepumuk
AW: 2 Spalten in ComboBox

05.03.2015 09:32:22

Wolfgang
Range übergeben

05.03.2015 09:26:46

RPP63
AW: Range übergeben

05.03.2015 09:38:21

Daniel
AW: 2 Spalten in ComboBox

05.03.2015 09:35:25

Rudi

AW: 2 Spalten in ComboBox

05.03.2015 09:23:32

Nepumuk

Hallo,
würde ich so machen:

Option Explicit

Private Sub Worksheet_Activate()
    With Worksheets("Stammdaten")
        UserForm4.ComboBox1.List = .Range(.Cells(4, 22), _
            .Cells(.Cells(.Rows.Count, 22).End(xlUp).Row, 23)).Value
    End With
    UserForm4.Show
End Sub

Gruß
Nepumuk

AW: 2 Spalten in ComboBox

05.03.2015 09:32:22

Wolfgang

Hallo Nepumuk,
Ich danke Dir. So sieht es gut aus.
Wolfgang
aus dem Erzgebirge

Range übergeben

05.03.2015 09:26:46

RPP63

Hallo!
Übergebe den zu ermittelnden Range im _Initialize.
Pseudocode:

Private Sub UserForm_Initialize()
ComboBox1.List = Tabelle3.Range("A2:B3").Value
End Sub

Gruß Ralf

AW: Range übergeben

05.03.2015 09:38:21

Daniel

Hi
mit .AddItem erzeugst du einen neuen Eintrag in die Comboboxliste.
Wenn die Combobox mehrere Spalten hat, müssen die Werte der weiten Spalten dann direkt ins LIST geschrieben werden.

UserForm4.ComboBox1.AddItem .Cells(s, 22)
Userform4.ComboBox1.List(Userform4.Combobox1.ListCount - 1, 1) = .Cells(s, 23)

(hier wärs dann vielleicht sinnvoller, die Combobox in die WITH-Klammer zu nehmen)
Gruß Daniel

AW: 2 Spalten in ComboBox

05.03.2015 09:35:25

Rudi

Hallo,

Private Sub Worksheet_Activate()
With Worksheets("Stammdaten")
UserForm4.ComboBox1.List = .Range(.Cells(4, 22), _
.Cells(.Rows.Count, 22).End(xlUp)).Resize(,2).Value
End With
UserForm4.Show
End Sub

Gruß
Rudi

Beliebteste Forumthreads (12 Monate)

Forumthread: 2 Spalten in ComboBox

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread