Makro nach unten kopieren

Forumthread: Makro nach unten kopieren

20.03.2023 10:50:04

tim

Hallo zusammen,

ich habe ein Probelm mit VBA bei dem auch nach langer Suche und nach Recherche mit KI nicht weiterkomme.

Ich habe eine Tabelle mit Namen, E-Mail-Adressen und Dateipfaden. Die Dateipfade sind aufgebaut nach "S:\Ordner\Unterordner\"Name".xlsx.

Ich möchte mir nun mit einem Makro alle 710 Namen in den Dateipfad einfügen, sodass ich einen vollständigen Pfad habe. So wie ich es jetzt habe, habe ich nur absolute Bezüge auf Zelle A2 mit den Namen und Zelle C2 mit den Datzeipfaden, kann den Befehl jedoch nicht nach unten weiter ausführen lassen.

Hoffe jemand kann mir helfen.

Danke im vorraus,

Tim

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Makro nach unten kopieren

20.03.2023 11:18:46

Rudi Maintaire
AW: Makro nach unten kopieren

20.03.2023 11:24:33

tim
AW: Makro nach unten kopieren

20.03.2023 11:32:17

Rudi Maintaire
AW: Makro nach unten kopieren

20.03.2023 11:41:04

Rudi Maintaire
AW: Makro nach unten kopieren

20.03.2023 11:51:42

tim

AW: Makro nach unten kopieren

20.03.2023 11:18:46

Rudi Maintaire

Hallo,
So wie ich es jetzt habe,
Was hast du denn?

Gruß
Rudi

AW: Makro nach unten kopieren

20.03.2023 11:24:33

tim

Sub ReplacePlaceholderNurText()

         
    'Define the filename format including folder path
    Dim fileNameFormat As String
    fileNameFormat = "S:\800 Team\Knapp\Zoll\Excel Dateien Lieferanten\Platzhalter.xlsx"
    
    'Get the value from cell A3
       Dim textToReplace As String
    textToReplace = Range("A3").Value
            
   
    
    'Replace the placeholder with the text from A3
    Dim fileName As String
    fileName = Replace(fileNameFormat, "Platzhalter", textToReplace)
    
    'Update cell C3 with the full file path
        
    Range("C3").Value = fileName
    
   
    
End Sub

so habe ich es jetzt, klappt an sich gut, nur dass ich es nicht schaffe die nächsten Zeilen mitzunehmen.

AW: Makro nach unten kopieren

20.03.2023 11:32:17

Rudi Maintaire

Hallo,

Sub ReplacePlaceholderNurText()
  Dim rngA As Range
  Dim textToReplace As String
  Dim fileName As String
  
  'Define the filename format including folder path
  Const fileNameFormat = "S:\800 Team\Knapp\Zoll\Excel Dateien Lieferanten\Platzhalter.xlsx"
  
  Application.ScreenUpdating = False
  
  For Each rngA In Range(Cells(3, 1), Cells(Rows.Count, 1).End(xlUp))
    'Get the value from Column A
    textToReplace = rngA.Value
    'Replace the placeholder with the text from A
    fileName = Replace(fileNameFormat, "Platzhalter", textToReplace)
    'Update cell C with the full file path
    rngA.Offset(, 2).Value = fileName
  Next rngA
  
End Sub

Gruß
Rudi

AW: Makro nach unten kopieren

20.03.2023 11:41:04

Rudi Maintaire

dürfte erheblich schneller sein:


Sub ReplacePlaceholderNurText()
  Dim vntA, i As Long
  
  'Define the filename format including folder path
  Const fileNameFormat = "S:\800 Team\Knapp\Zoll\Excel Dateien Lieferanten\Platzhalter.xlsx"
    
  vntA = Range(Cells(3, 1), Cells(Rows.Count, 1).End(xlUp))
  
  For i = 1 To UBound(vntA)
    vntA(i, 1) = Replace(fileNameFormat, "Platzhalter", vntA(i, 1))
  Next i
  
  Range("C3").Resize(UBound(vntA)) = vntA
  
End Sub

AW: Makro nach unten kopieren

20.03.2023 11:51:42

tim

Danke dir klappt alles perfekt :)

Beliebteste Forumthreads (12 Monate)

Forumthread: Makro nach unten kopieren

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread