Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1496to1500
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Datenübernahme aus Tabellenblatt mit Sortierung

Datenübernahme aus Tabellenblatt mit Sortierung
31.05.2016 13:16:09
Melanie
Hallo Zusammen.
Eins vorab. Ich bin absoluter Excel-"Embryo".
Ich bereite im Rahmen meiner Ausbildung zur Erzieherin innerhalb einer Bogensport AG
eine Stadtmeisterschaft von drei Schulen vor.
Hierfür habe ich mir jetzt eine Excel-Datei erstellt, die zur Auswertung der einzelnen Ergebnisse dienen soll.
Tabellenblatt "Eingabe" dient, wie der Name schon sagt, der bloßen Eingabe der erzielten Ringe eines jeden Schützen, unterteilt nach Schulen. Der Platzhalter in Spalte A "Schütze 1" bis "Schütze 30" wird durch den realen Namen der Kinder ersetzt.
Tabellenblatt "Auswertung" habe ich bereits mit einem "SVerweis" versehen, der bspw. bei X (BullsEye) eine 10 und bei M (Fehler) eine 0 einträgt. Zusätzlich muss ich bei Punktegleichstand die geschossenen X und M berücksichtigen. Diese werte ich mit "Zählenwenn" aus.
Und jetzt kommt es.
Ich benötige zur Auswertung und zur Veröffentlichung der Ergebnisse ein finales Tabellenblatt, welches ich mal "Druck" genannt habe . Dieses soll die Daten aus Tabellenblatt "Auswertung" übernehmen, allerdings in sortierter Form.
So soll zuerst nach "Spalte H", dann nach "Spalte E", dann nach "Spalte F", dann nach "Spalte G" sortiert werden.
Zur Veranschaulichung habe ich mal das Tabellenblatt "Beispiel für Druck" erstellt.
Die Schwierigkeit besteht zusätzlich darin, dass innerhalb der Schulen unterschiedlich viele Kinder antreten können.
Mein Entwurf habe ich beigefügt.
https://www.herber.de/bbs/user/105888.xlsx

4
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: u.a. mit KGRÖSSTE(), AGGREGAT(), VERWEIS() ...
31.05.2016 14:04:28
...
Hallo Melanie,
.... drei Formel sind maßgebend:
Zuerst eine einfache Formel in H5: =WENN(ZEILE(A1)>ZÄHLENWENN(Auswertung!M:M;">0");"";KGRÖSSTE(Auswertung!M:M;ZEILE(A1))) Dann noch zwei Matrixfunktion(alität)sformeln:
in E5: =WENN(H5="";"";AGGREGAT(14;6;Auswertung!O$1:O$99/(Auswertung!M$1:M$99=H5);ZÄHLENWENN(H$5:H5;H5)))
(vorstehende Formel wird etwas länger, wenn bei Treffer- und "X"-Gleichstand noch die 10er und 9er bei der Sortierung berücksichtigt werden müssen)
Danach in A5:
=WENN(H5="";"";VERWEIS(9;1/(Auswertung!M$1:M$99=H5)/(Auswertung!O$1:O99=E5);Auswertung!A:A))
Alle Formeln ziehend nach unten kopieren. Alle anderen Formeln von Dir, könnten prinzipiell weiter genutzt werden.
Gruß Werner
.. , - ...

Anzeige
AW: u.a. mit KGRÖSSTE(), AGGREGAT(), VERWEIS() ...
03.06.2016 08:02:10
Melanie
Danke "neopa C".
Leider weiß ich gerade nicht, was ich jetzt genau machen soll. Sind das die Formeln für das Tabellenblatt "Druck" oder übernehme ich diese ins Tabellenblatt "Beispiel für Druck" und ersetze hiermit "Druck"?
Ich bin in Excel echt nicht fit. Sorry!

AW: u.a. mit KGRÖSSTE(), AGGREGAT(), VERWEIS() ...
03.06.2016 08:20:28
Melanie
Jetzt habe ich es verstanden.
Aber wie muss die Formel
"in E5: =WENN(H5="";"";AGGREGAT(14;6;Auswertung!O$1:O$99/(Auswertung!M$1:M$99=H5);ZÄHLENWENN(H$5:H5;H5)))" aussehen, wenn noch die 10er und 9er bei der Sortierung berücksichtigt werden müssen?

AW: dann zusätzlich noch ZÄHLENWENNS() und ...
04.06.2016 09:33:29
...
Hallo melanie,
... die Formeln müssen natürlich um die entsprechenden Bedingungen erweitert werden.
So (Formeln nach unten kopieren):
Druck

 ABCDEFGH
4NameScheibeSchuleJahrgang X10'9'Total
5Schütze 144BSchule 2200330170

Formeln der Tabelle
ZelleFormel
A5=WENN(H5="";"";VERWEIS(9;1/(Auswertung!M$1:M$99=H5)/(Auswertung!O$1:O99=E5)/(Auswertung!P$1:P99=F5)/(Auswertung!Q$1:Q99=G5); Auswertung!A:A))
B5=SVERWEIS(A5;Auswertung!$A:$B;2;)
C5=SVERWEIS(A5;Auswertung!$A:$S;19;)
D5=SVERWEIS(A5;Auswertung!A:T;20;)
E5=WENN($H5="";"";AGGREGAT(14;6;Auswertung!O$1:O$99/(Auswertung!$M$1:$M$99=$H5); ZÄHLENWENN($H$5:$H5;$H5)))
F5=WENN(H5="";"";AGGREGAT(14;6;Auswertung!P$1:P$99/(Auswertung!M$1:M$99=H5)/(Auswertung!O$1:O$99=E5); ZÄHLENWENNS(H$5:$H5;H5;E$5:E5;E5)))
G5=WENN(H5="";"";AGGREGAT(14;6;Auswertung!Q$1:Q$99/(Auswertung!M$1:M$99=H5)/(Auswertung!O$1:O$99=E5)/(Auswertung!P$1:P$99=F5); ZÄHLENWENNS(H$5:$H5;H5;E$5:E5;E5;F$5:F5;F5)))
H5=WENN(ZEILE(A1)>ZÄHLENWENN(Auswertung!M:M;">0"); "";KGRÖSSTE(Auswertung!M:M;ZEILE(A1)))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...
Anzeige

304 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige