Spalten in andere Arbeitsmappe kopieren

Hallo,
Ich bin absolut unerfahren im Umgang mit Excel und VBA. Jetzt steh ich vor einem Problem und komm nicht weiter.
Und zwar will ich über Formeln errechnete Werte durch ein Makro in eine andere Arbeitsmappe übertragen.
Hab im Forum zwar schon einen Ansatz gefunden, ich schaff es aber nicht es auf die gesamte Spalte zu übertragen/ bzw will ich mehrere Spalten (aus einer geschlossenen Mappe) kopieren.
Und wie gesagt VBA ist absolutes Chinesisch für mich....

Function xl4Value(strParam As String) As Variant
xl4Value = ExecuteExcel4Macro(strParam)
End Function

Sub Makro()
Dim strSource As String
strSource = "'I:\...\...\[Datei.xlsx]Arbeitsblatt'!R4C4"
Range("D1").Value = xl4Value(strSource)
End Sub

Danke schon mal im vorraus...
Gruss Olli

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

Hallo Olli,
eine Möglichkeit per ADO.

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Public Sub ReadFromFile_ADO()
  Dim objADO As Object
  Dim strFile As String, strSheet As String, strRange As String

  strFile = "E:\Forum\Daten.xlsx" 'Datei
  strSheet = "Tabelle1" 'Pfad
  strRange = "A:C" 'Bereich

  Set objADO = ExcelTable(strFile, strSheet, strRange)

  'Ausgabe in aktiver Tabelle ab A2
  Range("A2").CopyFromRecordset objADO

  objADO.Close
End Sub

Public Function ExcelTable(ByRef Path As String, ByRef Table As String, ByRef SourceRange As String, Optional WhereString As String = "") As Object
  Dim SQL As String
  Dim Con As String

  SQL = "select * from [" & Table & "$" & SourceRange & "] " & WhereString

  If Mid(Path, InStrRev(Path, ".") + 1) = "xls" Then
    Con = "Provider=Microsoft.Jet.OLEDB.4.0;" _
      & "Extended Properties=Excel 8.0;" _
      & "Data Source=" & Path & ";"
  ElseIf Mid(Path, InStrRev(Path, ".") + 1) Like "xls?" Then
    Con = "Provider=Microsoft.ACE.OLEDB.12.0;" _
      & "Extended Properties=""Excel 12.0;HDR=YES"";" _
      & "Data Source=" & Path & ";"
  Else
    Exit Function
  End If
  Set ExcelTable = CreateObject("ADODB.Recordset")
  ExcelTable.Open SQL, Con, 3, 1
End Function

Gruß Sepp

Beliebteste Forumthreads (12 Monate)

Spalten in andere Arbeitsmappe kopieren

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

309 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Spalten in andere Arbeitsmappe kopieren

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

309 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread