Datei mit spez. Dateiname abspeichern

Sub Test() Sheets("Pfade Originaldateien").Select ChDir Range("C11") Workbooks.Open Filename:=Range("B11") Windows("Tool_Master.xls").Activate Sheets("Pfade Originaldateien").Select ChDir Range("C12") Windows("TOTAL_Kundenklassifikation.xls").Activate ActiveWorkbook.SaveAs Filename:=Range("B12") ActiveWindow.Close Sheets("Eingabe Maske").Select End Sub

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo
dann probier das mal aus
Bitte vorsichtig :-),... ich habe es nicht getestet

Option Explicit

Sub Test_Save()
    Dim qWkb As Workbook, tarWkb As Workbook
    Dim qWks As Worksheet, tarWks As Worksheet
    Dim qPath As String, qName As String, savePath As String, saveName As String
    On Error GoTo Error_Correction
    'Die Quelle ist "Tool_Master.xls", also
    'die aktuelle Mappe !!
    Set qWkb = ActiveWorkbook
    Set qWks = qWkb.Sheets("Pfade Originaldateien")
    With qWks
        qPath = .Range("B5")
        qName = .Range("C5")
        savePath = .Range("B6")
        saveName = .Range("C6")
    End With
    'Auf Backslasch am Pfadende prüfen
    If Left(qPath, 1) <> "\" Then
        qPath = qPath & "\"
    End If
    If Left(savePath, 1) <> "\" Then
        savePath = savePath & "\"
    End If
    'Eventuell Laufwerk wechseln
    'ChDrive Left(savePath, 1)
    ChDir savePath
    'Prüfung auf unerlaubte Zeichen im Dateinamen
    If CheckSaveName(qName) = False Then Exit Sub
    'Zielmappe öffnen und Object Zuweisung
    Set tarWkb = Workbooks.Open(qPath & qName)
    With tarWkb
        Application.DisplayAlerts = False
        .SaveAs savePath & saveName
        Application.DisplayAlerts = True
        .Close
    End With
    Sheets("Eingabe Maske").Select
    Error_Exit:
    Exit Sub

    Error_Correction:
    Select Case Err
        Case 68
            'Fehlendes Laufwerk
            MsgBox ("Das Gerät/Laufwerk das Sie angegeben haben existiert nicht")
            Resume Error_Exit
        Case 76
            'Fehlender Pfad
            MsgBox ("Der Pfad den Sie angegeben haben existiert nicht")
            Resume Error_Exit
        Case Else
            MsgBox "" & Chr$(13) & Err & " :" & Err.Description, vbCritical + vbOKOnly, "Unerwarteter Fehler"
            Resume Error_Exit
    End Select
End Sub

Function CheckSaveName(chkName As String) As Boolean
    '(C) Ramses
    'Prüft auf unerlaubte Zeichen im Dateinamen
    'Wenn unerlaubte Zeichen vorhanden dann FALSE
    Dim i As Integer
    For i = 1 To Len(chkName)
        Select Case Mid(chkName, i, 1)
            Case "\", "/", ">", "<", ":", "*", "?", "[", "]", "¦"
                MsgBox ("Unerlaubtes Zeichen """ & Mid(chkName, i, 1) & """ an Position " & i & " in " _
                & """" & chkName & """" & vbCrLf _
                & vbCrLf & "Speichervorgang wegen Fehler in Dateinamen abgebrochen")
                CheckSaveName = False
                Exit Function
        End Select
    Next i
    CheckSaveName = True
End Function

Gruss Rainer

guten morgen nochmals..
ich glaube ich habe dich bei deiner Frage nachdem, ob es sich nur um eine Datei handelt falsch verstanden. Es handelt sich durchaus nur um eine Datei, bei dem Makro wo wir jetzt dran sind.
Ich habe ja noch von einem anderen Problemchen geschrieben, dass ich die Pfade für andere Prozeduren ebenfalls aus den Zellen ziehen möchte.
Um dir zu erklären wofür ich das brauche, muss ich kurz noch etwas ausholen. Bis jetzt hatte ich ein Master File und Quell-files. Von den Quell-Files wurden die Daten mit V-lookup in das Masterfile gezogen.
Das läuft soweit.
Nun möchte ich (um das ganze "zu professionalisieren") die Pfade der Files aus den Zellen holen. Und das, woran wir eigentlich sind (File öffnen und kopie erstellen) brauche ich dafür, dass ich die S-verweise dann nicht ins Masterfile selbst gemacht werden, sondern in das neue File. Denn ich möchte Die Datenfiles vom Makro File (Master) trennen. Der Mater enthält somit nur Makros und sagt aus welchen 2 files der S-verweis geschehen muss.
War das so halbwegs verständlich?
Um somit nochmals zurückzukommen, ob nur ein File kopiert werden muss: JA, aber bei den anderen Files (für S-Verweise handelt es sich um mehrere).
Beim zweiten Problem des anpassen dass die Pfade für die S-verweise aus Zellen gezogen werde, habe ich wie oben bereits beschrieben, das Problem, dass ich das nicht so ändern kann wie ich möchte.
Falls du mir helfen möchtest, was ich natürlich sehr schätzen würde, ... es handelt sich um die Prozedur UmsatzStrecke() oben im Modul zwei. Ich hoffe wirklich, dass ich mich hier auf der Zielgeraden befinde und nicht wie alllzu oft die Probleme erst beginnen wenn man denkt man hat es jetzt.
Ps: bitte gib mir Bescheid ob du schweizer schoggi magst, ich fühle mich langsam aber sicher einer Gegenleistung schuldig ... ;-)

Beliebteste Forumthreads (12 Monate)

Datei mit spez. Dateiname abspeichern

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Datei mit spez. Dateiname abspeichern

14 Beiträge zum Forumthread Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread