Letzten Änderungsdatum der Datei eintrag

Forumthread: Letzten Änderungsdatum der Datei eintrag

19.05.2020 23:38:31

Sergej

Hallo Leute,
ich habe ab Zelle A3:A... eine Liste der Einträge mit vollständigen Pfad incl. Datenamen stehen.
Bsp. A3 = P:\Daten\Projekte\2020\Hauptschule Nest\Kundenliste.xls
In der Spalte recht daneben sprich Spalte B möchte ich gerne letzten Änderungsdatum der Datei eintragen.
Bsp. B3 = 2020-05-10 08:58 Uhr
Das Ganze soll soweit bis letzte benutzte Zelle der Spalte A durchgesführt werden.
Vor dem Start von Makro sollen die Daten von B3:B... (bis letzte benutzte Zelle der Spalte A) gelöscht werden. Wenn in Spalte A die Datei nicht existiert, dann die Zelle in ROT darstellen und das Makro weiterlaufen lassen.
Wie mache ich das bitte per VBA?
Vielen herzlichen Dank im Voraus!
Beste Grüße,
Sergej

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Letzten Änderungsdatum der Datei eintrag

20.05.2020 00:04:42

Oberschlumpf
AW: Letzten Änderungsdatum der Datei eintrag

20.05.2020 01:13:06

Werner
Nachtrag

20.05.2020 01:49:11

Werner
AW: Nachtrag

20.05.2020 11:53:55

Sergej
Gerne u. Danke für die Rückmeldung. o.w.T.

20.05.2020 12:33:16

Werner

AW: Letzten Änderungsdatum der Datei eintrag

20.05.2020 00:04:42

Oberschlumpf

Hi Sergej,
zeig uns doch mal eine Bsp-Datei per Upload mit Bsp-Daten.
Danke.
Ciao
Thorsten

AW: Letzten Änderungsdatum der Datei eintrag

20.05.2020 01:13:06

Werner

Hallo,
so:

Option Explicit
Sub letzte_Änderung()
Dim obFSO As Object, obFile As Object, i As Long
Set obFSO = CreateObject("Scripting.FileSystemObject")
'Blattname anpassen
With ThisWorkbook.Worksheets("Tabelle1")
For i = 3 To .Cells(.Rows.Count, "A").End(xlUp).Row
If obFSO.FileExists(.Cells(i, "A")) = True Then
Set obFile = obFSO.getfile(.Cells(i, "A"))
.Cells(i, "B").Value = obFile.DateLastModified
Else
.Cells(i, "B").Value = "Datei nicht gefunden!"
End If
Next i
End With
Set obFSO = Nothing: Set obFile = Nothing
End Sub

Gruß Werner

Nachtrag

20.05.2020 01:49:11

Werner

Hallo,
habe das Leeren der Spalte B am Anfang des Makros vergessen. Und wenn es denn unbedingt eine Färbung sein soll, wenn die Datei nicht gefunden wird.

Option Explicit
Sub letzte_Änderung()
Dim obFSO As Object, obFile As Object, i As Long
Set obFSO = CreateObject("Scripting.FileSystemObject")
'Blattname anpassen
With ThisWorkbook.Worksheets("Tabelle1")
.Range("B3:B" & .Cells(.Rows.Count, "A").End(xlUp).Row).ClearContents
For i = 3 To .Cells(.Rows.Count, "A").End(xlUp).Row
If obFSO.FileExists(.Cells(i, "A")) = True Then
Set obFile = obFSO.getfile(.Cells(i, "A"))
.Cells(i, "B").Value = obFile.DateLastModified
Else
.Cells(i, "A").Interior.Color = vbRed
End If
Next i
End With
Set obFSO = Nothing: Set obFile = Nothing
End Sub

Gruß Werner

AW: Nachtrag

20.05.2020 11:53:55

Sergej

Hallo Werner,
es funktioniert prima. Vielen herzlichen Dank!
Beste Grüße,
Sergej

Gerne u. Danke für die Rückmeldung. o.w.T.

20.05.2020 12:33:16

Werner

Beliebteste Forumthreads (12 Monate)

Letzten Änderungsdatum der Datei eintrag

Forumthread: Letzten Änderungsdatum der Datei eintrag

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread