Symbol in CommandButton einfügen

Micha · 2021-01-14T18:08:01+00:00

Hallo, habe eine UserForm mit einigen CommandButton. Diese sollen nun Symbole wie Drucken, Speichern usw... eingefügt bekommen. Habe die Excel-Version 2016. Ich gehe zu: - Symbolleiste für den Schnellzugriff anpassen -Weitere Befehle.... -Rechtsklick auf Symbol (um es zu kopieren!) funktioniert aber nicht. Was muss ich anstellen, damit ich ein Symbol in den CommandButton "Picture(keine)" bekomme? Für Euer Bemühen bedanke ich mich bereits im Voraus. MfG Micha

Hallo Micha,
ein Beispiel:

Private Sub UserForm_Activate()
CommandButton1.Picture = CommandBars(9).Controls(7).Picture
End Sub

An die Icons kommst du so:

Option Explicit

Private Declare PtrSafe Function MakeSureDirectoryPathExists Lib "imagehlp.dll" ( _
    ByVal DirPath As String) As Long

Public Sub Export_Icons()

    Dim objPicture As IPictureDisp
    Dim objCommandBar As CommandBar
    Dim objCommandBarControl As CommandBarControl
    Dim strPath As String

    strPath = ThisWorkbook.Path & "\CommandbarIcons\"

    Call MakeSureDirectoryPathExists(strPath)

    On Error Resume Next

    For Each objCommandBar In CommandBars

        For Each objCommandBarControl In objCommandBar.Controls

            Set objPicture = objCommandBarControl.Picture

            If Err.Number = 0 Then

                Call stdole.SavePicture(Picture:=objPicture, _
                    Filename:=strPath & Format$(objCommandBar.Index, "000") & _
                    "_" & Format$(objCommandBarControl.Index, "000") & ".bmp")

            Else
                Err.Clear
            End If
        Next
    Next
End Sub

Die 1. Zahl ist die Commandbar die 2. Zahl das Control. Es gibt viel mehr Icons, wenn du das gewünscht nicht findest, dann melde dich.
Wenn du die RibbonIcons in einem Commanbutton nutzen willst, dann so:

Private Sub UserForm_Initialize()
    Set CommandButton1.Picture = _
        Application.CommandBars.GetImageMso("AnimationTriggerAddMenu", 20, 20)
    Set CommandButton2.Picture = _
        Application.CommandBars.GetImageMso("PrintPreviewClose", 20, 20)
End Sub

Die Bezeichnung des Icons findest du in der IconGallery dieser Mappe:
https://www.herber.de/bbs/user/143016.zip
Gruß
Nepumuk

Hallo Oisse,
Du kannst auch über die API kopieren. Ersetze den Code mit diesem hier:

Code:
[Cc][+][-]

Option Explicit

Private Declare PtrSafe Function GlobalAlloc Lib "kernel32" (ByVal wFlags As Long, _
        ByVal dwBytes As LongPtr) As LongPtr
Private Declare PtrSafe Function GlobalFree Lib "kernel32" (ByVal hMem As LongPtr) As LongPtr
Private Declare PtrSafe Function GlobalLock Lib "kernel32" (ByVal hMem As LongPtr) As LongPtr
Private Declare PtrSafe Function GlobalUnlock Lib "kernel32" (ByVal hMem As LongPtr) As Long
Private Declare PtrSafe Function lstrcpy Lib "kernel32" (ByVal lpString1 As Any, _
        ByVal lpString2 As Any) As LongPtr
Private Declare PtrSafe Function SetClipboardData Lib "user32" (ByVal wFormat As Long, _
        ByVal hMem As LongPtr) As LongPtr
Private Declare PtrSafe Function OpenClipboard Lib "user32" (ByVal hwnd As LongPtr) As Long
Private Declare PtrSafe Function CloseClipboard Lib "user32" () As Long
Private Declare PtrSafe Function EmptyClipboard Lib "user32" () As Long

Private Sub cmdCopy_Click()
'Kopieren von Text über die API
  Dim hMem As LongPtr, lpGMem As LongPtr, sCliptext As String
  
  sCliptext = imageMso.Caption
  hMem = GlobalAlloc(&H42, Len(sCliptext) + 1)
  lpGMem = GlobalLock(hMem)
  lpGMem = lstrcpy(lpGMem, sCliptext)
  If GlobalUnlock(hMem) = 0 Then
     If OpenClipboard(0&) <> 0 Then
        EmptyClipboard
        SetClipboardData 1, hMem  '=CF_TEXT
        CloseClipboard
     End If
  End If
'GlobalFree hMem     'nur einmalig bereitstellen, Zwischenablage löschen
End Sub

_________________________
viele Grüße aus Freigericht 😊
Karl-Heinz

Symbol in CommandButton einfügen

Forumthread: Symbol in CommandButton einfügen

16
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial

Symbole in CommandButtons einfügen in Excel

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

Symbol in CommandButton einfügen

Forumthread: Symbol in CommandButton einfügen

16 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Infobox / Tutorial

Symbole in CommandButtons einfügen in Excel

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

16
Beiträge zum Forumthread

Beiträge zu diesem Forumthread