Übernahme bei zusätzlicher Seite

Forumthread: Übernahme bei zusätzlicher Seite

27.02.2008 09:25:28

m@rkus

Hallo,
ich habe folgendes Problem, ich hoffe mir kann jemand helfen.
Ich habe hier eine Excel-Tabelle, die in etwa folgendermaßen aussieht:
|Wert1|Datum|....65...|
|Wert2|Datum|....34...|
|Wert3|Datum|...........|
|Wert4|Datum|......8...|
|Wert5|Datum|...........|
|Wert6|Datum|...........|
|..........|..........|Summe|
nächste Seite:
|Wert7|Datum|....65...|
|..........|..........|...........|
|..........|..........|...........|
|..........|..........|...........|
|..........|..........|...........|
|..........|..........|...........|
|..........|..........|Summe|
Wenn die Tabelle nicht mehr auf eine Seite passt, soll auf der nächsten Seite automatisch die Summe erscheinen, d. h. sie soll errechnet werden.
Man könnte das Ganze als eine "Wiederholungszeile unten mit Formel" bezeichnen.
Es ist leider nicht ersichtlich, wie lange diese Tabelle wird.
Ist das irgendwie realisierbar und falls ja, wie?
Ich bin für jede Hilfe dankbar.

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Übernahme bei zusätzlicher Seite

01.03.2008 14:47:47

closer
AW: Übernahme bei zusätzlicher Seite

03.03.2008 16:21:00

m@rkus

AW: Übernahme bei zusätzlicher Seite

01.03.2008 14:47:47

closer

Hallo Markus,
eine Standardeinstellung dafür gibt es in EXCEL nicht.
Man kann so etwas aber per Makro einrichten. Dabei wird für die Summenberechnungen die Funktion TEILERGEBNIS verwendet. Siehe nachfolgendes Beispiel.
Gruß
Franz


Sub SummenformelEinfuegen()
'Löscht vorhandene Summenformeln und _
fügt an den Seitenwechseln und am Ende der Liste Formeln ein
Dim ws As Worksheet, lZeile As Long
Const lSpalteText As Long = 1
Const lSpalteFormel As Long = 3
Const ZeileStart As Long = 2 '1. Zeile mit Werten
Const strText1 As String = "Zwischensumme" 'Text unten auf Seite
Const strText2 As String = "Übertrag" 'Text oben auf Seite
Set ws = Worksheets("Tab1")
Application.ScreenUpdating = False
With ws
'vorhandene Zeilen mit Teilsummen entfernen
For lZeile = .Cells(.Rows.Count, lSpalteFormel).End(xlUp).Row To ZeileStart Step -1
If InStr(1, .Cells(lZeile, lSpalteFormel).Formula, "SUBTOTAL") > 0 Then
.Rows(lZeile).Delete shift:=xlShiftUp
End If
Next
'Seitenwechsel suchen und Formeln für Zwischensumme und Übertrag einfügen
lZeile = ZeileStart
Do Until lZeile = .Cells(.Rows.Count, lSpalteFormel).End(xlUp).Row
If .Rows(lZeile).PageBreak = xlPageBreakAutomatic Then
.Rows(lZeile - 1).Insert
.Cells(lZeile - 1, lSpalteText) = strText1
.Cells(lZeile - 1, lSpalteFormel).Formula = "=SUBTOTAL(9,R" & ZeileStart _
& "C" & lSpalteFormel & ":R[-1]C)"
.Rows(lZeile).Insert
.Cells(lZeile, lSpalteText) = strText2
.Cells(lZeile, lSpalteFormel).Formula = "=SUBTOTAL(9,R" & ZeileStart _
& "C" & lSpalteFormel & ":R[-1]C)"
lZeile = lZeile + 1
End If
lZeile = lZeile + 1
Loop
'Gesamtsummen-Formel einfügen
lZeile = lZeile + 1
.Cells(lZeile, lSpalteText) = "Gesamtsumme"
.Cells(lZeile, lSpalteFormel).Formula = "=SUBTOTAL(9,R" & ZeileStart _
& "C" & lSpalteFormel & ":R[-1]C)"
End With
Application.ScreenUpdating = True
Set ws = Nothing
End Sub

AW: Übernahme bei zusätzlicher Seite

03.03.2008 16:21:00

m@rkus

Vielen Dank für die tolle Hilfe, aber von Makros hab ich leider keine Ahnung...

Beliebteste Forumthreads (12 Monate)

Übernahme bei zusätzlicher Seite

Forumthread: Übernahme bei zusätzlicher Seite

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread