Tabellenblätter löschen VBA

Forumthread: Tabellenblätter löschen VBA
4 Beiträge zu diesem Forumthread
Anzeige
300 Threads zu ähnlichen Themen
Top 100 Forumthreads

03.12.2007 20:03:00

Wolfgang

Hallo,
die ausgeblendeten Tabellenblätter "Kunde1", "Kunde2" und "Kunde3" sollen via Schaltfläche ohne Rückfrage auf einmal gelöscht werden. Im Anschluß sollen neue ausgeblendete Tabellenblätter "Kunde4,5 und 6" eingefügt werden. Die Blätter sollen vor dem Tabellenblatt "Start" eingefügt werden. Ist so etwas machbar? - Mit dem Makrorekorder bekomme ich das irgendwie nicht hin. Wäre daher für Hilfestellungen sehr dankbar.
Gruß - Wolfgang

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Tabellenblätter löschen VBA

03.12.2007 20:13:00

Josef
Kleine Umstellung bzw. Zusatzfrage

03.12.2007 20:28:00

Wolfgang
AW: Kleine Umstellung bzw. Zusatzfrage

03.12.2007 20:38:00

Josef
Danke - klappt super!

03.12.2007 20:47:00

Wolfgang

AW: Tabellenblätter löschen VBA

03.12.2007 20:13:00

Josef

Hallo Wolfgang,
meinst du so?
Sub Loeschen()
Dim intN As Integer, intI As Integer
Dim objSh As Worksheet

On Error GoTo ErrExit
Application.DisplayAlerts = False
Application.ScreenUpdating = False

For Each objSh In ThisWorkbook.Worksheets
    If Left(objSh.Name, 5) = "Kunde" Then
        intN = Application.Max(intN, Cint(Replace(objSh.Name, "Kunde", "")))
        objSh.Delete
    End If
Next

For intI = intN + 1 To intN + 3
    Set objSh = ThisWorkbook.Worksheets.Add(Before:=Sheets("Start"))
    objSh.Name = "Kunde" & CStr(intI)
    objSh.Visible = xlSheetHidden
Next

ErrExit:
Application.DisplayAlerts = True
Application.ScreenUpdating = True
Set objSh = Nothing
End Sub

Gruß Sepp

Kleine Umstellung bzw. Zusatzfrage

03.12.2007 20:28:00

Wolfgang

Hallo Josef,
sorry, ich habe da etwas übersehen. Die Reihenfolge ist "Kunde", "Kunde1" und "Kunde2", was müßte verändert werden, damit der Code dann auch noch läuft? Mit der ursprünglichen Reihenfolge läuft er prima. Vielleicht auch noch eine ergänzende Frage, wie der Code aussehen könnte, wenn genau die Reihenfolge "Kunde", Kunde1 und Kunde2 wieder eingefügt werden sollte. Danke schon jetzt wieder für die Rückmeldung.
Gruß - Wolfgang

AW: Kleine Umstellung bzw. Zusatzfrage

03.12.2007 20:38:00

Josef

Hallo Wolfgang,
dann so.
Sub Loeschen()
Dim intN As Integer, intI As Integer
Dim objSh As Worksheet
Dim bFortlaufend As Boolean

On Error GoTo ErrExit
Application.DisplayAlerts = False
Application.ScreenUpdating = False

bFortlaufend = True 'Nummern werden weitergezählt
'bFortlaufend = False 'Nummerierung beginnt bei 0 ("")

For Each objSh In ThisWorkbook.Worksheets
    If Left(objSh.Name, 5) = "Kunde" Then
        If bFortlaufend Then _
            intN = Application.Max(intN, Cint(Replace(objSh.Name, "Kunde", "0")) + 1)
        objSh.Delete
    End If
Next

For intI = intN To intN + 2
    Set objSh = ThisWorkbook.Worksheets.Add(Before:=Sheets("Start"))
    objSh.Name = "Kunde" & IIf(intI > 0, CStr(intI), "")
    objSh.Visible = xlSheetHidden
Next

ErrExit:
Application.DisplayAlerts = True
Application.ScreenUpdating = True
Set objSh = Nothing
End Sub

Gruß Sepp

Danke - klappt super!

03.12.2007 20:47:00

Wolfgang

Hallo Josef,
super, das klappt so, wie ich es mir vorgestellt hatte. Herzlichen Dank dafür, Danke auch für die Erläuterungen, da kann ich mehr vom Code verstehen.
Einen schönen Abend noch und weiterhin alles Gute.
Herzliche Grüße
Wolfgang