Teilstring finden mit Zahl

Forumthread: Teilstring finden mit Zahl

23.08.2022 10:25:21

Brenneis

Guten Morgen zusammen,
für eine Vollständigkeitsanalyse würde ich gerne auf eine Formel zurückgreifen, die Zahlen als Teilstring in Zellen findet. Ich habe eine Ausgangsmatrix, in der Zahlen teilweise in einer Aufzählung hintereinander stehen: Zum Beispiel: "5 , 6 , 7" - In einer Suchspalte würde ich nun gerne für die einzelnen Zahlen - also 5 ; 6 ; 7 schauen, ob diese in der Ausgangsmatrix vorhanden sind. Bisher konnte ich für diesen Anwendungsfall nur eine Lösung mit reinem Text finden: =WENNFEHLER(@INDEX(Bereich;AGGREGAT(15;6;(ZEILE(Bereich)-1)/ - Credits: https://www.youtube.com/watch?v=JkyR6s0aBok
Hat jemand eine Idee? Ich habe euch eine Datei mit der Logik hinterlegt:
https://www.herber.de/bbs/user/154775.xlsx
Liebe Grüße aus Köln

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Teilstring finden mit Zahl

23.08.2022 10:33:22

{Boris}

Hi,
G4:
=ODER(ISTZAHL(FINDEN(","&F4&",";","&WECHSELN(D$4:D$9;" ";"")&",")))
und runterkopieren.
VG, Boris

Ergänzung: In Deiner Excelversion...

23.08.2022 11:30:41

{Boris}

Hi,
...kann man das Ergebnis auch spillen lassen.
Hab ODER(ISTZAHL(...)) zudem durch ANZAHL ersetzt - jetzt bekommst Du nicht mehr WAHR oder FALSCH sondern 1 oder 0:
G4:
=NACHZEILE(F4:F18;LAMBDA(a;ANZAHL(FINDEN(","&a&",";","&WECHSELN(D4:D9;" ";"")&","))))
VG, Boris

AW: Teilstring finden mit Zahl

23.08.2022 14:19:11

Daniel

Hi
Probiert mal diese Formel in Zeile 4


=WENN(SUMMENPRODUKT(--ISTZAHL(FINDEN(" , "&F4&" , ";" , "&$D$4:$D$8&" , ")));"Vorhanden"; "Nicht vorhanden")

Sollte in jeder Excelversion funktionieren.
Bei Excel 365 kannst du auch "Summe" statt "Summenprodukt" schreiben.
Wichtig ist, dass die Trennzeichen zwischen den Zahlen immer gleich geschrieben sind und du die Trennzeichen auch genauso in die Formeln übernimmst.
Gruß Daniel

Die erste Formel...

23.08.2022 15:08:59

{Boris}

Hi,
...mit ODER(....) funktioniert auch in jeder Excelversion, hat die selbe Logik wie Deine mit dem Unterschied, dass z.B. 13 auch bei 12,13,14 und nicht nur bei 12, 13, 14 erkannt wird.
VG, Boris

AW: Die erste Formel...

23.08.2022 18:52:29

Daniel

das mit dem Wechseln kann man, wenn man will auch bei meiner Formel übernehmen.
ODER liefert halt erstmal nur WAHR oder FALSCH und nicht "Vorhanden", "Nicht vorhanden", ok das ist eine einfache WENN-Funktion, die auch Anfänger können sollten.
Wenn man ODER auch in älteren Excelversionen einsetzt, sollte man aber dazuschreiben, dass man dann eine Matrixformel hat, die den Abschuss der Eingabe mit STRG+SHIFT+ENTER erfordert, ansonsten liefert die Formel zwar keinen Fehler, aber ein falsches Ergebnis, was tückisch ist.
das mit dem Summenprodukt ist zwar auch eine Matrixformel, aber Summenprodukt enthält die automatische Matrixformelerkennung , wie sie in 365 generell vorhanden ist, auch schon in älteren Excelversionen, womit die Fehlerquelle, das STRG+SHIFT+ENTER zu vergessen, entfällt.
Gruß Daniel

AW: Die erste Formel...

24.08.2022 12:25:33

{Boris}

Hi Daniel,
das weiß ich alles - und ich weiß auch, dass Du das weißt.
Es würde doch schon reichen, wenn Du einleitest mit "Alternativ kann man das so lösen...".
Ohne diesen Zusatz kommt das immer so rüber wie "Alles Murks bisher - jetzt komm ich mit der einzig wahren Antwort".
Zusätze bezüglich Excelversionen kann man natürlich bringen - hier hatte der TE aber xl365 angegeben - dann gebe ich i.d.R. keinen Hinweis auf veränderte Eingabemethoden in älteren Versionen (für das Archiv mag das aber sinnvoll sein). Fraglich nur, wie lange zurück man auf ältere Versionen hinweist.
Der Klassiker z.B. - SVERWEIS mit mehreren Treffern - ist in xl365 mit FILTER ein Knallfrosch - dann gebe ich nicht zusätzlich die Antwort mit INDEX-AGGREGAT (die auch schon tausendfach im Archiv vorhanden ist), sofern der Frager xl365 im Einsatz hat.
Also teile hier weiter gerne Dein umfangreiches Wissen - und es wird (zumindest von mir) noch besser aufgenommen, wenn Du Dich ein bisschen in den jeweiligen Thread-Verlauf integrierst :-)
VG, Boris

AW: ne Teil-Alternative könnte ich beisteuern ...

24.08.2022 13:24:02

neopa

Hallo Boris,
... nachfolgende Formel ist auch für alle älteren Excelversionen funktionsfähig und benötigt auch keinen Matrixformelabschluss. Aufgestellt hatte ich diese gestern "für mich".
In G4:
=WENN(ANZAHL(INDEX(FINDEN(","&F4&",";","&WECHSELN(D$4:D$8;" ";"")&",");));"";"Nicht ")&"vorhanden"
Gruß Werner
.. , - ...

Den "Matrixformelabschluss"...

24.08.2022 13:29:31

{Boris}

Hi Werner,
...benötigt der TE nicht, da er xl365 im Einsatz hat. Die Umgehung von Strg+Shift+Enter mit INDEX ist ja inzwischen hinreichend bekannt - bietet hier aber imho keinen Mehrwert - auch nicht ggü. der SUMMENPRODUKT-Variante von Daniel.
Aber nun hat der TE ja ausreichend Auswahlmöglichkeiten ;-)
VG, Boris

AW: das war/ist mir schon klar ...

24.08.2022 14:32:37

neopa

Hallo Boris,
... ich schrieb ja nicht den TE und auch, dass es eine Teil-Alternativ für ältere XL-Versionen wäre. Diese sich darauf bezieht, dass ich anstelle Deiner ODER()-Beziehung und Daniels SUMMENPRODUKT() die Auswertung mit Hilfe von ANZAHL() vornehme.
Gruß Werner
.. , - ...

Auch ANZAHL....

24.08.2022 14:46:03

{Boris}

Hi Werner,
...war schon mit in der Verlosung
Hab ODER(ISTZAHL(...)) zudem durch ANZAHL ersetzt - jetzt bekommst Du nicht mehr WAHR oder FALSCH sondern 1 oder 0:
wenn auch nur bei der NACHZEILE-Spill-Variante.
Es gibt - wie so oft - viele Excel-Wege nach Rom. Wenn man eine grundlegende Alternative aufzeigt (z.B. PQ statt Formel), bietet das ja Mehrwerte - und zwar für alle.
Aber für eine bestehende Lösung wird ein Thread imho nur unnötig aufgebläht durch Alternativlösungen, die keinerlei Mehrwert bringen. Zudem verwirrt man die Frager oft auch mehr als man ihnen dadurch hilft (auch wenn es gut gemeint ist).
Im Extremfall hatte ich mal woanders ein Lösung mit Wahrheitswerten gepostet à la:
=(A1>1)+0
woraufhin zeitlich deutlich später eine weitere Antwort kam:
Das geht auch so:
=--(A1>1)
Mehrwert = Null, Verwirrung beim Frager: tendenziell 100% ;-)
VG, Boris

Beliebteste Forumthreads (12 Monate)

Forumthread: Teilstring finden mit Zahl

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Teilstring finden mit Zahl

Forumthread: Teilstring finden mit Zahl

10 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread