Microsoft Excel

Herbers Excel/VBA-Archiv

Wenn dann sonst oder So

Betrifft: Wenn dann sonst oder So von: Dominique Herzog
Geschrieben am: 18.09.2020 12:51:51

Hallo

Ich bin wieder einmal auf eure komptente Hilfe angewiesen,

ich habe ein File mit einem Preis 3 verschiedenen Rabatten und der 4. Rabatt setzt sich aus dem 2. & 3.Rabatt zusammen.

Am Schluss möchte ich noch anhand der Zahlungsbedingungen den Netto-Netto-Preis anzeigen

Spalte J Bruttopreis

Spalte L Rabatt in %

Spalte M 1.Spezailrabtt in %

Spalte N 2.Spezailrabtt in %


Nun habe ich noch die Resultate

Spalte O = Bruttopreis minus Rabatt aus Spalte L ergibt ersten Nettopreis

Formel: =J3-(J3*L3)

Spalte P = Bruttopreis minus SpezialRabatt aus Spalte M ergibt zweiten Nettopreis

Formel: =WENN(ODER(M3="");"";(RUNDEN(J3-(J3*L3)-((J3-(J3*L3))*M3);2)))

Spalte Q = Bruttopreis minus SpezialRabatt aus Spalte N ergibt dritten Nettopreis

Formel: =WENN(N3="";"";(J3-(J3*(L3+N3))))

Spalte R Bruttopreis minus Rabatt aus Spalte M und SpezialRabatt aus Spalte N ergibt vierten Nettopreis

Formel: =WENN(ODER(M3="";N3="");"";((RUNDEN(J3-(J3*(L3+N3))-((J3-(J3*(L3+N3)))*M3);2))))


Es sollen aber nur ein Preis angezeigt werden.

Wie mache ich das in Spalte R ?

Betrifft: AW: Wenn dann sonst oder So
von: Yal
Geschrieben am: 18.09.2020 17:23:27

Hallo Dominique,

= WENN(Q3<>"";Q3;WENN(P3<>"";P3;O3))

Bonne soirée
Yal

Betrifft: AW: Wenn dann sonst oder So
von: Dominique Herzog
Geschrieben am: 21.09.2020 09:53:18

Hallo Yal
Leider funktioniert das nicht so, wie ich mir das gedacht habe.
In Spalte R soll die aktuelle Formel nur angewendet werden,
wenn in Spalte M und N eine Zahl(Rabatt) eingefügt wird.
So dass ich in den Spalten P Q R nie gleichzeitig ein Resultat drin stehen habe.

Besten Dank

Gruss
Dominique

Betrifft: AW:(D)eine Beispieldatei könnte hilfreich sein owT
von: neopa C
Geschrieben am: 22.09.2020 11:26:16

Gruß Werner
.. , - ...

Betrifft: AW: AW:(D)eine Beispieldatei könnte hilfreich sein owT
von: Dominique Herzog
Geschrieben am: 22.09.2020 11:50:58

Hallo
Sorry, hatte das Testfile schon angelegt, aber vergessen zu veröffentlichen, Danke.

https://www.herber.de/bbs/user/140361.xlsx

Betrifft: AW: die Bedingungsdefinitionen der Formeln ...
von: neopa C
Geschrieben am: 22.09.2020 14:31:57

Hallo Dominique,

... um Deine angestrebtes Ergebnis (so wie ich es momentan interpretieren konnte) hab ich ich in nachfolgenden Formel aufgezeigt. Dabei hab ich bewusst, Deinen jeweiligen Berechnungsformelteil 1:1 belassen:

Arbeitsblatt mit dem Namen 'Tabelle1'
 JKLMNOPQRST
3Fr. 36,90m246,0% 5,0%  Fr. 18,08 738,0017,54

ZelleFormel
L3=(41+5)%
O3=WENN(ANZAHL(M3:N3)=0;J3-(J3*L3);"")
P3=WENN((M3="")+(ANZAHL(M3:N3)=2);"";RUNDEN(J3-(J3*L3)-((J3-(J3*L3))*M3);2))
Q3=WENN((N3="")+(ANZAHL(M3:N3)=2);"";J3-(J3*(L3+N3)))
R3=WENN(ANZAHL(M3:N3)<2;"";RUNDEN(J3-(J3*(L3+N3))-((J3-(J3*(L3+N3)))*M3);2))
S3=J3/I3
T3=MAX(O3:R3)*97%
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg


Gruß Werner
.. , - ...

Betrifft: AW: die Bedingungsdefinitionen der Formeln ...
von: Dominique
Geschrieben am: 24.09.2020 10:11:28

Guten Morgen
Super herzlichen Dank für die grosse Unterstützung,konnte mir das Ganze noch nicht im einzelnen betrachten, aber es funktioniert einwandfrei.
Vielen Dank und einen schönen Tag

Betrifft: AW: bitteschön owT
von: neopa C
Geschrieben am: 24.09.2020 10:50:49

Gruß Werner
.. , - ...