Ausgabe ohne Leerzeilen

Bild

Betrifft: Ausgabe ohne Leerzeilen
von: Sascha
Geschrieben am: 15.07.2015 13:58:32

Liebes Team,
steh vor folgender Herausforderung ...
In Spalte A habe ich alle meine Bauprojekte mi Ländercode (Bspw.AT0005) und In Spalte B sage ich ob es ein "Neubau" oder "Umbau" ist und in Spalte C will ich nur Neubauten haben und in Spalte D nur die Umbauten.
Frage: Eigentlich ganz leicht mit einer Wenn-Formel zu lösen und funktioniert auch aber in den Spalten C und D hab ich jeweils Leerzellen
wie bekomm ich das mit einer Formel weg und in aufsteigender reihenfolge sortiert
muss unbeding filtern und sortieren vermeiden
Vielen Dank für eueren Einsatz
lg sascha

Bild

Betrifft: AW: Ausgabe ohne Leerzeilen
von: SF
Geschrieben am: 15.07.2015 14:00:12
Hola,
entweder:
http://www.excelformeln.de/formeln.html?welcher=28
oder:
http://www.excelformeln.de/formeln.html?welcher=224
Gruß,
steve1da

Bild

Betrifft: AW: Ausgabe ohne Leerzeilen
von: Sascha
Geschrieben am: 15.07.2015 15:28:39
uhhh das ist schwierig, da brauch ich bitte deinen support ...
kann ich mir vl. gleich auch in Spalte C nur alle "NewOpenings" in sortierter Reihenfolge zeigen lassen ohne Hilfsspalte?
bis dato steht jetzt folgendes in C1 =IF(B:B="NewOpening";A:A;"") und dann wird mir AT005 angezeigt und eben die anderen wobei bei AT107 dann leider eine leerzeile kommt
Bauprojekt Project action
AT0005 NewOpening
AT0010 NewOpening
AT0016 NewOpening
AT0017 NewOpening
AT0107 Rebuilding
AT0120 Rebuilding
AT0130 Rebuilding
AT0147 Rebuilding
AT0158 Rebuilding
HR0416 NewOpening
RS0510 NewOpening
SI0202 Rebuilding
vielen lieben dank

Bild

Betrifft: das ist möglich ...
von: der neopa C
Geschrieben am: 15.07.2015 16:28:29
Hallo Sascha,
... allerdings solltest Du dazu einen kleine Beispieldateiauszug hier einstellen und darin auch beispielhaft händisch aufzeigen, was Deine Zielstellung genau ist.
Gruß Werner
.. , - ...

Bild

Betrifft: AW: das ist möglich ...
von: Sascha
Geschrieben am: 15.07.2015 21:50:00
Hi also so sieht das bis dato aus ... kann leider kein Bild und auch keine file uploaden
in zelle C würde ich jetzt gerne alle "newopenings" haben aber ohne Leerzeilen wenn nötig auch dann in Spalte D als Hilfestellung
spalte A Bauprojekte
spalte B Project Action
spalte C NewOpening Ergebnis aus C1 =IF(B:B="NewOpening";A:A;"")

Bauprojekt Project action NewOpening
AT0005 NewOpening AT0005
AT0010 NewOpening AT0010
AT0016 NewOpening AT0016
AT0017 NewOpening AT0017
AT0107 Rebuilding
AT0120 Rebuilding
AT0130 Rebuilding
AT0147 Rebuilding
AT0158 Rebuilding
HR0416 NewOpening HR0416
RS0510 NewOpening RS0510
SI0202 Rebuilding
vielen Dank an alle

Bild

Betrifft: AW: das ist möglich ...
von: Sepp
Geschrieben am: 15.07.2015 23:06:29
Hallo Sascha,
so?
Tabelle1

 ABCDE
1BauprojektProject actionNewOpeningRebuilding 
2AT0005NewOpeningAT0005AT0107 
3AT0010NewOpeningAT0010AT0120 
4AT0016NewOpeningAT0016AT0130 
5AT0017NewOpeningAT0017AT0147 
6AT0107RebuildingHR0416AT0158 
7AT0120RebuildingRS0510SI0202 
8AT0130Rebuilding   
9AT0147Rebuilding   
10AT0158Rebuilding   
11HR0416NewOpening   
12RS0510NewOpening   
13SI0202Rebuilding   
14     

Formeln der Tabelle
ZelleFormel
C2=WENN(ZÄHLENWENN($B:$B;C$1)<ZEILE($A1); "";INDEX($A$2:$A$100;AGGREGAT(15;6;ZEILE($A$1:$A$99)/($B$2:$B$100=C$1); ZEILE($A1))))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Sepp


Bild

