Zählen über Liste mit verschiedenen Bedingungen

Bild

Betrifft: Zählen über Liste mit verschiedenen Bedingungen
von: CB
Geschrieben am: 10.07.2015 15:19:47

Hallo,
ich beschäftige mich schon ein paar Stunden mit einem Problem. Vielleicht denke ich auch zu kompliziert oder habe nur ein Brett vor dem Kopf. Ich konnte dazu aber auch nichts in Foren oder sonstwo finden, bei dem ich die Problemstellung übertragen kann:
Es geht darum, zu berechnen, wie viele Personen in einem vorgegebenen Zeitraum in einem Haus gewohnt haben. Diese sollen gezählt werden, sobald sie mindestens einen Tag da waren. Dafür hat man ein Einzugs- und Auszugsdatum, sowie den gewünschten Zeitraum angegeben.
Anschauliches Beispiel:
Person1: Einzug 22.12.2014 - Auszug 13.05.2015
Person2: Einzug 22.03.2015 - Auszug 01.05.2015
Person3: Einzug 22.01.2014 - Auszug 04.02.2015
Person3: Einzug 01.01.2014
Zeitraum für die Erfassung wäre 01.01.2015 bis 28.02.2015
Ich muss dann überprüfen ob
1. Einzugsdatum vor Enddatum
2. Auszugsdatum nach Einzugsdatum
3. Wenn kein Auszugsdatum vorhanden trotzdem mitzählen
Ergebnis müsste dann 3 sein.
Bei mir sieht es so aus:
Einzugsdatum steht jeweils in LISTE!K15 bis LISTE!K30 (Listen erweiterbar - gehen mit mehr Einträgen über K30 oder L30 hinaus)
Auszugsdatum steht in LISTE!L15 bis LISTE!L30 (Kann aber auch sein, dass einzelne Zellen beim Auszugsdatum leer sind, wenn die Person noch nicht ausgezogen ist - diese sollen aber trotzdem mitgezählt werden - ich nehme dann einfach als Auszugsdatum HEUTE() mit gleicher Berechnung)
Zeitspanne: z.B. 01.01.2015 bis 28.02.2015
(die nehme ich aus einer bestimmten Zelle in der sie als „01.01.2015 bis 28.02.2015“ formatiert steht mit: LINKS(B3;FINDEN("-";B3;1)-1)*1 bzw. RECHTS(B3;FINDEN("-";B3;1)-1)*1
Für eine Zeile klappt es beispielhaft wunderbar mit folgender Formel:
=WENN(ISTLEER(LISTE!L20);SUMME(UND(LISTE!K20;(Liste!K20<=RECHTS(B3;FINDEN("-";B3;1)-1)*1);(HEUTE() >=LINKS(B3;FINDEN("-";B3;1)-1)*1)));SUMME(UND(LISTE!K20;(Liste!K20<=RECHTS(B3;FINDEN("-";B3;1)-1) *1) ; (Liste!L20>=LINKS(B3;FINDEN("-";B3;1)-1)*1))))
sobald ich aber versuche, dass ganz über mehrere Zeilen z.B. die Zeilen 15-100 laufen zu lassen kommt nur 0 raus.
Folgende Sachen habe ich dafür ausprobiert:
=SUMME(WENN(ISTLEER(LISTE!L15:LISTE!L20);ZÄHLENWENNS(LISTE!K15:LISTE!K20; (LISTE!K15:Liste!K20<=RECHTS(B3;FINDEN("-";B3;1)-1)*1);LISTE!L15:LISTE!L20;(HEUTE()>=LINKS(B3; FINDEN("-";B3;1)-1)*1));ZÄHLENWENNS(LISTE!K15:LISTE!K20;(LISTE!K15:Liste!K20<=RECHTS(B3; FINDEN("-"; B3;1)-1)*1);LISTE!L15:LISTE!L20;(LISTE!L15:LISTE!L20>=LINKS(B3;FINDEN("-";B3;1)-1)*1))) )
Auch mit der folgenden Formel geht es nicht (wobei der Fall, dass kein Auszugsdatum angegeben ist, damit auch noch nicht abgedeckt wäre):
=ZÄHLENWENNS(LISTE!K15:LISTE!K20;LISTE!K15:Liste!K20<=RECHTS(B3;FINDEN("-";B3;1)-1)*1; LISTE!L15:LISTE!L20;LISTE!L15:LISTE!L20>=LINKS(B3;FINDEN("-";B3;1)-1)*1)
Kann mir jemand weiterhelfen?

Bild

Betrifft: AW: Zählen über Liste mit verschiedenen Bedingungen
von: Peter Müller
Geschrieben am: 10.07.2015 15:33:42
"Anschauliches Beispiel:"
...mit einer Beispielmappe wäre das Beispiel noch anschaulicher...

Bild

Betrifft: z.B. mit SUMMENPRODUKT() ...
von: der neopa C
Geschrieben am: 10.07.2015 15:39:28
Hallo,
... für Deine 4 Beispieldaten:

 BCDEFG
1EinzugAuszug Ergebnisvonbis
222.12.201413.05.2015 301.01.201528.02.2015
322.03.201501.05.2015    
422.01.201404.02.2015    
501.01.2014     
6      

Formeln der Tabelle
ZelleFormel
E2=SUMMENPRODUKT((C2:C99+(C2:C99=0)*(B2:B99>0)*HEUTE()>=F2)*(B2:B99<=G2))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Bild

Betrifft: AW: Zählen über Liste mit verschiedenen Bedingungen
von: CB
Geschrieben am: 10.07.2015 16:09:32
Habe das gerade an meine Version angepasst.
Perfekt, klappt wunderbar. Ich werde das gleich mal nachvollziehen.
VIELEN DANK!

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Zählen über Liste mit verschiedenen Bedingungen"