Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Werte in einer Zelle suchen

Werte in einer Zelle suchen
10.05.2017 13:15:50
Jens
Hallo zusammen,
Ich habe in einer Matrix Werte drin stehen. Z.B. in den Zellen A1:O1
Diese sollen in einer Zelle gesucht werden. Z.B. in Zelle A3
Wenn einer der Werte aus A1 bis O1 gefunden wurde, soll WAHR zurück gegeben werden. Ansonsten FALSCH oder "" (also nix).
Mein Ansatz sieht so aus. In B3 schreibe ich als Matrixformel:
{=WENNFEHLER(FINDEN($A$1:$O$1;A3);"")}
Leider funktioniert das nur sporadisch und ich bekomme "nur" eine Zahl anstatt WAHR zurück.
Was mache ich falsch?
Beim Anschauen mit der Formelauswertung sehe ich immer unter den vielen #WERT! -Werten auch den einen gefunden Wert z.B. 2 aber der wird nicht ausgegeben.

13
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Werte in einer Zelle suchen
10.05.2017 13:19:52
Sheldon
Hallo Jens,
{=SUMME(WENNFEHLER(FINDEN($A$1:$O$1;A3);0))>0}
Gruß
Sheldon
AW: Werte in einer Zelle suchen
10.05.2017 14:26:00
Jens
Hallo Sheldon,
vielen Dank für deine Hilfe, aber die Formel bringt grundsätzlich WAHR als Ergebnis bei mir. Da kommt nie etwas anderes raus. ?
Viele Grüße
AW: Werte in einer Zelle suchen
10.05.2017 14:51:23
Sheldon
Hallo Jens,
sorry, hatte die Formel nicht getestet. In deiner Finden-Formel waren die Argumente vertauscht.
Argument 1: Suchtext
Argument 2: zu durchsuchender Text
{=SUMME(WENNFEHLER(FINDEN(A3;$A$1:$O$1);0))>0}
Gruß
Sheldon
AW: Werte in einer Zelle suchen
10.05.2017 15:36:50
Jens
Hallo Sheldon,
Aber das ist genau mein Thema! Ich habe mehrere Werte in Zellen welche die Suchttexte sind.
Wenn einer dieser Werte in der Zielzelle A3 gefunden wird soll WAHR ausgegeben werden.
Geht das überhaupt?
Anzeige
AW: einfacher mit mit ZÄHLENWENN() ...
10.05.2017 16:15:55
...
Hallo Jens,
... so: =WENN(ZÄHLENWENN(A1:O1;A3);WAHR;"")
Gruß Werner
.. , - ...
AW: leider nein ...
10.05.2017 16:35:43
Jens
Hallo Werner,
hallo Sheldon,
leider hilft mir das noch immer nicht mein Problem zu lösen. Anbei ein Link zu einer Musterdatei.
https://www.herber.de/bbs/user/113477.xlsx
PS: Die Spalten E bis O können wie hier im Beispiel auch mal leer sein.
Kann mir jemand helfen?
AW: jetzt erst die Aufgabenstellung eindeutig ...
10.05.2017 16:52:34
...
Hallo jens,
... dann mit einer Matrixfunktion(alität)sformel (bedarf keines spez. Eingabeabschlusses wie eine klassische Matrixformel)
So z.B.: =WENN(ISTNV(VERWEIS(9;1/SUCHEN(A$1:O$1&"";A3)/(A$1:O$1"")));"";WAHR)
Gruß Werner
.. , - ...
Anzeige
AW: leider nein ...
10.05.2017 16:52:38
Sheldon
Ah, verstanden!
{=SUMME(WENNFEHLER(WENN($A$1:$O$1<>"";FINDEN($A$1:$O$1;A3);NV());0))>0}
Das Problem war, dass die leeren Zellen immer zu einer Übereinstimmung geführt haben. Daher gibt die Wennformel dann #NV aus, was vom Wennfehler wieder umgeformt wird. Ist umständlich, aber ich bin heute unkreativ.
Gruß
Sheldon
AW: doch noch nicht ganz eindeutig ...
10.05.2017 17:01:31
...
Hallo jens,
... was ist wenn in A4 F14P1053 steht? Soll dann WAHR (wegen der 53) oder FALSCH erscheinen. Im letzteren Fall wird die Formel wohl länger.
Gruß Werner
.. , - ...
AW: doch noch nicht ganz eindeutig ...
10.05.2017 17:19:23
Jens
Hallo Werner,
hallo Sheldon,
vielen Dank für die Antworten. Beide Formel funktionieren jetzt wie ich mir das gedacht hatte.
@Werner: Deine Frage ist berechtigt, und daran hatte ich auch schon gedacht. Jetzt liegt es aber in der Natur der Daten, dass dieser Fall 53 in P1053 eigentlich nicht vorkommen sollte. Wenn doch, dann hatte ich in Gedanken schon in Kauf genommen, dass ich dieses sehr schnell in einem nachgelagerten Prozessschritt erkennen müsste und dann eben manuell eingreifen muss. Perfekt wäre natürlich eine Formel, die immer die gesamte Zahl zwischen zwei Buchstaben oder zwischen Buchstabe und Komma
P201,F1053F23,O44 ==> Enthält die zu vergleichenden Zahlen: 201/1053/23/44
berücksichtigt. Aber da wäre ich mir nicht sicher ob, das ohne VBA geht?
Vielen Dank.
Grüße
Anzeige
AW: mit Matrixfunktion(alität)sformel möglich ...
10.05.2017 18:23:46
...
Hallo Jens,
... die Frage ist allerdings, ob Dich eine Monsterformel vielleicht nur abschreckt. Meine entsprechende Formel (zwar noch nicht auf Kürze optimiert) wäre momentan 383 Zeichen lang.
Meine erste Formel ließe sich übrigens noch etwas kürzen.
Gruß Werner
.. , - ...
AW: mit Matrixfunktion(alität)sformel möglich ...
11.05.2017 09:53:09
Jens
Hallo Werner,
WOW!! Wenn du die schon erstellt hast dann poste die doch mal. Aber ich kann nicht versprechen, dass sie zum Einsatz kommt. Ich werde berichten.
VG
AW: es bleibt leider noch eine Einschränkung ...
11.05.2017 15:31:27
...
Hallo Jens,
... zunächst hat meine heutige Überprüfung meiner gestrigen Formel noch Fehler aufgewiesen. Diese konnte ich zu Lasten einer weiteren Formel-Verlängerung weites gehend reduzieren allerdings war mir dies auch nicht mehr als Matrixfunktion(alität)sformel realisierbar. Die neue Formelbedarf nun den klassischen Matrixformelabschluss.
Die gekürzte Formel für den einfachen Test findest Du in C3. Die Matrixformel in E3.
Diese Formel kann momentan aber noch nicht richtig auswerten, wenn die gesuchte Zahl korrekt nach der einer Ziffernfolge steht die links und oder rechts von dieser durch eine weitere Ziffer umgeben ist.
Im Beispiel, wenn in A8 die G25 nicht vor der P10253 sondern nach dieser stehen würde, würde G25 nicht als WAHR erkannt.
Nimm also beide Formelversionen und vergleiche da, wo deren Ergebnisse nicht überein stimmen zusätzlich
per Sicht.
 ABCDEFGHI
1 1019531125 105 
2         
319F19 WAHR WAHR    
4F14P102536 WAHR FALSCH    
517F188;G999,F33 FALSCH FALSCH    
6F14P105,G122 WAHR WAHR    
7F14P1156 WAHR FALSCH    
8F16;G25;P10253;F99;V66 WAHR WAHR    
9         

Formeln der Tabelle
ZelleFormel
C3=ISTZAHL(VERWEIS(9;1/SUCHEN(A$1:O$1;A3)/(A$1:O$1<>"")))
E3{=WENN(ANZAHL(INDEX(SUCHEN(A$1:O$1;A3)-1/(A$1:O$1<>""); )); SUMME(--((ISTFEHL(--TEIL(","&A3&",";AGGREGAT(15;6;SUCHEN(A$1:O$1;","&A3&",")-1/(A$1:O$1<>""); ZEILE(A$1:INDEX(A$1:A$15;ANZAHL(SUCHEN(A$1:O$1;A3)-1/(A$1:O$1<>""))))); 1))*ISTFEHL(--TEIL(","&A3&",";AGGREGAT(15;6;SUCHEN(A$1:O$1;","&A3&",")+LÄNGE(A$1:O$1)/(A$1:O$1<>""); ZEILE(A$1:INDEX(A$1:A$15;ANZAHL(SUCHEN(A$1:O$1;A3)-1/(A$1:O$1<>""))))); 1)))=1))>0;1=0)}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Gruß Werner
.. , - ...
Anzeige

339 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige