Microsoft Excel

Herbers Excel/VBA-Archiv

Ausgabe von mehreren Werten anhand Suchkriterium

Betrifft: Ausgabe von mehreren Werten anhand Suchkriterium von: Carl
Geschrieben am: 20.08.2008 13:46:17

Hallo Zusammen,

mich interessiert, ob es zu dem nachfolgenden Problem eine relativ simple Excel Lösung gibt.

Ich habe eben mal das Forum durchsucht, allerdings nichts passendes gefunden. Ich nehmen aber mal an, dass ich einfach nicht die richtigen Suchbegriffe weiß. Sprich: wer einen Link weiß, bitte kurz posten. Danke!

Datenblatt



Ausgabeblatt



Ich hatte schon mal an sverweis gedacht, habe dabei allerdings zwei Probleme:

1.) es soll nicht nur ein Spalte, sondern drei Spalten (die liegen in der wirklichen Tabelle nicht nebeneinander!) nach dem Argument durchsucht werden.

2.) Es sollen (wenn vorhanden) mehrere Werte "gefunden" werden.

Inhaltlicher Hintergrund (falls es interessiert):

Ich baue grade ein "Excel-Monster" zur Nachverfolgung und Berechnung von MWSt. für Bauleistungen in Norwegen auf. In Norwegen wird nicht einfach der Netto-Betrag für die Bauleistung (Brücken) mal dem Mehrwertsteuersatz genommen, sondern es wird geschaut wie viel Mehrwertsteuer für das verbaute Material bezahlt wurde.
Darum zielt meine Anfrage auf Folgendes hinaus: Im Datenblatt werden die Rechnungen von Materiallieferungen (pro Rechnung eine Zeile) eingetragen und auf welche Abschlagsrechnungen (=Suchkriterium) der Betrag verteilt werden soll. Im Ausgabe Blatt soll dann für jede Abschlagsrechnung eine Übersicht erstellt werden, die aufführt, welche Materiallieferungen berücksichtigt wurden. Stark vereinfacht

Vielen Dank fürs Lesen und herzlichen Dank für evtl. Antworten,

Carl

  

Betrifft: AW: Ausgabe von mehreren Werten anhand Suchkriterium von: Erich G.
Geschrieben am: 20.08.2008 19:46:17

Hallo Carl,
probier das mal:

 ABCDE
1  2  
2     
3     
4Feld 1-Z2Feld 2-Z2Feld 3-Z2Feld 4-Z22
5Feld 5-Z2Feld 6-Z2Feld 7-Z2Feld 8-Z2 
6     
7     
8Feld 1-Z4Feld 2-Z4Feld 3-Z4Feld 4-Z44
9Feld 5-Z4Feld 6-Z4Feld 7-Z4Feld 8-Z4 
10     
11     
12Feld 1-Z5Feld 2-Z5Feld 3-Z5Feld 4-Z55
13Feld 5-Z5Feld 6-Z5Feld 7-Z5Feld 8-Z5 

Formeln der Tabelle
ZelleFormel
A4=INDEX(Datenblatt!A:A;$E4)
B4=INDEX(Datenblatt!B:B;$E4)
C4=INDEX(Datenblatt!C:C;$E4)
D4=INDEX(Datenblatt!D:D;$E4)
E4{=KKLEINSTE(WENN(C$1=Datenblatt!$I$2:$K$7;ZEILE(Datenblatt!$I$2:$K$7)); ZEILE()/4)}
A5=INDEX(Datenblatt!E:E;$E4)
B5=INDEX(Datenblatt!F:F;$E4)
C5=INDEX(Datenblatt!G:G;$E4)
D5=INDEX(Datenblatt!H:H;$E4)

Die Formeln der Zeilen 4 und 5 musst du nach unten nach A8, A12 usw. kopieren.

Ich hoffe, ich habe das Problem richtig verstanden und in die Ausgabe sollen die
(in deinem Beispiel fehlenden) Einträge im Datenblatt unter Feld 1 usw. übertragen werden.

Noch eine Bemerkung:
Eine Beispielgrafik ist nicht so furchtbar praktisch für potentielle Antworter.
Soll man die Aufgabenstellung erst einmal abtippen?
Sinnvoller wären die Darstellung als Tabellen per Excel-Jeanie oder das Hochladen einer Beispielmappe.

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort


  

Betrifft: AW: Ausgabe von mehreren Werten anhand Suchkriterium von: Carl
Geschrieben am: 23.08.2008 10:09:12

Hei Erich,

vielen Dank für Deine Antwort und tschuldigung, dass meine Antwort (=Ausprobieren) so lange auf sich hat warten lassen.

Funktioniert wunderbar.

Eine kleine Frage noch: Wenn keine "Datensätze" mehr gefunden werden, erscheint in den Datenfeldern #ZAHL! (siehe Beispieldatei https://www.herber.de/bbs/user/54836.xls :-)

Gibt es eine Möglichkeit das noch zu eliminieren (oder automatische den Druckbereich anzupassen)? Ich habe mal mit WENN rumgespielt, allerdings ohne Erfolg.

Grüße aus Norwegen,

Carl


  

Betrifft: AW: Ausgabe von Werten anhand Suchkriterium von: Erich G.
Geschrieben am: 23.08.2008 12:34:40

Hi Carl,
das ginge wohl so:

 ABCDE
1  2  
2     
3     
4Feld 1-Z2Feld 2-Z2Feld 3-Z2Feld 4-Z22
5Feld 5-Z2Feld 6-Z2Feld 7-Z2Feld 8-Z2 
6     
7     
8Feld 1-Z4Feld 2-Z4Feld 3-Z4Feld 4-Z44
9Feld 5-Z4Feld 6-Z4Feld 7-Z4Feld 8-Z4 
10     
11     
12Feld 1-Z5Feld 2-Z5Feld 3-Z5Feld 4-Z55
13Feld 5-Z5Feld 6-Z5Feld 7-Z5Feld 8-Z5 

Formeln der Tabelle
ZelleFormel
A4=WENN($E4="";"";INDEX(Datenblatt!A:A;$E4))
B4=WENN($E4="";"";INDEX(Datenblatt!B:B;$E4))
C4=WENN($E4="";"";INDEX(Datenblatt!C:C;$E4))
D4=WENN($E4="";"";INDEX(Datenblatt!D:D;$E4))
E4{=WENN(ANZAHL(WENN(C$1=Datenblatt!$I$2:$K$7;ZEILE(Datenblatt!$I$2:$K$7)))<ZEILE()/4;""; KKLEINSTE(WENN(C$1=Datenblatt!$I$2:$K$7;ZEILE(Datenblatt!$I$2:$K$7)); ZEILE()/4))}
A5=WENN($E4="";"";INDEX(Datenblatt!E:E;$E4))
B5=WENN($E4="";"";INDEX(Datenblatt!F:F;$E4))
C5=WENN($E4="";"";INDEX(Datenblatt!G:G;$E4))
D5=WENN($E4="";"";INDEX(Datenblatt!H:H;$E4))
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort und: Schönes Wochenende!


 

Beiträge aus den Excel-Beispielen zum Thema "Ausgabe von mehreren Werten anhand Suchkriterium"