Tabellen zusammenführen und Summe bilden

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

OK Hörmi,
ich kann und will nicht ausschließen, dass eine Formel- oder PivotTable-Lösung machbar ist. Schwierig wird es in jedem Fall, weil eine "ordentliche" Liste in der Daten-Verwaltung immer eine eindeutige, einmalige Überschrift hat. Das hätte ich in meinem ersten Beitrag noch erwähnen sollen
Auf der Basis deines ersten Musters habe ich einmal einen Ansatz, ein Muster erstellt, wie das mit PQ machbar ist. Für eine einmalige Auswertung gewiss nicht der Hit, weil zu viel "Klicke di Klick", aber da diese Auswertungen auf der Basis gewiss öfter geschehen werden, kann sich das lohnen. Dass Spalten dupliziert werde müssen (Name), umbenannt und umsortiert werden könnten, ist klar. Genauso wie die Tatsache, dass ich nur einen Teil der Arbeit getan habe ;-)
Hier mein "Startkapital": https://www.herber.de/bbs/user/132901.xlsx
Gruß
Günther

Hallo Hörni,
... sind ausreichend. Siehe unten.
- Q31 nach S32, V32 und Y32 kopieren
- P32 nach R32
- T32 nach W32 und
- U32 nach X32
und alle Formeln nach unten kopieren.
Wie Du siehst wird formelmäßig in Spalte Y auch kein Duplikat gelistet:

Arbeitsblatt mit dem Namen 'Bestleistungen'
	B	C	D	E	F	G	H	I	J	K	L	P	Q	R	S	T	U	V	W	X	Y
1	Tages - Bestleistungen
2	180er		171er		High Finish			Short Leg
3	Anzahl	Name	Anzahl	Name	Anzahl	Wert	Name	Anzahl	Wert	Name
4	2	Hans	1	Stefan	1	100	Rudi	1	21	Sepp
5	1	Klaus			1	102	Sepp	1	21	Andi
6					1	112	Klaus	2	20	Peter
7					2	120	Gerd	1	20	Rainer
8								1	17	Hans
9
26												Soll-Ergebnis
27
28	Bestleistungen Gesamt											Bestleistungen Gesamt + Tages-Bestleistung
29	Bestleistungen Gesamt											Bestleistungen Gesamt + Tages-Bestleistung
30	180er		171er		High Finish			Short Leg				180er		171er		High Finish			Short Leg
31	Anzahl	Name	Anzahl	Name	Anzahl	Wert	Name	Anzahl	Wert	Name		Anzahl	Name	Anzahl	Name	Anzahl	Wert	Name	Anzahl	Wert	Name
32	2	Hans	1	Sepp	1	102	Sepp	1	17	Gerd		4	Hans	2	Stefan	2	100	Rudi	4	21	Sepp
33	1	Gerd	1	Stefan	1	101	Hias	1	17	Hans		2	Klaus	1	Sepp	2	102	Sepp	1	21	Andi
34	1	Klaus			1	100	Rudi	2	19	Gerd		1	Gerd			1	112	Klaus	3	20	Peter
35								1	20	Peter						2	120	Gerd	1	20	Rainer
36								3	21	Sepp						1	101	Hias	2	17	Hans
37																			3	17	Gerd
38

Zelle	Formel
P32	=WENN(Q32="";"";SUMMEWENN(C:C;Q32;B:B))
Q32	=WENNFEHLER(INDEX(C:C;AGGREGAT(15;6;ZEILE(C$4:C$99)/(ZÄHLENWENN(Q$31:Q31;C$4:C$99)=0)/(C$4:C$99>"");1));"")
R32	=WENN(S32="";"";SUMMEWENN(E:E;S32;D:D))
S32	=WENNFEHLER(INDEX(E:E;AGGREGAT(15;6;ZEILE(E$4:E$99)/(ZÄHLENWENN(S$31:S31;E$4:E$99)=0)/(E$4:E$99>"");1));"")
T32	=WENN(U32="";"";SUMMEWENN(H:H;V32;F:F))
U32	=WENN(V32="";"";AGGREGAT(14+(LINKS(T$30;1)="S");6;G$4:G$99/(H$4:H$99=V32);1))
V32	=WENNFEHLER(INDEX(H:H;AGGREGAT(15;6;ZEILE(H$4:H$99)/(ZÄHLENWENN(V$31:V31;H$4:H$99)=0)/(H$4:H$99>"");1));"")
W32	=WENN(X32="";"";SUMMEWENN(K:K;Y32;I:I))
X32	=WENN(Y32="";"";AGGREGAT(14+(LINKS(W$30;1)="S");6;J$4:J$99/(K$4:K$99=Y32);1))
Y32	=WENNFEHLER(INDEX(K:K;AGGREGAT(15;6;ZEILE(K$4:K$99)/(ZÄHLENWENN(Y$31:Y31;K$4:K$99)=0)/(K$4:K$99>"");1));"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Gruß Werner
.. , - ...

Beliebteste Forumthreads (12 Monate)

Tabellen zusammenführen und Summe bilden

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

294 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Tabellen zusammenführen und Summe bilden

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

294 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread