"Einweglisten"

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Werner,
es funktioniert super:
die Drop Down Listen bleiben also ohne Leerstellen am Ende, wenn ich über "Namen", "neu" (bzw. "bearbeiten") eingebe:
=Tabelle wo die Liste steht!$E$2:INDEX(Tabelle wo die Liste steht!$E:$E; SUMME(N(Tabelle wo die Liste steht!$E$1:$E$99"")))
die Anzahl Zeilen kann ich durch Veränderung der "99" ändern, Spalte E durch z.B. M ersetzen.
Die Formel in I2 bezieht sich auf den Bereich A1 bis Z19 in jedem Tabellenblatt und ordnet dem Spaltennamen den jeweiligen Blattnamen zu; hierbei ist der Blattname so oft zu erwähnen, wie ich Spalten habe - also für Z19 in "Notarztwagen" 26 x rüberkopieren.
Die Formel in E2 "arbeitet" auf dem Tabellenblatt mit der Zusammenfassung, die sich aus den anderen Tabellenblättern ableitet. Sie erstreckt sich auf den Bereich G2 bis M9. Die im Bereich verwendeten Namen werden von Spalte A abgezogen und der Rest ab E2 dargestellt.
Die Urlauber und Kranken können händisch eingetippelt werden, die Formel aus I2 links rüberziehen geht nicht; alternativ kann ich in der Bearbeitungsleiste den Spaltenbuchstaben ersetzen (Formel aus Zwischenablage).
Ich wähle also den Fahrer für den Leiterwagen aus, der wird zeitgleich in die entsprechende Spalte der Zusammenfassung eingefügt und ist nicht mehr "einsetzbar". Ich muss nur darauf achten, dass ich die Zeilen von oben an ohne Leerfeld nutze.
Und jetzt neue Frage:
Allerdings sollte im Beispiel anstelle "Beimer" kein "Beifahrer" eingesetzt werden und aber "Schmitz" weiterhin "Schmitt" zugeordnet werden, dann wird die Formel in I2 auch eine MATRIX Formel.
Da verstehe ich nicht was Du meinst.
Und noch ´ne Frage: Können Formel E2 und I2 zu einer neuen Formel zusammengefasst werden (wenn ich z.B. keine Zusammenfassung brauche)?
LG
Oliver

Hallo Oliver,
... fällt mir schwerer als die aufgezeigten Formeln zu erstellen ;-)
- "...die Anzahl Zeilen kann ich durch Veränderung der "99" ändern, Spalte E durch z.B. M ersetzen." Zum ersten Frageteil ist anzumerken, dass Du in Deiner Beispielarbeitsmappe in den Zeilen ab 22 andere Textinhalte zu stehen hast, die dann dort nicht stehen dürfen, weil sie sonst mitgezählt werden. Und zum zweiten Frageteil: ja, wenn dann auch der Datensammelbereich entsprechend verschoben ist.
- wenn in "Notarztwagen" Daten bis z.B. in Spalte Z stehen würden, dann ist in "Fahrer" der Blattname 26 x rüberkopieren, aber muss auch der auszuwertende Bereich der Formel in E2 entsprechend groß vorgenommen werden. Aber jeweils nicht (viel) größer als max. notwendig (Matrixformeln sind Resoursen hungrig)
- Die Formel in E2 "arbeitet" auf dem Tabellenblatt mit der Zusammenfassung der bereits verplanten Fahrer, in den anderen Tabellenblättern. Der auszuwertende Bereich ist natürlich entsprechen so groß zu definieren, wie er auszuwerten ist, dann reduziert sich die Fahrerliste in Spalte E dynamisch um die bereits verplanten Fahrer aller anderen Tabellenblätter.
- Die Urlauber und Kranken können natürlich auch per Dropdown aus der Gesamtfahrerliste gwählt werden. Siehe unten (die Formel passt sich dynamisch an die gelisteten personen an)
- "... Ich muss nur darauf achten, dass ich die Zeilen von oben an ohne Leerfeld nutze" Ja, ansonsten muss die Formel in I2 auch eine Matrixformel werden, wie ich schon schrieb.
- "...Da verstehe ich nicht was Du meinst." . Weil mit der derzeitigen Formel in I2 zunächst die Anzahl der eingesetzten Fahrer ermittelt werden und deren Anzahl mit der "Zählzeile" der jeweiligen Auswertungsliste verglichen wird und mit INDEX() immer die Werte Zeile für Zeile aus den "Planlisten" genommen werden. Und da würden dann 0-Werte übernommen und die wirklich eingesetzten Fahrer nur zum Teil oder gar nicht.
- Deine Frage: "Können Formel E2 und I2 zu einer neuen Formel zusammengefasst werden (wenn ich z.B. keine Zusammenfassung brauche)" versteh ich wiederum nicht. Du brauchst die Zusammenfassung. Was genau meinst Du also mit dieser Frage.
Hier nun noch das Beispiel, wo in der Formel E2 der auszuwertende Bereich vergrößert wurde und wie die Zuordnung der Kranken und Urlauber erfolgen könnte. Stell da Beispile mach nach und lösch dann in Notarztwagen!B2 den Namen und sieh was dann in Fahrer K2:K3 (nicht) steht.

	E	F	G	H	I	J	K	L	M
1	noch einsetzbar		Krank	Urlaub	Dienstlimousine	Notarztwagen	Notarztwagen	Leiterwagen	Spritzenwagen
2	Schmidt		Meier	Grönemeier	Müller	Dr. Brinkmann	Beimer		Schulze
3	Schmidtmeier		Lennon	Kling		Schmitt	Schmitz		Mustermann
4	Kaiser			Zappa					Musterfrau
5	Graf								König
6	Herzog
7

Formeln der Tabelle

Zelle	Formel
E2	{=WENN(ZEILE(A1)>ANZAHL2(A:A)-1-SUMME(N(G$2:CZ$99<>"")); "";INDEX(A:A;KKLEINSTE(WENN(ZÄHLENWENN(G$2:CZ$99;A$2:A$99)=0;ZEILE($2:$99)); ZEILE(A1))))}
I2	{=WENN(ZEILE(A2)>ANZAHL2(INDEX(INDIREKT(I$1&"!A1:Z19"); ;ZÄHLENWENN($I$1:I$1;I$1))); "";INDEX(INDIREKT(I$1&"!A:Z"); ZEILE(A2); ZÄHLENWENN($I$1:I$1;I$1)))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Datengültigkeit der Tabelle

Zelle	Zulassen	Daten	Eingabe 1	Eingabe 2
G2	Liste		=Fahrer
H2	Liste		=Fahrer

Namen in Formeln

Zelle	Name	Bezieht sich auf
G2	Fahrer	=Fahrer!$A$2:INDEX(Fahrer!$A:$A;ANZAHL2(Fahrer!$A:$A))
H2	Fahrer	=Fahrer!$A$2:INDEX(Fahrer!$A:$A;ANZAHL2(Fahrer!$A:$A))

Namen verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

"Einweglisten"

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread