Microsoft Excel

Herbers Excel/VBA-Archiv

Altersberechnung

Betrifft: Altersberechnung von: Baywatch
Geschrieben am: 14.08.2008 17:44:29

Hi

ich habe ein kleines Problem bezüglich des Alters.

Ich habe eine Liste mit:

Spalte A : Name
Spalte B : Geschlecht (M oder W)
Spalte C : Alter

Wie kann ich mit nur einer Formel den Ältesten männlichen oder weiblichen Namen in ein Kästchen bekommen?
ISt dies möglich?

Gruß und Dank im Vorraus

  

Betrifft: AW: Altersberechnung von: Andreas Emmert
Geschrieben am: 14.08.2008 17:59:09

Hi,
etwas umständlich sicherlich, aber so get's:

Tabelle1

 ABC
1Stefanm14
2Martinm38
3Alexanderm23
4Mariaw14
5Mariechenw24
6Martinaw31
7   
8   
9   
10   
11Ältester Mann  Martin
12Älteste Frau  Martina

Formeln der Tabelle
ZelleFormel
C11{=BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(C1:C6=MAX(WENN(B1:B6="m";C1:C6;0)); ZEILE(C1:C6); 0))-1;0;1;1)}
C12{=BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(C1:C6=MAX(WENN(B1:B6="w";C1:C6;0)); ZEILE(C1:C6); 0))-1;0;1;1)}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

Grüße
Andreas


  

Betrifft: AW: Altersberechnung von: Baywatch
Geschrieben am: 14.08.2008 18:21:49

UNd ich habe in meiner Datei in Spalte B den NAchnamen, wie kann ich dies dann in diese Komplizierte Matrixberechnung mit einfließen lassen, alles andere konnte ich umschreiben.

Danke


  

Betrifft: AW: Wert zu Maximum mit Bedingung von: Erich G.
Geschrieben am: 14.08.2008 19:17:38

Hallo Vorname, ( siehe hierzu bitte mal in die Forums-FAQ )

wenn in Spalte B der Nachname steht - in welchen Spalten stehen dann Geschlecht und Alter?
In C und D?

Andreas' Formel arbeitet nicht korrekt. Teste mal mit einigen gleichen Altern.
In Spalte F findest du eine neue Formel (die hoffentlich richtig rechnet...):

 ABCDEF
1StefanMüllerm10MariechenMartin
2MartinMeierm40MartinaMartina
3AlexanderSchulzem40  
4Maria w20  
5Mariechen w50  
6Martina w60  

Formeln der Tabelle
ZelleFormel
E1{=BEREICH.VERSCHIEBEN($A$1;SUMME(WENN($D$1:$D$6=MAX(WENN($C$1:$C$6="m";$D$1:$D$6;0)); ZEILE($D$1:$D$6); 0))-1;0;1;1)}
F1{=INDEX(A:A;VERGLEICH("m"&MAX(($C$1:$C$6="m")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))}
E2{=BEREICH.VERSCHIEBEN($A$1;SUMME(WENN($D$1:$D$6=MAX(WENN($C$1:$C$6="w";$D$1:$D$6;0)); ZEILE($D$1:$D$6); 0))-1;0;1;1)}
F2{=INDEX(A:A;VERGLEICH("w"&MAX(($C$1:$C$6="w")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort


  

Betrifft: AW: Altersberechnung von: Ramses
Geschrieben am: 14.08.2008 19:17:55

Hallo

Ein wenig nachdenken und die Parameter der Funktion "Bereich.Verschieben" mal in der Online Hilfe nachlesen :-)

Tabelle1

 ABCDE
1StefanMusterm14 
2MartinMeisterm38 
3AlexanderGuterm23 
4MariaHelferw14 
5MariechenAntworterw24 
6MartinaFragerw31 
7    
8    
9    
10    
11Ältester MannMartin Meister   
12Älteste FrauMartina Frager   
13     

Formeln der Tabelle
ZelleFormel
B11{=BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="m";D1:D6;0)); ZEILE(D1:D6); 0))-1;0;1;1)&" "&BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="m";D1:D6;0)); ZEILE(D1:D6); 0))-1;1;1;1)}
B12{=BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="w";D1:D6;0)); ZEILE(D1:D6); 0))-1;0;1;1)&" "&BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="w";D1:D6;0)); ZEILE(D1:D6); 0))-1;1;1;1)}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

Gruss Rainer


  

Betrifft: AW: Altersberechnung von: Baywatch
Geschrieben am: 14.08.2008 19:25:08

Hi Leute das ist super und klappt auch nur leider habe ich noch dieses kleine Problem, das ich kein Alter da stehen habe, sondern leider ein Datum, gibt es da auch eine möglichkeit das inder Formel noch zu ändern, das der den Ältesten oder Jüngsten findet?

Danke schon einmal im Vorfeld ihr seit spitze.

GRuß

Daniel


  

Betrifft: AW: Altersberechnung von: Ramses
Geschrieben am: 14.08.2008 19:28:59

Hallo

Fragesteller wie du machen das Leben unnötig schwer.
Deine Vorgaben waren klar und die Antworten haben genau dein gestelltes Problem gelöst.

Ein klein wenig nachdenken täte bei deinem Level "Excel Gut" gut.
Wenn du nur das Geburtsdatum hast, ist das nun das Maximum im Datum oder das Minimum im Datum ?
Wenn du das Rätsel gelöst hast, weisst du was du in der Formel anpassen musst.

Gruss Rainer


  

Betrifft: AW: Altersberechnung von: Erich G.
Geschrieben am: 14.08.2008 19:34:28

Hallo Daniel (:-)),
schau doch mal bei den heutigen Forumsbeiträgen. Da gibt es zwei Threads, in denen es um die
Berechnung des Alters aus dem Geburtsdatum geht.

Wäre es nicht sinnvoll, die eigene Frage zu klären, BEVOR du mehrere Menschen damit beschäftigst?

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort


  

Betrifft: AW: Maximum mit Bedingung von: Erich G.
Geschrieben am: 14.08.2008 19:27:30

Hi Rainer,
die Formel arbeitet nur bei "schönen" Altern korrekt. Hier noch ein Beispiel:

 ABCDEF
1StefanMusterm20Martin MeisterMartin Meister
2MartinMeisterm30Mariechen Antworter
3AlexanderGuterm10  
4MariaHelferw15  
5MariechenAntworterw20  
6MartinaFragerw20  

Formeln der Tabelle
ZelleFormel
E1{=INDEX(A:A;VERGLEICH("m"&MAX(($C$1:$C$6="m")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))&" "&INDEX(B:B;VERGLEICH("m"&MAX(($C$1:$C$6="m")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))}
F1{=BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="m";D1:D6;0)); ZEILE(D1:D6); 0))-1;0;1;1)&" "&BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="m";D1:D6;0)); ZEILE(D1:D6); 0))-1;1;1;1)}
E2{=INDEX(A:A;VERGLEICH("w"&MAX(($C$1:$C$6="w")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))&" "&INDEX(B:B;VERGLEICH("w"&MAX(($C$1:$C$6="w")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))}
F2{=BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="w";D1:D6;0)); ZEILE(D1:D6); 0))-1;0;1;1)&" "&BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="w";D1:D6;0)); ZEILE(D1:D6); 0))-1;1;1;1)}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort


  

Betrifft: AW: Maximum mit Bedingung von: Ramses
Geschrieben am: 14.08.2008 19:30:09

Hallo

was meinst du mit "nur bei "schönen" Altern" ?

Das Ergebnis ist doch korrekt,... oder ?

Gruss Rainer


  

Betrifft: AW: Maximum mit Bedingung von: Baywatch
Geschrieben am: 14.08.2008 19:32:07

Hi ich versehe gerade nur noch Bahnhof helft mir und es stehen immer noch feste Zahlen da und kein Geburtstdatum.
ich glaube er meint was ist wenn zwei gleich alt sind oder?


  

Betrifft: AW: Maximum mit Bedingung von: Erich G.
Geschrieben am: 14.08.2008 19:37:29

Hi Rainer,
nee - in F2 steht ne Formel, aber das Ergebnis ist leer.

Schau mal das Ergebnis an, wenn du alle Männlein 10 und alle Weiblein 20 Jahre alt machst...

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort


  

Betrifft: AW: Maximum mit Bedingung von: Ramses
Geschrieben am: 14.08.2008 19:39:25

hallo

Lass mich nicht dumm sterben.
Wo ist das Problem ?
Die Formel wird einfach den ersten auswerfen.

Gruss Rainer


  

Betrifft: AW: Maximum mit Bedingung von: Baywatch
Geschrieben am: 14.08.2008 19:42:04

Habt ihr das bezüglich des Datums gelesen?


  

Betrifft: AW: Maximum mit Bedingung von: Erich G.
Geschrieben am: 14.08.2008 19:48:24

Hi Daniel,
ja doch, das haben wir gelesen - und auch schon geantwortet.

Rainers Antwort: https://www.herber.de/forum/messages/1001960.html

Meine Antwort: https://www.herber.de/forum/messages/1001957.html

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort


  

Betrifft: AW: Maximum mit Bedingung von: Erich G.
Geschrieben am: 14.08.2008 19:43:59

Hi Rainer,
nein, das tut es nicht.

Hier noch ein Bsp.:
(Wie kommt das Weiblein nach F1?)

 ABCDEF
1StefanMusterm10Martin MeisterMariechen Antworter
2MartinMeisterm30Martina FragerMartina Frager
3AlexanderGuterm30  
4MariaHelferw20  
5MariechenAntworterw31  
6MartinaFragerw33  

Formeln der Tabelle
ZelleFormel
E1{=INDEX(A:A;VERGLEICH("m"&MAX(($C$1:$C$6="m")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))&" "&INDEX(B:B;VERGLEICH("m"&MAX(($C$1:$C$6="m")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))}
F1{=BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="m";D1:D6;0)); ZEILE(D1:D6); 0))-1;0;1;1)&" "&BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="m";D1:D6;0)); ZEILE(D1:D6); 0))-1;1;1;1)}
E2{=INDEX(A:A;VERGLEICH("w"&MAX(($C$1:$C$6="w")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))&" "&INDEX(B:B;VERGLEICH("w"&MAX(($C$1:$C$6="w")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))}
F2{=BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="w";D1:D6;0)); ZEILE(D1:D6); 0))-1;0;1;1)&" "&BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="w";D1:D6;0)); ZEILE(D1:D6); 0))-1;1;1;1)}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort


  

Betrifft: AW: Maximum mit Bedingung von: Ramses
Geschrieben am: 15.08.2008 10:07:30

Hallo Erich

Jetzt habe ich es kapiert :-) Danke.
Ich habe die Formel diesbezüglich natürlich nicht durchgerechnet, sondern nur die beiden Teile zusammengebaut.

Gruss Rainer


  

Betrifft: AW: @Ramses von: Erich G.
Geschrieben am: 14.08.2008 20:25:32

Hi Rainer,
bislang war ich einfach zu faul, mir die BEREICH.VER...-Formel genauer anzusehen.

Ich denke, ich habe das Problem lokalisiert. Im Ausdruck SUMME(WENN(...)) werden,
wenn zwei Männlein maximal sind, deren Zeilennummern addiert. (Vgl. Formel in G1.)
Es sollte aber nur die erste Zeilennr. rauskommen, damit richtig verschoben wird.

Im Beispiel werden die Zeilennr. 2 und 3 addiert, dann 1 abgezogen.
A1 wird um 4 nach unten verschoeben - und schon haben wir das Mariechen:

 ABCDEFG
1StefanMusterm10Martin MeisterMariechen Antworter4
2MartinMeisterm30Martina FragerMartina Frager4 = 2 + 3 -1
3AlexanderGuterm30   
4MariaHelferw20   
5MariechenAntworterw31   
6MartinaFragerw33   

Formeln der Tabelle
ZelleFormel
E1{=INDEX(A:A;VERGLEICH("m"&MAX(($C$1:$C$6="m")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))&" "&INDEX(B:B;VERGLEICH("m"&MAX(($C$1:$C$6="m")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))}
F1{=BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="m";D1:D6;0)); ZEILE(D1:D6); 0))-1;0;1;1)&" "&BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="m";D1:D6;0)); ZEILE(D1:D6); 0))-1;1;1;1)}
G1{=SUMME(WENN(D1:D6=MAX(WENN(C1:C6="m";D1:D6;0)); ZEILE(D1:D6); 0))-1}
E2{=INDEX(A:A;VERGLEICH("w"&MAX(($C$1:$C$6="w")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))&" "&INDEX(B:B;VERGLEICH("w"&MAX(($C$1:$C$6="w")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))}
F2{=BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="w";D1:D6;0)); ZEILE(D1:D6); 0))-1;0;1;1)&" "&BEREICH.VERSCHIEBEN($A$1;SUMME(WENN(D1:D6=MAX(WENN(C1:C6="w";D1:D6;0)); ZEILE(D1:D6); 0))-1;1;1;1)}

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort


  

Betrifft: AW: @Ramses von: Erich G.
Geschrieben am: 14.08.2008 20:44:35

Hi,
jetzt habe ich wohl auch eine BEREICH...-Formel (in F1 und F2):

 ABCDEFG
1StefanMusterm10Stefan MusterStefan Muster0
2MartinMeisterm10Maria HelferMaria Helfer3
3AlexanderGuterm10   
4MariaHelferw10   
5MariechenAntworterw10   
6MartinaFragerw10   

Formeln der Tabelle
ZelleFormel
E1{=INDEX(A:A;VERGLEICH("m"&MAX(($C$1:$C$6="m")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))&" "&INDEX(B:B;VERGLEICH("m"&MAX(($C$1:$C$6="m")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))}
F1{=BEREICH.VERSCHIEBEN($A$1;MIN(WENN(C1:C6&D1:D6="m"&MAX(WENN(C1:C6="m";D1:D6;0)); ZEILE(D1:D6); ""))-1;0;1;1)&" "&BEREICH.VERSCHIEBEN($A$1;MIN(WENN(C1:C6&D1:D6="m"&MAX(WENN(C1:C6="m";D1:D6;0)); ZEILE(D1:D6); ""))-1;1;1;1)}
G1{=MIN(WENN(C1:C6&D1:D6="m"&MAX(WENN(C1:C6="m";D1:D6;0)); ZEILE(D1:D6); ""))-1}
E2{=INDEX(A:A;VERGLEICH("w"&MAX(($C$1:$C$6="w")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))&" "&INDEX(B:B;VERGLEICH("w"&MAX(($C$1:$C$6="w")*($D$1:$D$6)); $C$1:$C$6&$D$1:$D$6;0))}
F2{=BEREICH.VERSCHIEBEN($A$1;MIN(WENN(C1:C6&D1:D6="w"&MAX(WENN(C1:C6="w";D1:D6;0)); ZEILE(D1:D6); ""))-1;0;1;1)&" "&BEREICH.VERSCHIEBEN($A$1;MIN(WENN(C1:C6&D1:D6="w"&MAX(WENN(C1:C6="w";D1:D6;0)); ZEILE(D1:D6); ""))-1;1;1;1)}
G2{=MIN(WENN(C1:C6&D1:D6="w"&MAX(WENN(C1:C6="w";D1:D6;0)); ZEILE(D1:D6); ""))-1}

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort


  

Betrifft: AW: @Ramses von: Baywatch
Geschrieben am: 15.08.2008 00:03:34

Hi ihr excel Könner,

welche von den vielen Formeln ist denn jetzt die richtige für mich? Welche tut das richtige?

Und wegen dem Datum, wie es mit den JAhren machen würde ich ja vielleicht noch hinbekommen, aber es muß leider aufden Tag genau der älteste oder jüngste sein.

Danke euch

Gruß

Daniel


  

Betrifft: AW: @Ramses von: Baywatch
Geschrieben am: 15.08.2008 13:14:43

Wenn ich Max habe, dann gibt er mir den Jüngsten teilnehmer an, nur leider klappt das nicht bei min für den Ältesten? wieso?


  

Betrifft: AW: @Ramses von: Ramses
Geschrieben am: 15.08.2008 13:20:30

Hallo

Ich werde hier nichts mehr beantworten.
Ich sehe als Voraussetzung für weitere Unterstützung eine Mustertabelle wie sie definitiv aussieht.

Alles andere ist doch ein Ratespiel.

Gruss Rainer


  

Betrifft: AW: @Ramses von: Baywatch
Geschrieben am: 15.08.2008 13:28:23

Nein ich arbeite immer noch mit deiner tabelle, wie du sie vorgegeben hattest in deinem BEispiel, nur wenn du anstele einer ZAhl ein Datum eingibst und Max in der Formel stehen hast berechnet er den Jüngsten Teilnehmer, dann habe ich mir gedacht, wenn man Min eingibt, das er den Ältesten berechnet, aber leider macht er dann nur mist, oder soll ich dir meine Datei mal zur verfügung stellen?

Dank


  

Betrifft: AW: @Ramses von: Ramses
Geschrieben am: 15.08.2008 13:52:05

Hallo

"...aber leider macht er dann nur mist,.."

Excel macht keinen Mist

Tabelle1

 ABC
1Geburtdatum01.01.2002 
2Geburtdatum01.05.1978 
3Geburtdatum01.01.1981 
4Geburtdatum01.01.2002 
5Geburtdatum01.05.1978 
6Geburtdatum01.01.1964 
7Geburtdatum01.01.2002 
8Geburtdatum01.05.1978 
9Geburtdatum01.01.1981 
10Geburtdatum01.01.2002 
11Geburtdatum01.05.1978 
12Geburtdatum01.01.1981 
13Geburtdatum01.01.2002 
14Geburtdatum01.05.1978 
15Geburtdatum01.01.1981 
16Geburtdatum01.01.2002 
17   
18   
19ÄLTESTER01.01.1964 
20JÜNGSTER01.01.2002 
21   

Formeln der Tabelle
ZelleFormel
B19=MIN(B1:B17)
B20=MAX(B1:B16)


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

Allenfalls derjenige der die Daten eingibt.

Gruss Rainer


  

Betrifft: AW: @Ramses von: Baywatch
Geschrieben am: 15.08.2008 13:58:00

Ja so klappt das, wenn ich in der Formel mit deinem Beispiel von Gestern mit überschrifften und in der Matrixformel auch leere Kästchen dabei habe, gibt er mir den FEhler BEzug an und ich habe nur aus Max Min gemacht.
Bin glaube ich einfach zu dumm


  

Betrifft: Ohne Matrix von: Klaus M.vdT.
Geschrieben am: 15.08.2008 11:01:49

Hi Baywatch (fieser Vorname),

hier mal eine Möglichkeit ohne Matrix, dafür mit zwei Hilfsspalten.

https://www.herber.de/bbs/user/54627.xls

Grüße,
Klaus M.vdT.