Werte aus anderer Datei auslesen

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Mario,
kopiere dir bitte folgenden Code in ein Modul deiner Datei2:

Sub Daten_suchen()
Dim wkb As Workbook
Dim geoeffnet As Boolean
Dim wkbName As String, wkbPath As String, Kuerzel As String
Dim rZelle As Range
wkbName = "Datei1.xls"
wkbPath = "H:\Dokumente\Fuhrpark"
' feststellen, ob Datei schon geöffnet
For Each wkb In Application.Workbooks
If wkb.Name = wkbName And wkb.Path = wkbPath Then geoeffnet = True
Next wkb
' entsprechend reagieren
If geoeffnet Then
Workbooks(wkbName).Activate
Else
Workbooks.Open Filename:=wkbPath & "\" & wkbName, UpdateLinks:=0
End If
Kuerzel = ThisWorkbook.Worksheets("Tabelle1").Range("A2").Value
' Kürzel suchen
Set rZelle = Workbooks(wkbName).Worksheets("Tabelle1").Range("C:C").Find(Kuerzel, LookIn:= _
xlValues, LookAt:=xlWhole)
If Not rZelle Is Nothing Then
MsgBox "Gefundener Wert: " & rZelle.Value & "   Zelle: " & rZelle.Address
' Wert in Zelle schreiben:
ThisWorkbook.Worksheets("Tabelle1").Range("A3").Value = _
Workbooks(wkbName).Worksheets("Tabelle1").Range(rZelle.Address).Value
Else
MsgBox "Wert nicht gefunden."
End If
If geoeffnet Then
Thisworkbook.Activate
Else
' Datei1 schließen
Application.DisplayAlerts = False
Workbooks(wkbName).Close
Application.DisplayAlerts = True
End If
End Sub

Es wird zunächst geprüft ob Datei1 schon geöffnet ist, wenn Nein dann wird dies getan. Anschließend wird dein Kürzel wie gewünscht darin gesucht und als MsgBox dir Wert und Ort wiedergegeben.
Sei dir aber bewusst, dass so nur das 1. Auftreten des Kürzels gefunden wird. Kann es mehrfach vorkommen, muss man den Code ändern.
lg Matthias

Hallo,
starte das mal in der Datei2:

Public Sub DateiLesen()

Dim wkbQuelle As Workbook

Dim wksZiel As Worksheet

Dim strSB As String

'Set wkbQuelle = Workbooks.Open("H:\Dokumente\Fuhrpark\Datei1.xls")

Set wkbQuelle = Workbooks.Open("C:\Dokumente und Einstellungen\bla_2\Desktop\StraßeC.xls")

Set wksZiel = ThisWorkbook.Worksheets("Tabelle1")

'alte Ergebnisse löschen

'wksZiel.Range("G5").CurrentRegion.Clear

strSB = wksZiel.Range("A2") 'der Suchbegriff

With wkbQuelle.Worksheets("Tabelle1").Range("A1")

'Spalte C filtern

.AutoFilter Field:=3, Criteria1:=strSB

'die dann sichtbaren Zellen nach G5 kopieren

.CurrentRegion.SpecialCells(xlCellTypeVisible).Copy wksZiel.Range("G5")

End With

wkbQuelle.Close SaveChanges:=False

Set wkbQuelle = Nothing

Set wksZiel = Nothing

End Sub

Gruß
Alfons
http://vba1.de

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Werte aus anderer Datei auslesen

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread