Herbers Excel/VBA-Archiv

Inhalte von markierten Zellen vergleiche

• Inhalte von markierten Zellen vergleiche von Sergej vom 02.09.2020 11:54:31
• AW: Inhalte von markierten Zellen vergleiche - von Daniel am 02.09.2020 12:36:21
  • AW: Inhalte von markierten Zellen vergleiche - von Sergej am 02.09.2020 13:48:06

Betrifft: Inhalte von markierten Zellen vergleiche von: Sergej
Geschrieben am: 02.09.2020 11:54:31

Hallo Leute,

wie kann ich bitte per VBA von zwei markierten Zellen die Inhalte überprüfen?
Die neuen Texte / Wörter sollen farbig in GRÜN gekkenzeichnet werden. Die entfallen Texte / Wörter sollen durchgestrichen und in ROT dargestellt werden.

Vielen herzlichen Dank im Voraus!

Beste Grüße,
Sergej

  

Betrifft: AW: Inhalte von markierten Zellen vergleiche
von: Daniel
Geschrieben am: 02.09.2020 12:36:21

Hi

probiers mal so, Anleitung steht im Code
die Anzahl, wie oft ein Wort vorkommt, wird jedoch nicht verglichen.

Sub Zellen_WorteVergleich()

'--- die zwei Zellen, die miteinander vergleichen werden sollen, müssen
'--- nacheinander mit gedrückter STRG-Taste markiert werden.
'--- die Zelle mit dem alten Text zuerst, die Zelle mit dem neuen Text als zweites

Dim rng(0 To 1) As Range
Dim Txt(0 To 1) As String
Dim Worte(0 To 1)
Dim i As Long, w As Long
Dim Pos As Long

For i = 0 To 1
    Set rng(i) = Selection.Areas(i + 1)
    Txt(i) = rng(i).Text
    Worte(i) = Split(Txt(i), " ")
Next

For i = 0 To 1
    Pos = 0
    For w = 0 To UBound(Worte(i))
        Pos = Pos + 1
        If Worte(i)(w) <> "" Then
            If InStr(" " & Txt(1 - i) & " ", " " & Worte(i)(w) & " ") = 0 Then
                With rng(i).Characters(Pos, Len(Worte(i)(w))).Font
                    Select Case i
                        Case 0
                            .Color = vbRed
                            .Strikethrough = True
                        Case 1
                            .Color = vbGreen
                    End Select
                End With
            End If
        End If
        Pos = Pos + Len(Worte(i)(w))
    Next
Next
        
End Sub

Gruß Daniel

  

Betrifft: AW: Inhalte von markierten Zellen vergleiche
von: Sergej
Geschrieben am: 02.09.2020 13:48:06

Hallo Daniel,

vielen herzlichen Dank!

Beste Grüße,
Sergej

Beiträge aus dem Excel-Forum zum Thema "Inhalte von markierten Zellen vergleiche"