Formel: nach mehreren Teilstrings in Zelle suchen

Bild

Betrifft: Formel: nach mehreren Teilstrings in Zelle suchen
von: Christian
Geschrieben am: 04.09.2015 21:18:20

Hallo bestes Forum,
ich suche noch einer Formellösung für folgendes Problem:
In Spalte C stehen ab Zeile 2 beliebige Texte
In Spalte A soll jeweils ein "x" eingetragen werden, wenn in dem Text in Spalte C einer der folgenden Befriffe enthalten ist:

  • SUCHBEGRIFF1

  • ZWEITER SUCHBEGRIFF

  • SUCHBEGRIFF DREI

  • Mit folgender Formel In A2 funktioniert das soweit:
    =WENN(ISTFEHLER(WENNFEHLER(FINDEN("SUCHBEGRIFF1";$C2);WENNFEHLER(FINDEN("ZWEITER SUCHBEGRIFF";$C2); FINDEN("SUCHBEGRIFF DREI";$C2))));"";"x")
    Meine Frage:
    geht das auch eleganter / kürzer?
    Insgesamt hat die Tabelle mehr als 10000 Zeilen
    eine Bsp-Tabelle habe ich hochgeladen:
    https://www.herber.de/bbs/user/100023.xls
    Vielen Dank vorab
    Christian

    Bild

    Betrifft: AW: Formel: nach mehreren Teilstrings in Zelle suchen
    von: ransi
    Geschrieben am: 04.09.2015 21:53:35
    Hallo Christian,
    Was hältst du hiervon ?
    Tabelle1

     ABC
    1Formel-1 Text
    21 irgend ein beliebiger Text am Anfang (Status: SUCHBEGRIFF1) irgend ein Text
    31 irgend ein anderer beliebiger Text (Status: ZWEITER SUCHBEGRIFF) irgend ein anderer Text
    40 irgend ein beliebiger Text in dem keiner der 3 Suchbegriffe vorkommt (Status: ANDERER TEXT1) irgend ein Text
    51 irgend ein beliebiger anderer Text und am Ende  (Status: SUCHBEGRIFF DREI)
    60 irgend ein beliebiger Text ohne den Begriff "Status" mit voran gestellter Klammer und keinem der 3 Suchbegriffe
    70 irgend ein beliebiger Text in dem keiner der 3 Suchbegriffe vorkommt (Status: ANDERER TEXT2) irgend ein Text
    81 irgend ein anderer beliebiger Text (Status: ZWEITER SUCHBEGRIFF) irgend ein anderer Text
    90 irgend ein beliebiger Text in dem keiner der 3 Suchbegriffe vorkommt (Status: ANDERER TEXT3) irgend ein Text
    101 (Status:SUCHBEGRIFF1) am Anfang und dann irgend ein weiterer Text
    111 irgend ein beliebiger anderer Text und am Ende (Status: ZWEITER SUCHBEGRIFF)
    121 beliebiger Text (Status: SUCHBEGRIFF DREI) beliebiger Text

    Formeln der Tabelle
    ZelleFormel
    A2=SUMMENPRODUKT(ZÄHLENWENN(C2;"*" & {"SUCHBEGRIFF1";"ZWEITER SUCHBEGRIFF";"SUCHBEGRIFF DREI"} & "*"))


    Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
    ransi

    Bild

    Betrifft: AW: Formel: nach mehreren Teilstrings in Zelle suchen
    von: Christian
    Geschrieben am: 04.09.2015 22:24:29
    Hi Ransi,
    genau sowas hab ich gesucht. Vielen Dank!
    Mit dem Array hab ich auch schon rumprobiert, bin aber nicht auf die Idee mit ZÄHLENWENN gekommen.
    Aber wenn ich das richtig verstehe, kann man hier auch auf SUMMENPRODUKT verzichten, denn SUMME bringt bei meiner Bsp-Datei das gleiche Ergebnis:
    =WENN(SUMME(ZÄHLENWENN(C2;"*"&{"SUCHBEGRIFF1";"ZWEITER SUCHBEGRIFF";"SUCHBEGRIFF DREI"}&"*"));"x";"")
    Das muss ich noch mal in der Original-Datei testen.
    Vielen Dank für deine Unterstützung und Grüße
    Christian

    Bild

    Betrifft: gelöst - vielen Dank, Ransi
    von: Christian
    Geschrieben am: 04.09.2015 23:03:53
    ich hab das eben noch mal geprüft.
    SUMME bringt hier das gleiche Ergebnis wie SUMMEWENN.
    Allerdings sind beide Formeln im Vergleich zu FINDEN nicht case sensitive und leider kommen in der Original-Datei die Suchbegriffe in den Texten an anderer Stelle auch kleingeschrieben vor.
    Das kann man aber abfangen, da in diesem Fall vor den Suchbegriffen immer "(Status: " stehen muss:
    =WENN(SUMME(ZÄHLENWENN(C2;"*"&{"(Status: SUCHBEGRIFF1)";"(Status: ZWEITER SUCHBEGRIFF)"; "(Status: SUCHBEGRIFF DREI)"}&"*"));"x";"")
    Vielen Dank, Ransi - so kann man das auch bei weiteren Suchbegriffen elegant erweitern.
    Grüße
    Christian

     Bild

    Beiträge aus den Excel-Beispielen zum Thema "Formel: nach mehreren Teilstrings in Zelle suchen"