Kopieren bestimmter Zellen in anderes Worksheet

Forumthread: Kopieren bestimmter Zellen in anderes Worksheet

22.12.2018 21:05:49

Michael

Guten Abend,
ich bin momentan dabei ein eigenständiges Reisekostenabrechnungstool zu entwerfen, um auch einmal eigenständig ein bisschen VBA-Kenntnisse mir anzueignen.
Leider hat es bei mir an einer Stelle gewaltig, alleine komme ich nicht weiter und im Netz finde ich auch nicht wirklich etwas brauchbares.
Vorab mein gewünschtes Ziel mit der Makro:
Mein Abrechnungstool besteht aus 2 Worksheets ("Input screen" und "Overview").
In den Input screen werden Information über die Reise (wie Stunden, Abfahrt,Ankunft,Ab-&Anreisedatum, welche Fortbewegungsmöglichkeiten) eingetragen, um dadurch zu ermitteln wie hoch die Kosten für Tagespauschale(wird per Formel automatisch ermittelt), Fortbewegungsmittel (PKW,Zug,Flug) und Hotelübernachtung (mit/ohne Nachweis) sind.
Diese Berechnungen stehen soweit.
Nun möchte ich mithilfe von zwei Buttons mein Tool ausbauen:
1.Button= setzt alle ausgefüllten Zellen im Input screen auf 0. (Dadurch neue Eingabe einer anderen Reise möglich). ->Bereits erfolgreich umgesetzt.
2.Button= Übernimmt gewissen Zellen und trägt diese in mein zweites Worksheet Overview. Dort sollen alle bisherigen Reise aufgelistet werden.
Und genau hier offenbart sich mir ein nicht-lösbares-Problem:
Die eingeben Infos sollten in Overview aufgelistet werden. Folgende Annahme:
In A4 bzw. Zeile 3 steht bereits eine Reise nach Berlin.
Nun soll die nächste eingegeben Reise sich logischerweise drunter ansiedeln (If/ then). Jedoch bekomme ich es nicht über die VBA Programmierung hin, dass die neue Reise, welche ich über die Inputmaske eingeben, eine Zeile später angesiedelt wird.
Leider wird somit immer wieder meine alte Reise in der Zeile 4 durch die neue Reise ersetzt
Zur Veranschaulichung hier mein Code:
Option Explicit

Sub ZellenTransfer()
'Zelleninhalte aus Input screen kopieren und in Overview auflisten
ThisWorkbook.Worksheets("Input screen").Select
Range("C5,D5,E5,F5,G5,K5,L5,M5,N5,O5,R5,S5,T5").Select
Selection.Copy Destination:=Worksheets("Overview").Range("A4")
If ThisWorkbook.Worksheets("Overview").Range("A4").Offset(1, 0)  "" Then
Worksheets("Overview").Range("A4").End(xlDown).Select
End If
End Sub

Da ich nach etlichen Stunden mir leider nicht mehr zu helfen weiß, wäre ich über Hilfe äußerst dankbar.

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Kopieren bestimmter Zellen in anderes Worksheet

22.12.2018 21:10:48

onur

Hier steht ja auch, dass in A4 kopiert werden soll:

Selection.Copy Destination:=Worksheets("Overview").Range("A4")

AW: Kopieren bestimmter Zellen in anderes Worksheet

23.12.2018 10:59:08

Werner

Hallo Michael,
so:

Option Explicit
Sub ZellenTransfer()
Dim loLetzte As Long
Application.ScreenUpdating = False
With Worksheets("Input screen")
With Worksheets("Overview")
loLetzte = .Cells(.Rows.Count, 1).End(xlUp).Offset(1).Row
If .Range("A4") = "" Then loLetzte = 4
End With
.Range("C5:G5,K5:O5,R5:T5").Copy Worksheets("Overview").Range("A" & loLetzte)
.Range("C5:G5,K5:O5,R5:T5").ClearContents
End With
End Sub

Zum Löschen/Leeren der Eingabefleder brauchst du so auch keinen extra Button. Das Makro überträgt die Daten ins Blatt Overview und leert dann die Eingabefelder wieder.
Gruß Werner

AW: Kopieren bestimmter Zellen in anderes Worksheet

23.12.2018 13:00:53

Gerd

Hallo Michael,
noch ein Gedicht.

Sub M()
Dim Q As Range, Z As Range
Set Q = ThisWorkbook.Worksheets("Input screen").Range("C5:G5,K5:O5,R5:T5")
With ThisWorkbook.Worksheets("Overview")
Set Z = .Cells(Application.Max(4, .Cells(.Rows.Count, 1).End(xlUp).Row + 1), 1)
End With
Q.Copy Z
Q.ClearContents
Set Q = Nothing: Set Z = Nothing
End Sub

Gruß Gerd

Beliebteste Forumthreads (12 Monate)

Kopieren bestimmter Zellen in anderes Worksheet

Forumthread: Kopieren bestimmter Zellen in anderes Worksheet

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Kopieren bestimmter Zellen in anderes Worksheet

Forumthread: Kopieren bestimmter Zellen in anderes Worksheet

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread