Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1488to1492
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Daten mit mehreren Suchkriterien in 2. Tabelle

Daten mit mehreren Suchkriterien in 2. Tabelle
28.04.2016 10:23:36
Albrecht
Werte Experten,
Ich habe in Tab. 1 (hier benannt "AF_CB_FV" eine Checkliste. In Tab. 2 (hier "NCs") sollen untereinander nur die Einträge erscheinen, die zwei Suchkriterien entsprechen. Mit Hilfe von Herrn Thehos habe ich mir in Tab. 2 folgende Formel zurechtgefummelt:
=WENNFEHLER(INDEX('AF_CB_FV '!A2:A332;AGGREGAT(15;6;ZEILE('AF_CB_FV '!D2:D332) /(('AF_CB_FV '!D2:D332="Major")*('AF_CB_FV '!F2:F332="x"));zeile());-1;1);"")
Im beiliegenden Bspl. müssten im Blatt "NCs" jetzt drei Ergebnisse erscheinen, für welche die beiden Suchkriterien zutreffen. Tun sie aber unverschämter Weise nicht.
PS: Leider gibt es erst mal kein "beiliegendes Beispiel", weil ich mit mit dem File-Upload jetzt 10X im Kreis gedreht habe, und, nachdem ich die Datei ausgesucht und den Code kopiert habe, nicht weiß, wie es weiter geht. Wo muss ich diesen Code dann einfügen? Tut mir Leid - kann mir jemand erst mal damit helfen?
Kann mir jemand helfen? Was mache ich falsch?
Herzlichen Dank im Voraus!
Albrecht

12
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Daten mit mehreren Suchkriterien in 2. Tabelle
28.04.2016 12:00:49
Werner
Hallo Albrecht,
nur zum File-Upload:
oberhalb dieses Fensters - zum File-Upload - dann -Durchsuchen- entsprechende Datei auswählen -Datei zum Server- im Fenster wird dann ein generierter Link angezeigt, diesen kopieren und mittels rechter Maustaste hier im Antwortfenster einfügen - fertig.
Gruß Werner

AW: Daten mit mehreren Suchkriterien in 2. Tabelle
28.04.2016 13:35:05
Albrecht
Hallo zusammen,
kann mir vielleicht noch jemand bei meinem eigentlichen Anliegen helfen?
Danke!

Anzeige
AW: AGGREGAT() ? dann frag doch mich ;-) ...
28.04.2016 14:08:37
...
Hallo Albrecht,
... in A1 so:
=WENNFEHLER(INDEX('AF_CB_FV '!A:A;AGGREGAT(15;6;ZEILE('AF_CB_FV '!A$2:A$332)/
(('AF_CB_FV '!D$2:D$332="Mayor")/('AF_CB_FV '!F$2:F$332="x"));ZEILE()));"")

oder in einer beliebigen Zelle unterhalb Zeile 1 so:
=WENNFEHLER(INDEX('AF_CB_FV '!A:A;AGGREGAT(15;6;ZEILE('AF_CB_FV '!A$2:A$332)/
(('AF_CB_FV '!D$2:D$332="Mayor")/('AF_CB_FV '!F$2:F$332="x"));ZEILE(A1)));"")

und Formeln nach unten kopieren.
Gruß Werner
.. , - ...

... und natürlich als xlsX-Datei abspeichern owT
28.04.2016 14:11:48
...
Gruß Werner
.. , - ...

AW: ... und natürlich als xlsX-Datei abspeichern owT
28.04.2016 17:48:50
Albrecht
Hallo Werner,
Herzlichen Dank! Funktioniert im Prinzip total gut. Ich habe nur die folgenden Probleme:
1.) Wenn ich es so mache, wie von dir angegeben, dann steht in Zeile 1 und 2 genau das Gleiche. Ab Zeile 3 stimmt es dann.
2.) Wenn ich in der Ergebnistabelle z.B. noch zwei Kopfzeilen über die Formelausgabe drüber setze, dann spuckt mir die Formel auch erst das dritte zutreffende Ergebnis aus, obwohl sich das doch eigentlich durch den absoluten $-Bezug gar nicht ändern dürfte?
Irgendwie durchschaue ich noch nicht so richtig, was hier eigentlich passiert.
Nochmals Danke für eine Rückmeldung!
Albrecht

Anzeige
AW: bei mir nicht, sieh mal ...
28.04.2016 18:09:34
...
Hallo Albrecht,
... hier:
 ABC
1AF 1.1.1 KopfZeile1
2AF 1.1.2 KopfZeile2
3AF 1.2.1 AF 1.1.1
4  AF 1.1.2
5  AF 1.2.1
6   

Formeln der Tabelle
ZelleFormel
A1=WENNFEHLER(INDEX('AF_CB_FV '!A:A;AGGREGAT(15;6;ZEILE('AF_CB_FV '!A$2:A$332)/(('AF_CB_FV '!D$2:D$332="Mayor")/('AF_CB_FV '!F$2:F$332="x")); ZEILE())); "")
A2=WENNFEHLER(INDEX('AF_CB_FV '!A:A;AGGREGAT(15;6;ZEILE('AF_CB_FV '!A$2:A$332)/(('AF_CB_FV '!D$2:D$332="Mayor")/('AF_CB_FV '!F$2:F$332="x")); ZEILE())); "")
A3=WENNFEHLER(INDEX('AF_CB_FV '!A:A;AGGREGAT(15;6;ZEILE('AF_CB_FV '!A$2:A$332)/(('AF_CB_FV '!D$2:D$332="Mayor")/('AF_CB_FV '!F$2:F$332="x")); ZEILE())); "")
C3=WENNFEHLER(INDEX('AF_CB_FV '!A:A;AGGREGAT(15;6;ZEILE('AF_CB_FV '!A$2:A$332)/(('AF_CB_FV '!D$2:D$332="Mayor")/('AF_CB_FV '!F$2:F$332="x")); ZEILE(A1))); "")
C4=WENNFEHLER(INDEX('AF_CB_FV '!A:A;AGGREGAT(15;6;ZEILE('AF_CB_FV '!A$2:A$332)/(('AF_CB_FV '!D$2:D$332="Mayor")/('AF_CB_FV '!F$2:F$332="x")); ZEILE(A2))); "")
C5=WENNFEHLER(INDEX('AF_CB_FV '!A:A;AGGREGAT(15;6;ZEILE('AF_CB_FV '!A$2:A$332)/(('AF_CB_FV '!D$2:D$332="Mayor")/('AF_CB_FV '!F$2:F$332="x")); ZEILE(A3))); "")


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Anzeige
AW: bei mir nicht, sieh mal ...
28.04.2016 19:04:06
Albrecht
Obercool! Keine Ahnung, was ich falsch gemacht hatte, aber jetzt klappts!
In ewiger Dankbarkeit verbunden
Albrecht

AW: gerne, doch dazu aber ...
29.04.2016 08:12:47
...
Hallo Albrecht,
... nur wenn Du Deinen zuvor gemachten Fehler reproduzieren und erkennen kannst, wird Dir das nächste mal eine eigene analoge Lösung leichter fallen.
Gruß Werner
.. , - ...

AW: gerne, doch dazu aber ...
29.04.2016 21:04:51
Albrecht
Hallo Werner,
da hast du natürlich Recht, ich glaube, inzwischen habe ich den Fehler mindestens teilweise verstanden!
Darf ich noch mal eine Frage stellen im Zusammenhang mit dieser Aggregat-Funktion?
Wenn nun bei
=WENNFEHLER(INDEX('AF_CB_FV '!A:A;AGGREGAT(15;6;ZEILE('AF_CB_FV '!A$2:A$332) /(('AF_CB_FV '!D$2:D$332="Mayor")/('AF_CB_FV '!F$2:F$332="x")); ZEILE())); "")
in der Spalte F nicht nur "x" stehen kann, sondern z.B. "a", "b", "c" oder "d", und der Eintrag in der zweiten Tabelle dann erfolgen soll, wenn in Spalte F "a" ODER "b" steht - wie muss ich die Formel dann verändern? Mit ODER klappt's irgendwie nicht...
Beste Grüße
Albrecht

Anzeige
AW: Lang- und Kurzfassung ...
30.04.2016 09:28:29
...
Hallo Albrecht,
... zunächst aber, hab eben festgestellt, dass ich vergessen hatte, aus Deiner ursprünglichen Formel ein unnötiges Klammerpaar zu entfernen. Ausreichend wäre:
=WENNFEHLER(INDEX('AF_CB_FV '!A:A;AGGREGAT(15;6;ZEILE('AF_CB_FV '!A$2:A$332) /('AF_CB_FV '!D$2:D$332="Mayor")/('AF_CB_FV '!F$2:F$332="x");ZEILE(A1)));"")
Nun zu Deiner Zusatzanfrage:
In ("echten" Matrixformeln oder in Matrixfunktio(nalität)sformeln wie dieser hier wird anstelle ODER() bzw. UND() eine + bzw. * eingesetzt. Mehr dazu sieh mal hier:http://www.online-excel.de/excel/singsel.php?f=91
So wie ich Deine neue Frage interpretiert stelle zunächst die Formel zum besseren Verständnis in Langfassung und nur für "a" oder "b" auf:
=WENNFEHLER(INDEX('AF_CB_FV '!A:A;AGGREGAT(15;6;ZEILE('AF_CB_FV '!A$2:A$332) /('AF_CB_FV '!D$2:D$332="Mayor")/(('AF_CB_FV '!F$2:F$332="a")+('AF_CB_FV '!F$2:F$332="b"));ZEILE(A1) ));"")
um außerdem "c" oder "d" noch zu berücksichtigen müsste die Formel entsprechend verlängert werden.
Nun die Kurzfassung für alle vier "ODERs": "a", "b", "c" oder "d" so:
=WENNFEHLER(INDEX('AF_CB_FV '!A:A;AGGREGAT(15;6;ZEILE('AF_CB_FV '!A$2:A$332) /('AF_CB_FV '!D$2:D$332="Mayor")/('AF_CB_FV '!F$2:F$332={"a"."b"."c"."d"});ZEILE(A1)));"")
Gruß Werner
.. , - ...

Anzeige
AW: Lang- und Kurzfassung ...
01.05.2016 08:21:38
Albrecht
Hallo Werner,
So einfach!!! Funktioniert prima!
Vielen Dank - auch für den Hinweis mit den Klammern!
Schönen Sonntag!
Albrecht

322 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige