ich hatte mal eine Formel, wo ich den Text in einer Zelle A1 blinkend darstellen konnte. Leider ist mir die Formel nicht griffbereit. Kann mir jemand helfen?
Gruss
Reto
ich glaube mit Formel ist dies nicht Möglich. Nur mit VBA. Im Beispiel falls A1 =10
' **************************************************************
' Modul: DieseArbeitsmappe Typ = Element der Mappe(Sheet, Workbook, ...)
' **************************************************************
Option Explicit
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Ende
End Sub
Private Sub Workbook_Open()
Farbe = ThisWorkbook.Worksheets("Tabelle1").Range("A1").Interior.ColorIndex
If ThisWorkbook.Worksheets("Tabelle1").Range("A1") = 10 Then ersteFarbe
End Sub
' **************************************************************
' Modul: Tabelle1 Typ = Element der Mappe(Sheet, Workbook, ...)
' **************************************************************
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
If Range("A1") = 10 Then
If ET = "" Then ersteFarbe
Else
Ende
End If
End Sub
' **************************************************************
' Modul: Modul1 Typ = Allgemeines Modul
' **************************************************************
Option Explicit
Public ET As Variant
Public Farbe As Integer
Sub ersteFarbe()
ThisWorkbook.Worksheets("Tabelle1").Range("A1").Interior.ColorIndex = 3
ET = Now + TimeValue("00:00:01")
Application.OnTime ET, "zweiteFarbe"
End Sub
Sub zweiteFarbe()
ThisWorkbook.Worksheets("Tabelle1").Range("A1").Interior.ColorIndex = 33
ET = Now + TimeValue("00:00:01")
Application.OnTime ET, "ersteFarbe"
End Sub
Sub Ende()
On Error Resume Next
Application.OnTime EarliestTime:=ET, Procedure:="ErsteFarbe", Schedule:=False
Application.OnTime EarliestTime:=ET, Procedure:="zweiteFarbe", Schedule:=False
ET = ""
ThisWorkbook.Worksheets("Tabelle1").Range("A1").Interior.ColorIndex = Farbe
End Sub
Code eingefügt mit: Excel Code Jeanie
Gruß Hajo