Betrifft: ich finde es natürlich prima, ...
von: der neopa C
Geschrieben am: 16.07.2015 10:19:17
Hallo Sepp,
...mit Dir einen so profilierten Mitstreiter wie Dich gefunden zu haben, der den Einsatz der AGGREGAT()-Funktion offensichtlich nun auch den klassischen MATRIXFormel vorzuziehen beginnst :-)
Im konkreten Beispiel könnte man die Formel noch um einiges kürzen zu
=WENNFEHLER(INDEX($A:$A;1+AGGREGAT(15;6;ZEILE(Z$1:Z$99)/($B$2:$B$99=C$1);ZEILE(A1)));"")
Wobei ich bewusst auch ...(Z$1:Z$99)/($B$2:$B$99....) geschrieben habe, um damit indirekt auf einen spez. Vorteil von AGGREGAT() hinzuweisen. Man kann mit dieser nämlich auch inhomogene Bereichsangaben auswerten.
Gruß Werner
.. , - ...

Bild

Betrifft: AW: ich finde es natürlich prima, ...
von: Sepp
Geschrieben am: 16.07.2015 18:22:16
Hallo Werner,
das man die Formel abkürzen kann, war mir klar, aber ich werde, wenn immer möglich, einen Fehler vorher abfangen und die Bereichsangaben werde ich auch immer angleichen. Bin es halt gewohnt, saubere Angaben zu machen und ich will nicht die Schlamperei fördern.
Mit Aggregat() hab ich kein Problem, wobei mir die "alten" Matrixlösungen etwas mehr zusagen, weil sie in (fast) allen XL-Versionen laufen.

Gruß Sepp


Bild

Betrifft: AW: ich finde es natürlich prima, ...
von: sascha
Geschrieben am: 20.07.2015 22:41:13
Hallo werner
hätte deine Formel ins englische übersetzt, aber leider funktioniert es nicht ganz ... siehst du da noch nen Fehler?
=IFERROR(INDEX($A:$A;1+AGGREGATE(15;6;CELL(Z$1:Z$99)/($B$2:$B$99=C$1);CELL(A1)));"")
vielen dank u alles liebe
lg sascha

Bild

Betrifft: verwende Komma statt Semikolon! o.T.
von: Sepp
Geschrieben am: 20.07.2015 22:53:44

Gruß Sepp


Bild

Betrifft: AW: ich finde es natürlich prima, ...
von: Mullit
Geschrieben am: 20.07.2015 22:55:30
Hallo,
nicht Zelle, sondern Zeile:

=IFERROR(INDEX($A:$A;1+AGGREGATE(15;6;ROW(Z$1:Z$99)/($B$2:$B$99=C$1);ROW(A1)));"")

Gruß, Mullit

Bild

Betrifft: AW: ich finde es natürlich prima, ...
von: sascha
Geschrieben am: 20.07.2015 23:06:09
Wahnsinn
vielen lieben Dank an Sepp, Werner und Multi ganz ganz ganz toll
alles liebe Sascha

Bild

Betrifft: AW: ich finde es natürlich prima, ...
von: P-Quest :-)
Geschrieben am: 20.07.2015 23:06:34
Was bitte ist ROW(Z$1:Z$99) bzw. ROW(A1)?

Bild

Betrifft: AW: ich finde es natürlich prima, ...
von: Mullit
Geschrieben am: 20.07.2015 23:24:41
die Zeile des jeweiligen relativen Zellbereiches auf den die Formel sich bezieht, die allerdings von Werner erstellt wurde, ich hab jetzt mal nur übersetzt, bei Werner kann man zu 100% davon ausgehen, das sie funktioniert...

Bild

Betrifft: dazu muss ich anmerken ...
von: der neopa C
Geschrieben am: 21.07.2015 08:41:54
Hallo Mullit,
... manche meiner Formelvorschläge können genauso fehlerhafte Ergebnisse ergeben, wie wohl keiner immer fehlerfreie Formelvorschläge erstellt hat oder erstellen wird, wenn er/sie sich etwas komplexere Formellösungen im Rahmen von Forenstätigkeit einstellt, wenn wir natürlich alle die 100% anstreben.
Aber ich danke für Deine gute Meinung.
Gruß Werner
.. , - ...

Bild

Betrifft: AW: das ist möglich ...
von: sascha
Geschrieben am: 20.07.2015 22:54:20
Hi Sepp,
erstmal vielen lieben Dank für deine Hilfe
hätte jetzt versucht das ins englische zu übersetzen, aber habe leider immer noch einen #Value Fehler
=IF(COUNTIF($B:$B;C$1<CELL($A1);"";INDEX($A$2:$A$100;AGGREGATE(15;6;CELL($A$1:$A$99) /($B$2:$B$100=C$1);CELL($A1))))
danke für dein Hilfe, echt super
lg sascha

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Ausgabe ohne Leerzeilen"