Live-Forum - Die aktuellen Beiträge
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Dateneinlesen aus Exceldatei (Internet)
29.04.2009 10:45:54
Franz
Hallo zusammen,
von meiner geöffneten Excelmappe "Aufnahme" möchte ich auf eine Exceldatei im Internet zugreifen und
in die Excelmappe "Aufnahme" die Daten einlesen. Mit cbgemarkung (Combobox) möchte ich als erstens die Combobox über die Exceldatei im Internet füllen und zwar mit dem Bereich A3:A395. Nach Auswahl von der Combox "cbgemarkung" soll aus der Exceldatei im Internet die Daten in der Zeile (2 und 3) meiner ausgewählten Zeile in meine geöffneten Excelmappe eingelesen werden. Anbei mein VBA-Lösungsvorschlag. Nur leider kann ich die Daten nicht einlesen! Hat jeamand eine Idee?
Danke.
Gruß Franz

Private Sub cbgemarkung_Change()
Dim rng As Range
Dim sPage As String
Dim s As String
Dim zeile As Long
Dim Gemarkungen As Worksheet
Application.ScreenUpdating = False
sPage = "http://www.......xls"
Workbooks.Open Filename:=sPage
Set Gemarkungen = _
ActiveWorkbook.Worksheets("Gemarkungen")
s = cbgemarkung.Text
zeile = 3
Do While Not IsEmpty(Gemarkungen.Cells(zeile, 1))
If Gemarkungen.Cells(zeile, 1).Value = s Then
Tabelle1.txtGemeinde.Text = Sheets("Gemarkungen").Cells(zeile, 2).Value
Tabelle1.txtStandort.Text = Sheets("Gemarkungen").Cells(zeile, 3).Value
Exit Do
End If
zeile = zeile + 1
Loop
End Sub


4
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
ungetestet, da kein nachbau...
29.04.2009 11:07:58
Tino
Hallo,
habe jetzt Deine Datei nicht nachgebaut und daher auch nicht getestet ob Dein Code funktioniert.
Ich kann Dir nur den Vorschlag unterbreiten, die Datei zuerst Lokal runder zu laden und auf diese zuzugreifen.
Teste mal.
Option Explicit

Public Declare Function URLDownloadToFile Lib "urlmon" Alias "URLDownloadToFileA" ( _
ByVal pCaller&, _
ByVal szURL$, _
ByVal szFileName$, _
ByVal dwReserved&, _
ByVal lpfnCB&) As Long

Public Function DownloadFile(ByVal strURL$, ByVal strLocalFilename$) As Boolean
   Dim lngRet As Long
   
   lngRet = URLDownloadToFile(0, strURL, strLocalFilename, 0, 0)
   
   If lngRet = 0 Then DownloadFile = True
End Function

Private Sub cbgemarkung_Change()
   Dim rng As Range
   Dim sPage As String, strZieldatei  As String
   Dim s As String
   Dim zeile As Long
   Dim Gemarkungen As Worksheet
   Dim meFile As Workbook
   
   Application.ScreenUpdating = False
   
   sPage = "http://www.......xls"
   
   'Ziel = gleicher Ordner 
   strZieldatei = IIf(Right$(ThisWorkbook.Path, 1) = "\", ThisWorkbook.Path, ThisWorkbook.Path & "\")
   strZieldatei = strZieldatei & Right$(sPage, Len(sPage) - InStrRev(sPage, "/"))

   On Error Resume Next
    Kill strZieldatei 'sollte Datei schon vorhanden sein 
   On Error GoTo 0

        If DownloadFile(sPage, strZieldatei) Then
           
               Set meFile = Workbooks.Open(Filename:=strZieldatei)
               Set Gemarkungen = meFile.Worksheets("Gemarkungen")
            
                s = cbgemarkung.Text
                zeile = 3
                
                Do While Not IsEmpty(Gemarkungen.Cells(zeile, 1))
                    If Gemarkungen.Cells(zeile, 1).Value = s Then
                        Tabelle1.txtGemeinde.Text = Gemarkungen.Cells(zeile, 2).Value
                        Tabelle1.txtStandort.Text = Gemarkungen.Cells(zeile, 3).Value
                        Exit Do
                    End If
                    zeile = zeile + 1
                Loop
        
        Else
            MsgBox "Der Download ist fehlgeschlagen!", vbCritical
        End If

Application.ScreenUpdating = True
End Sub


Gruß Tino

Anzeige
AW: ungetestet, da kein nachbau...
29.04.2009 11:47:04
Franz
Hallo Tino,
super funktioniert soweit! Nach dem eintragen sollte jetzt die download Datei wieder geschlossen werden.
.. Close ?
Danke.
Gruß Franz
AW: ungetestet, da kein nachbau...
29.04.2009 12:20:39
Tino
Hallo,
schreibe nach der Loop Zeile diese zwei Zeilen

meFile.Close False
Kill strZieldatei


Gruß Tino

AW: ungetestet, da kein nachbau...
29.04.2009 13:06:26
Franz
Vielen Dank.
Funkt!
Gruß Franz

313 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige
Anzeige

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige