Aus Excel Word Tabelle aus Kopfzeile auslesen

Forumthread: Aus Excel Word Tabelle aus Kopfzeile auslesen

01.03.2017 10:47:51

Milo

Hallo Zusammen,
habe schon alles versucht aber ....
Mein Problem ist, dass ich nicht schaffe, aus Excel über einen Makro, von einer Word-Datei, auf einer Tabelle in der Kopfzeile zuzugreifen. Die Kopfzeile ist immer so aufgebaut, dass in den ersten 3 Zeilen normaler Text steht und danach erst eine 3 zeilige Tabelle mit unterschiedlichen Spalten, mit Daten eingefügt ist.
Tabellenaufgliederung:
1.Zeile mit einer Spalte
2.Zeile mit drei Spalten
3.Zeile mit drei Spalten
Ich müsste die Daten aus 3.Zeile 2.Spalte auslesen.
Besten Dank im Voraus

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Worddatei mit Tabelle in Kopfzeile...

01.03.2017 11:21:33

Case
AW: Worddatei mit Tabelle in Kopfzeile...

02.03.2017 18:12:10

Milo
Bezogen auf Deine...

03.03.2017 08:03:04

Case

Worddatei mit Tabelle in Kopfzeile...

01.03.2017 11:21:33

Case

Hallo, :-)
... kannst Du auf verschiedenen Wegen auslesen: ;-)

Variable = DasWordDokument.Sections(1).Headers(wdHeaderFooterFirstPage).Shapes(1). _
TextFrame.TextRange.Tables(1).Rows(3).Cells(2).Range.Text

Oder...

Variable = DasWordDokument.Sections(1).Headers(wdHeaderFooterPrimary).Range. _
Tables(1).Cell(3, 2).Tables(1).Cell(3, 2).Range.Text

Kommt ganz darauf an... ;-)
"DasWordDokument", "wdHeaderFooterFirstPage" bzw. "wdHeaderFooterPrimary" musst Du natürlich auf Deine Gegebenheiten anpassen.
Wenn es nicht klappt - Worddokument zur Verfügung stellen.
Servus
Case

AW: Worddatei mit Tabelle in Kopfzeile...

02.03.2017 18:12:10

Milo

Hallo Case,
habe es leider nicht hinbekommen.
Anbei die Datei.
https://www.herber.de/bbs/user/111906.doc
Gruss
Milo

Bezogen auf Deine...

03.03.2017 08:03:04

Case

Hallo Milo, :-)
... Beispieldatei: ;-)

Option Explicit
Const wdHeaderFooterPrimary = 1
Dim blnTMP As Boolean
Public Sub Test()
Dim objWDD As Object
Dim objApp As Object
On Error GoTo Fin
' Word sichtbar
'Set objApp = OffApp("Word")
' Word NICHT sichtbar
Set objApp = OffApp("Word", False)
If Not objApp Is Nothing Then
' Pfad- und Dateiname anpassen!!!!
Set objWDD = objApp.Documents.Open("C:\Temp\Kopf.doc")
Range("A" & Rows.Count).End(xlUp).Offset(1, 0).Value = _
Replace(objWDD.Sections.First.Headers(wdHeaderFooterPrimary) _
.Range.Tables(1).Cell(5, 2).Range.Text, _
Chr(13) & Chr(7), "")
objWDD.Close False
Else
MsgBox "Applikation nicht installiert!"
End If
Fin:
Set objWDD = Nothing
If Not objApp Is Nothing Then
If blnTMP = True Then
objApp.Quit
blnTMP = False
End If
End If
Set objApp = Nothing
If Err.Number  0 Then MsgBox "Fehler: " & _
Err.Number & " " & Err.Description
End Sub
Private Function OffApp(ByVal strApp As String, _
Optional blnVisible As Boolean = True) As Object
Dim objApp As Object
On Error Resume Next
Set objApp = GetObject(, strApp & ".Application")
Select Case Err.Number
Case 429
Err.Clear
Set objApp = CreateObject(strApp & ".Application")
blnTMP = True
If blnVisible = True Then
On Error Resume Next
objApp.Visible = True
Err.Clear
End If
End Select
On Error GoTo 0
Set OffApp = objApp
Set objApp = Nothing
End Function

Hier kannst Du dir noch weitere Informationen rausziehen. Auch wenn Du z. B. mehrere Worddokumente auslesen willst. ;-)
Posts mit dem Label Word werden angezeigt...
Das "Replace Chr(13) & Chr(7)" ist wegen der "Zellenende Markierung" drin: ;-)
Servus
Case

Beliebteste Forumthreads (12 Monate)

Aus Excel Word Tabelle aus Kopfzeile auslesen

Forumthread: Aus Excel Word Tabelle aus Kopfzeile auslesen

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread