Zeilen in Spalten m. untersch. grossen Datensätzen

Forumthread: Zeilen in Spalten m. untersch. grossen Datensätzen

30.11.2007 11:16:59

Steffen

Hallo,
erstmal - NEIN, es geht nicht schon wieder um's Transponieren :-)
Ich habe eine Reihe von Datensätzen (Inventardaten von PCs), die untereinander geschrieben sind; dummerweise sind die Datensätze nicht identisch gross, d.h. zu einem PC habe ich 5 Datensätze, zu anderen 3, mal sind's 4 oder auch 6, etc. - transponieren fällt also flach
Bsp.:
Inventarfeld_1 PC_1 Wert
Inventarfeld_2 PC_1 Wert
Inventarfeld_3 PC_1 Wert
Inventarfeld_4 PC_1 Wert
Inventarfeld_5 PC_1 Wert
Inventarfeld_2 PC_2 Wert
Inventarfeld_4 PC_2 Wert
Inventarfeld_6 PC_2 Wert
Inventarfeld_1 PC_3 Wert
Inventarfeld_5 PC_3 Wert
Das ganz soll nun in eine Tabelle folgender Art (habe als Spaltentrenner " ; " eingefügt)
PC ; Inventarfeld_1 ; Inventarfeld_2 ; Inventarfeld_3 ; Inventarfeld_4 ; Inventarfeld_4 ; ...
PC_1 ; Wert ; Wert ; Wert ; Wert ; Wert
PC_2 ; ; Wert ; ; Wert
PC_3 ; Wert
Da ich fast 43000 Datensätze habe, und das Ganze auch wiederholbar sein sollte, möchte ich das automatisieren. Mit Pivot-Tabelle, Summenprodukten, sverweis etc. bin ich nicht weitergekommen. Lässt sich das in Excel überhaupt noch realisieren, oder ist das was für Access?
Gruss und Dank,
Steffen.

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread

Betreff

Datum

Anwender

AW: Zeilen in Spalten m. untersch. grossen Datensätzen

30.11.2007 17:13:00

Christian

AW: Zeilen in Spalten m. untersch. grossen Datensätzen

30.11.2007 17:13:00

Christian

Hallo Steffen,
als Ansatz mit Formeln und Hilfsspalten (Formeln tlw. von http://www.excelformeln.de/ )
Quelle:
Tabelle1

	A	B	C	D	E	F	G	H	I
1	Inventarfeld_1	PC_1	Wert		1	Inventarfeld_1	1	PC_1	PC_1Inventarfeld_1
2	Inventarfeld_2	PC_1	Wert		2	Inventarfeld_2	0	PC_2	PC_1Inventarfeld_2
3	Inventarfeld_3	PC_1	Wert		3	Inventarfeld_3	0	PC_3	PC_1Inventarfeld_3
4	Inventarfeld_4	PC_1	Wert		4	Inventarfeld_4	0		PC_1Inventarfeld_4
5	Inventarfeld_5	PC_1	Wert		5	Inventarfeld_5	0		PC_1Inventarfeld_5
6	Inventarfeld_2	PC_2	Wert		0	Inventarfeld_6	2		PC_2Inventarfeld_2
7	Inventarfeld_4	PC_2	Wert		0		0		PC_2Inventarfeld_4
8	Inventarfeld_6	PC_2	Wert		6		0		PC_2Inventarfeld_6
9	Inventarfeld_1	PC_3	Wert		0		3		PC_3Inventarfeld_1
10	Inventarfeld_5	PC_3	Wert		0		0		PC_3Inventarfeld_5

Formeln der Tabelle

Zelle	Formel
F1	=WENN(ZEILE(A1)>MAX(E:E); "";INDEX(A:A;VERGLEICH(ZEILE(A1); E:E;0)))
H1	=WENN(ZEILE(C1)>MAX(G:G); "";INDEX(B:B;VERGLEICH(ZEILE(C1); G:G;0)))
I1	=B1&A1
E2	=(ZÄHLENWENN(A$1:A2;A2)=1)*(MAX(E$1:E1)+1)
F2	=WENN(ZEILE(A2)>MAX(E:E); "";INDEX(A:A;VERGLEICH(ZEILE(A2); E:E;0)))
G2	=(ZÄHLENWENN(B$1:B2;B2)=1)*(MAX(G$1:G1)+1)
H2	=WENN(ZEILE(C2)>MAX(G:G); "";INDEX(B:B;VERGLEICH(ZEILE(C2); G:G;0)))
I2	=B2&A2
E3	=(ZÄHLENWENN(A$1:A3;A3)=1)*(MAX(E$1:E2)+1)
F3	=WENN(ZEILE(A3)>MAX(E:E); "";INDEX(A:A;VERGLEICH(ZEILE(A3); E:E;0)))
G3	=(ZÄHLENWENN(B$1:B3;B3)=1)*(MAX(G$1:G2)+1)
H3	=WENN(ZEILE(C3)>MAX(G:G); "";INDEX(B:B;VERGLEICH(ZEILE(C3); G:G;0)))
I3	=B3&A3

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Ziel:
Tabelle2

	A	B	C	D	E	F	G	H
1	PC	Inventarfeld_1	Inventarfeld_2	Inventarfeld_3	Inventarfeld_4	Inventarfeld_5	Inventarfeld_6
2	PC_1	Wert	Wert	Wert	Wert	Wert
3	PC_2		Wert		Wert		Wert
4	PC_3	Wert				Wert
5
6

Formeln der Tabelle

Zelle	Formel
B1	=WENN(INDIREKT(ADRESSE(SPALTE(A1); 6;;;"Tabelle1"))="";"";INDIREKT(ADRESSE(SPALTE(A1); 6;;;"Tabelle1")))
C1	=WENN(INDIREKT(ADRESSE(SPALTE(B1); 6;;;"Tabelle1"))="";"";INDIREKT(ADRESSE(SPALTE(B1); 6;;;"Tabelle1")))
D1	=WENN(INDIREKT(ADRESSE(SPALTE(C1); 6;;;"Tabelle1"))="";"";INDIREKT(ADRESSE(SPALTE(C1); 6;;;"Tabelle1")))
E1	=WENN(INDIREKT(ADRESSE(SPALTE(D1); 6;;;"Tabelle1"))="";"";INDIREKT(ADRESSE(SPALTE(D1); 6;;;"Tabelle1")))
F1	=WENN(INDIREKT(ADRESSE(SPALTE(E1); 6;;;"Tabelle1"))="";"";INDIREKT(ADRESSE(SPALTE(E1); 6;;;"Tabelle1")))
G1	=WENN(INDIREKT(ADRESSE(SPALTE(F1); 6;;;"Tabelle1"))="";"";INDIREKT(ADRESSE(SPALTE(F1); 6;;;"Tabelle1")))
H1	=WENN(INDIREKT(ADRESSE(SPALTE(G1); 6;;;"Tabelle1"))="";"";INDIREKT(ADRESSE(SPALTE(G1); 6;;;"Tabelle1")))
A2	=WENN(Tabelle1!H1="";"";Tabelle1!H1)
B2	=WENN(ODER($A2="";B$1="";ISTFEHLER(INDEX(Tabelle1!$C:$C;VERGLEICH($A2&B$1;Tabelle1!$I:$I;0)))); "";INDEX(Tabelle1!$C:$C;VERGLEICH($A2&B$1;Tabelle1!$I:$I;0)))
C2	=WENN(ODER($A2="";C$1="";ISTFEHLER(INDEX(Tabelle1!$C:$C;VERGLEICH($A2&C$1;Tabelle1!$I:$I;0)))); "";INDEX(Tabelle1!$C:$C;VERGLEICH($A2&C$1;Tabelle1!$I:$I;0)))
D2	=WENN(ODER($A2="";D$1="";ISTFEHLER(INDEX(Tabelle1!$C:$C;VERGLEICH($A2&D$1;Tabelle1!$I:$I;0)))); "";INDEX(Tabelle1!$C:$C;VERGLEICH($A2&D$1;Tabelle1!$I:$I;0)))
E2	=WENN(ODER($A2="";E$1="";ISTFEHLER(INDEX(Tabelle1!$C:$C;VERGLEICH($A2&E$1;Tabelle1!$I:$I;0)))); "";INDEX(Tabelle1!$C:$C;VERGLEICH($A2&E$1;Tabelle1!$I:$I;0)))
F2	=WENN(ODER($A2="";F$1="";ISTFEHLER(INDEX(Tabelle1!$C:$C;VERGLEICH($A2&F$1;Tabelle1!$I:$I;0)))); "";INDEX(Tabelle1!$C:$C;VERGLEICH($A2&F$1;Tabelle1!$I:$I;0)))
G2	=WENN(ODER($A2="";G$1="";ISTFEHLER(INDEX(Tabelle1!$C:$C;VERGLEICH($A2&G$1;Tabelle1!$I:$I;0)))); "";INDEX(Tabelle1!$C:$C;VERGLEICH($A2&G$1;Tabelle1!$I:$I;0)))
H2	=WENN(ODER($A2="";H$1="";ISTFEHLER(INDEX(Tabelle1!$C:$C;VERGLEICH($A2&H$1;Tabelle1!$I:$I;0)))); "";INDEX(Tabelle1!$C:$C;VERGLEICH($A2&H$1;Tabelle1!$I:$I;0)))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
MfG Christian

Beliebteste Forumthreads (12 Monate)

Zeilen in Spalten m. untersch. grossen Datensätzen

Forumthread: Zeilen in Spalten m. untersch. grossen Datensätzen

1 Beitrag zum Forumthread Beitrag zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread